1 /*
2 * armboot - Startup Code for ARM926EJS CPU-core
3 *
4 * Copyright (c) 2003 Texas Instruments
5 *
6 * ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
7 *
8 * Copyright (c) 2001 Marius Gröger <mag@sysgo.de>
9 * Copyright (c) 2002 Alex Züpke <azu@sysgo.de>
10 * Copyright (c) 2002 Gary Jennejohn <garyj@denx.de>
11 * Copyright (c) 2003 Richard Woodruff <r-woodruff2@ti.com>
12 * Copyright (c) 2003 Kshitij <kshitij@ti.com>
13 * Copyright (c) 2010 Albert Aribaud <albert.aribaud@free.fr>
14 *
15 * See file CREDITS for list of people who contributed to this
16 * project.
17 *
18 * This program is free software; you can redistribute it and/or
19 * modify it under the terms of the GNU General Public License as
20 * published by the Free Software Foundation; either version 2 of
21 * the License, or (at your option) any later version.
22 *
23 * This program is distributed in the hope that it will be useful,
24 * but WITHOUT ANY WARRANTY; without even the implied warranty of
25 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
26 * GNU General Public License for more details.
27 *
28 * You should have received a copy of the GNU General Public License
29 * along with this program; if not, write to the Free Software
30 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
31 * MA 02111-1307 USA
32 */
34 #include <asm-offsets.h>
35 #include <config.h>
36 #include <common.h>
37 #include <version.h>
39 #if defined(CONFIG_OMAP1610)
40 #include <./configs/omap1510.h>
41 #elif defined(CONFIG_OMAP730)
42 #include <./configs/omap730.h>
43 #endif
45 /*
46 *************************************************************************
47 *
48 * Jump vector table as in table 3.1 in [1]
49 *
50 *************************************************************************
51 */
54 .globl _start
55 _start:
56 b reset
57 #ifdef CONFIG_PRELOADER
58 /* No exception handlers in preloader */
59 ldr pc, _hang
60 ldr pc, _hang
61 ldr pc, _hang
62 ldr pc, _hang
63 ldr pc, _hang
64 ldr pc, _hang
65 ldr pc, _hang
67 _hang:
68 .word do_hang
69 /* pad to 64 byte boundary */
70 .word 0x12345678
71 .word 0x12345678
72 .word 0x12345678
73 .word 0x12345678
74 .word 0x12345678
75 .word 0x12345678
76 .word 0x12345678
77 #else
78 ldr pc, _undefined_instruction
79 ldr pc, _software_interrupt
80 ldr pc, _prefetch_abort
81 ldr pc, _data_abort
82 ldr pc, _not_used
83 ldr pc, _irq
84 ldr pc, _fiq
86 _undefined_instruction:
87 .word undefined_instruction
88 _software_interrupt:
89 .word software_interrupt
90 _prefetch_abort:
91 .word prefetch_abort
92 _data_abort:
93 .word data_abort
94 _not_used:
95 .word not_used
96 _irq:
97 .word irq
98 _fiq:
99 .word fiq
101 #endif /* CONFIG_PRELOADER */
102 .balignl 16,0xdeadbeef
105 /*
106 *************************************************************************
107 *
108 * Startup Code (reset vector)
109 *
110 * do important init only if we don't start from memory!
111 * setup Memory and board specific bits prior to relocation.
112 * relocate armboot to ram
113 * setup stack
114 *
115 *************************************************************************
116 */
118 .globl _TEXT_BASE
119 _TEXT_BASE:
120 .word CONFIG_SYS_TEXT_BASE
122 /*
123 * These are defined in the board-specific linker script.
124 * Subtracting _start from them lets the linker put their
125 * relative position in the executable instead of leaving
126 * them null.
127 */
128 .globl _bss_start_ofs
129 _bss_start_ofs:
130 .word __bss_start - _start
132 .globl _bss_end_ofs
133 _bss_end_ofs:
134 .word _end - _start
136 #ifdef CONFIG_USE_IRQ
137 /* IRQ stack memory (calculated at run-time) */
138 .globl IRQ_STACK_START
139 IRQ_STACK_START:
140 .word 0x0badc0de
142 /* IRQ stack memory (calculated at run-time) */
143 .globl FIQ_STACK_START
144 FIQ_STACK_START:
145 .word 0x0badc0de
146 #endif
148 /* IRQ stack memory (calculated at run-time) + 8 bytes */
149 .globl IRQ_STACK_START_IN
150 IRQ_STACK_START_IN:
151 .word 0x0badc0de
153 /*
154 * the actual reset code
155 */
157 reset:
158 /*
159 * set the cpu to SVC32 mode
160 */
161 mrs r0,cpsr
162 bic r0,r0,#0x1f
163 orr r0,r0,#0xd3
164 msr cpsr,r0
166 /*
167 * we do sys-critical inits only at reboot,
168 * not when booting from ram!
169 */
170 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
171 bl cpu_init_crit
172 #endif
174 /* Set stackpointer in internal RAM to call board_init_f */
175 call_board_init_f:
176 ldr sp, =(CONFIG_SYS_INIT_SP_ADDR)
177 bic sp, sp, #7 /* 8-byte alignment for ABI compliance */
178 ldr r0,=0x00000000
179 bl board_init_f
181 /*------------------------------------------------------------------------------*/
183 /*
184 * void relocate_code (addr_sp, gd, addr_moni)
185 *
186 * This "function" does not return, instead it continues in RAM
187 * after relocating the monitor code.
188 *
189 */
190 .globl relocate_code
191 relocate_code:
192 mov r4, r0 /* save addr_sp */
193 mov r5, r1 /* save addr of gd */
194 mov r6, r2 /* save addr of destination */
196 /* Set up the stack */
197 stack_setup:
198 mov sp, r4
200 adr r0, _start
201 cmp r0, r6
202 beq clear_bss /* skip relocation */
203 mov r1, r6 /* r1 <- scratch for copy loop */
204 ldr r2, _TEXT_BASE
205 ldr r3, _bss_start_ofs
206 add r2, r0, r3 /* r2 <- source end address */
208 copy_loop:
209 ldmia r0!, {r9-r10} /* copy from source address [r0] */
210 stmia r1!, {r9-r10} /* copy to target address [r1] */
211 cmp r0, r2 /* until source end address [r2] */
212 blo copy_loop
214 #ifndef CONFIG_PRELOADER
215 /*
216 * fix .rel.dyn relocations
217 */
218 ldr r0, _TEXT_BASE /* r0 <- Text base */
219 sub r9, r6, r0 /* r9 <- relocation offset */
220 ldr r10, _dynsym_start_ofs /* r10 <- sym table ofs */
221 add r10, r10, r0 /* r10 <- sym table in FLASH */
222 ldr r2, _rel_dyn_start_ofs /* r2 <- rel dyn start ofs */
223 add r2, r2, r0 /* r2 <- rel dyn start in FLASH */
224 ldr r3, _rel_dyn_end_ofs /* r3 <- rel dyn end ofs */
225 add r3, r3, r0 /* r3 <- rel dyn end in FLASH */
226 fixloop:
227 ldr r0, [r2] /* r0 <- location to fix up, IN FLASH! */
228 add r0, r0, r9 /* r0 <- location to fix up in RAM */
229 ldr r1, [r2, #4]
230 and r7, r1, #0xff
231 cmp r7, #23 /* relative fixup? */
232 beq fixrel
233 cmp r7, #2 /* absolute fixup? */
234 beq fixabs
235 /* ignore unknown type of fixup */
236 b fixnext
237 fixabs:
238 /* absolute fix: set location to (offset) symbol value */
239 mov r1, r1, LSR #4 /* r1 <- symbol index in .dynsym */
240 add r1, r10, r1 /* r1 <- address of symbol in table */
241 ldr r1, [r1, #4] /* r1 <- symbol value */
242 add r1, r9 /* r1 <- relocated sym addr */
243 b fixnext
244 fixrel:
245 /* relative fix: increase location by offset */
246 ldr r1, [r0]
247 add r1, r1, r9
248 fixnext:
249 str r1, [r0]
250 add r2, r2, #8 /* each rel.dyn entry is 8 bytes */
251 cmp r2, r3
252 blo fixloop
253 #endif
255 clear_bss:
256 #ifndef CONFIG_PRELOADER
257 ldr r0, _bss_start_ofs
258 ldr r1, _bss_end_ofs
259 ldr r3, _TEXT_BASE /* Text base */
260 mov r4, r6 /* reloc addr */
261 add r0, r0, r4
262 add r1, r1, r4
263 mov r2, #0x00000000 /* clear */
265 clbss_l:str r2, [r0] /* clear loop... */
266 add r0, r0, #4
267 cmp r0, r1
268 bne clbss_l
270 bl coloured_LED_init
271 bl red_LED_on
272 #endif
274 /*
275 * We are done. Do not return, instead branch to second part of board
276 * initialization, now running from RAM.
277 */
278 #ifdef CONFIG_NAND_SPL
279 ldr r0, _nand_boot_ofs
280 mov pc, r0
282 _nand_boot_ofs:
283 .word nand_boot
284 #else
285 ldr r0, _board_init_r_ofs
286 adr r1, _start
287 add lr, r0, r1
288 add lr, lr, r9
289 /* setup parameters for board_init_r */
290 mov r0, r5 /* gd_t */
291 mov r1, r6 /* dest_addr */
292 /* jump to it ... */
293 mov pc, lr
295 _board_init_r_ofs:
296 .word board_init_r - _start
297 #endif
299 _rel_dyn_start_ofs:
300 .word __rel_dyn_start - _start
301 _rel_dyn_end_ofs:
302 .word __rel_dyn_end - _start
303 _dynsym_start_ofs:
304 .word __dynsym_start - _start
306 /*
307 *************************************************************************
308 *
309 * CPU_init_critical registers
310 *
311 * setup important registers
312 * setup memory timing
313 *
314 *************************************************************************
315 */
316 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
317 cpu_init_crit:
318 /*
319 * flush v4 I/D caches
320 */
321 mov r0, #0
322 mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */
323 mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */
325 /*
326 * disable MMU stuff and caches
327 */
328 mrc p15, 0, r0, c1, c0, 0
329 bic r0, r0, #0x00002300 /* clear bits 13, 9:8 (--V- --RS) */
330 bic r0, r0, #0x00000087 /* clear bits 7, 2:0 (B--- -CAM) */
331 orr r0, r0, #0x00000002 /* set bit 2 (A) Align */
332 orr r0, r0, #0x00001000 /* set bit 12 (I) I-Cache */
333 mcr p15, 0, r0, c1, c0, 0
335 /*
336 * Go setup Memory and board specific bits prior to relocation.
337 */
338 mov ip, lr /* perserve link reg across call */
339 bl lowlevel_init /* go setup pll,mux,memory */
340 mov lr, ip /* restore link */
341 mov pc, lr /* back to my caller */
342 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
344 #ifndef CONFIG_PRELOADER
345 /*
346 *************************************************************************
347 *
348 * Interrupt handling
349 *
350 *************************************************************************
351 */
353 @
354 @ IRQ stack frame.
355 @
356 #define S_FRAME_SIZE 72
358 #define S_OLD_R0 68
359 #define S_PSR 64
360 #define S_PC 60
361 #define S_LR 56
362 #define S_SP 52
364 #define S_IP 48
365 #define S_FP 44
366 #define S_R10 40
367 #define S_R9 36
368 #define S_R8 32
369 #define S_R7 28
370 #define S_R6 24
371 #define S_R5 20
372 #define S_R4 16
373 #define S_R3 12
374 #define S_R2 8
375 #define S_R1 4
376 #define S_R0 0
378 #define MODE_SVC 0x13
379 #define I_BIT 0x80
381 /*
382 * use bad_save_user_regs for abort/prefetch/undef/swi ...
383 * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
384 */
386 .macro bad_save_user_regs
387 @ carve out a frame on current user stack
388 sub sp, sp, #S_FRAME_SIZE
389 stmia sp, {r0 - r12} @ Save user registers (now in svc mode) r0-r12
390 ldr r2, IRQ_STACK_START_IN
391 @ get values for "aborted" pc and cpsr (into parm regs)
392 ldmia r2, {r2 - r3}
393 add r0, sp, #S_FRAME_SIZE @ grab pointer to old stack
394 add r5, sp, #S_SP
395 mov r1, lr
396 stmia r5, {r0 - r3} @ save sp_SVC, lr_SVC, pc, cpsr
397 mov r0, sp @ save current stack into r0 (param register)
398 .endm
400 .macro irq_save_user_regs
401 sub sp, sp, #S_FRAME_SIZE
402 stmia sp, {r0 - r12} @ Calling r0-r12
403 @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
404 add r8, sp, #S_PC
405 stmdb r8, {sp, lr}^ @ Calling SP, LR
406 str lr, [r8, #0] @ Save calling PC
407 mrs r6, spsr
408 str r6, [r8, #4] @ Save CPSR
409 str r0, [r8, #8] @ Save OLD_R0
410 mov r0, sp
411 .endm
413 .macro irq_restore_user_regs
414 ldmia sp, {r0 - lr}^ @ Calling r0 - lr
415 mov r0, r0
416 ldr lr, [sp, #S_PC] @ Get PC
417 add sp, sp, #S_FRAME_SIZE
418 subs pc, lr, #4 @ return & move spsr_svc into cpsr
419 .endm
421 .macro get_bad_stack
422 ldr r13, IRQ_STACK_START_IN @ setup our mode stack
424 str lr, [r13] @ save caller lr in position 0 of saved stack
425 mrs lr, spsr @ get the spsr
426 str lr, [r13, #4] @ save spsr in position 1 of saved stack
427 mov r13, #MODE_SVC @ prepare SVC-Mode
428 @ msr spsr_c, r13
429 msr spsr, r13 @ switch modes, make sure moves will execute
430 mov lr, pc @ capture return pc
431 movs pc, lr @ jump to next instruction & switch modes.
432 .endm
434 .macro get_irq_stack @ setup IRQ stack
435 ldr sp, IRQ_STACK_START
436 .endm
438 .macro get_fiq_stack @ setup FIQ stack
439 ldr sp, FIQ_STACK_START
440 .endm
441 #endif /* CONFIG_PRELOADER */
443 /*
444 * exception handlers
445 */
446 #ifdef CONFIG_PRELOADER
447 .align 5
448 do_hang:
449 ldr sp, _TEXT_BASE /* switch to abort stack */
450 1:
451 bl 1b /* hang and never return */
452 #else /* !CONFIG_PRELOADER */
453 .align 5
454 undefined_instruction:
455 get_bad_stack
456 bad_save_user_regs
457 bl do_undefined_instruction
459 .align 5
460 software_interrupt:
461 get_bad_stack
462 bad_save_user_regs
463 bl do_software_interrupt
465 .align 5
466 prefetch_abort:
467 get_bad_stack
468 bad_save_user_regs
469 bl do_prefetch_abort
471 .align 5
472 data_abort:
473 get_bad_stack
474 bad_save_user_regs
475 bl do_data_abort
477 .align 5
478 not_used:
479 get_bad_stack
480 bad_save_user_regs
481 bl do_not_used
483 #ifdef CONFIG_USE_IRQ
485 .align 5
486 irq:
487 get_irq_stack
488 irq_save_user_regs
489 bl do_irq
490 irq_restore_user_regs
492 .align 5
493 fiq:
494 get_fiq_stack
495 /* someone ought to write a more effiction fiq_save_user_regs */
496 irq_save_user_regs
497 bl do_fiq
498 irq_restore_user_regs
500 #else
502 .align 5
503 irq:
504 get_bad_stack
505 bad_save_user_regs
506 bl do_irq
508 .align 5
509 fiq:
510 get_bad_stack
511 bad_save_user_regs
512 bl do_fiq
514 #endif
515 #endif /* CONFIG_PRELOADER */