1 /*
2 * Copyright (C) 2013 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * * Redistributions of source code must retain the above copyright
9 * notice, this list of conditions and the following disclaimer.
10 * * Redistributions in binary form must reproduce the above copyright
11 * notice, this list of conditions and the following disclaimer in
12 * the documentation and/or other materials provided with the
13 * distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
29 #include <private/bionic_asm.h>
31 // pid_t __bionic_clone(int flags, void* child_stack, pid_t* parent_tid, void* tls, pid_t* child_tid, int (*fn)(void*), void* arg);
32 ENTRY(__bionic_clone)
33 # Copy 'fn' and 'arg' onto the child stack.
34 movq %r9, -16(%rsi) # fn
35 movq 8(%rsp), %rax # Read 'arg'.
36 movq %rax, -8(%rsi) # Write 'arg'.
38 subq $16, %rsi
40 # Translate to the kernel calling convention and swap the 'tls' and 'child_tid' arguments.
41 # They're flipped for x86-64 compared to all our other architectures and __bionic_clone.
42 movq %r8, %r10
43 movq %rcx, %r8
45 # Make the system call.
46 movl $__NR_clone, %eax
47 syscall
49 # Check result.
50 testq %rax, %rax
51 jz .L_bc_child
52 jg .L_bc_parent
54 # An error occurred, set errno and return -1.
55 negl %eax
56 movl %eax, %edi
57 call __set_errno_internal
58 ret
60 .L_bc_child:
61 # We don't want anyone to unwind past this point.
62 .cfi_undefined %rip
63 .cfi_undefined %rbp
65 # We're in the child now, so call __start_thread
66 # with the arguments from the child stack moved into
67 # the appropriate registers.
68 popq %rdi # fn
69 popq %rsi # arg
70 call __start_thread
71 hlt
73 .L_bc_parent:
74 # We're the parent; nothing to do.
75 ret
76 END(__bionic_clone)
77 .hidden __bionic_clone