b02a70992e734985768e839281932c315fafb21d
1 /*
2 * Copyright (C) 2008-2010 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * * Redistributions of source code must retain the above copyright
9 * notice, this list of conditions and the following disclaimer.
10 * * Redistributions in binary form must reproduce the above copyright
11 * notice, this list of conditions and the following disclaimer in
12 * the documentation and/or other materials provided with the
13 * distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
29 #include <private/bionic_asm.h>
31 // pid_t __bionic_clone(int flags, void* child_stack, pid_t* parent_tid, void* tls, pid_t* child_tid, int (*fn)(void*), void* arg);
32 ENTRY(__bionic_clone)
33 mov ip, sp
34 # save registers to parent stack
35 stmfd sp!, {r4, r5, r6, r7}
36 .cfi_def_cfa_offset 16
37 .cfi_rel_offset r4, 0
38 .cfi_rel_offset r5, 4
39 .cfi_rel_offset r6, 8
40 .cfi_rel_offset r7, 12
42 # load extra parameters
43 ldmfd ip, {r4, r5, r6}
45 # store 'fn' and 'arg' to the child stack
46 stmdb r1!, {r5, r6}
48 # System call
49 ldr r7, =__NR_clone
50 swi #0
51 movs r0, r0
52 beq 1f
54 # In the parent, reload saved registers then either return or set errno.
55 ldmfd sp!, {r4, r5, r6, r7}
56 cmn r0, #(MAX_ERRNO + 1)
57 bxls lr
58 neg r0, r0
59 b __set_errno_internal
61 1: # The child.
62 # Setting lr to 0 will make the unwinder stop at __start_thread
63 mov lr, #0
64 pop {r0, r1}
65 b __start_thread
66 END(__bionic_clone)
67 .hidden __bionic_clone