1 /*
2 * armboot - Startup Code for ARM926EJS CPU-core
3 *
4 * Copyright (c) 2003 Texas Instruments
5 *
6 * ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
7 *
8 * Copyright (c) 2001 Marius Gröger <mag@sysgo.de>
9 * Copyright (c) 2002 Alex Züpke <azu@sysgo.de>
10 * Copyright (c) 2002 Gary Jennejohn <garyj@denx.de>
11 * Copyright (c) 2003 Richard Woodruff <r-woodruff2@ti.com>
12 * Copyright (c) 2003 Kshitij <kshitij@ti.com>
13 * Copyright (c) 2010 Albert Aribaud <albert.aribaud@free.fr>
14 *
15 * See file CREDITS for list of people who contributed to this
16 * project.
17 *
18 * This program is free software; you can redistribute it and/or
19 * modify it under the terms of the GNU General Public License as
20 * published by the Free Software Foundation; either version 2 of
21 * the License, or (at your option) any later version.
22 *
23 * This program is distributed in the hope that it will be useful,
24 * but WITHOUT ANY WARRANTY; without even the implied warranty of
25 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
26 * GNU General Public License for more details.
27 *
28 * You should have received a copy of the GNU General Public License
29 * along with this program; if not, write to the Free Software
30 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
31 * MA 02111-1307 USA
32 */
34 #include <asm-offsets.h>
35 #include <config.h>
36 #include <common.h>
37 #include <version.h>
39 #if defined(CONFIG_OMAP1610)
40 #include <./configs/omap1510.h>
41 #elif defined(CONFIG_OMAP730)
42 #include <./configs/omap730.h>
43 #endif
45 /*
46 *************************************************************************
47 *
48 * Jump vector table as in table 3.1 in [1]
49 *
50 *************************************************************************
51 */
54 .globl _start
55 _start:
56 b reset
57 #ifdef CONFIG_PRELOADER
58 /* No exception handlers in preloader */
59 ldr pc, _hang
60 ldr pc, _hang
61 ldr pc, _hang
62 ldr pc, _hang
63 ldr pc, _hang
64 ldr pc, _hang
65 ldr pc, _hang
67 _hang:
68 .word do_hang
69 /* pad to 64 byte boundary */
70 .word 0x12345678
71 .word 0x12345678
72 .word 0x12345678
73 .word 0x12345678
74 .word 0x12345678
75 .word 0x12345678
76 .word 0x12345678
77 #else
78 ldr pc, _undefined_instruction
79 ldr pc, _software_interrupt
80 ldr pc, _prefetch_abort
81 ldr pc, _data_abort
82 ldr pc, _not_used
83 ldr pc, _irq
84 ldr pc, _fiq
86 _undefined_instruction:
87 .word undefined_instruction
88 _software_interrupt:
89 .word software_interrupt
90 _prefetch_abort:
91 .word prefetch_abort
92 _data_abort:
93 .word data_abort
94 _not_used:
95 .word not_used
96 _irq:
97 .word irq
98 _fiq:
99 .word fiq
101 #endif /* CONFIG_PRELOADER */
102 .balignl 16,0xdeadbeef
105 /*
106 *************************************************************************
107 *
108 * Startup Code (reset vector)
109 *
110 * do important init only if we don't start from memory!
111 * setup Memory and board specific bits prior to relocation.
112 * relocate armboot to ram
113 * setup stack
114 *
115 *************************************************************************
116 */
118 .globl _TEXT_BASE
119 _TEXT_BASE:
120 .word CONFIG_SYS_TEXT_BASE
122 /*
123 * These are defined in the board-specific linker script.
124 * Subtracting _start from them lets the linker put their
125 * relative position in the executable instead of leaving
126 * them null.
127 */
128 .globl _bss_start_ofs
129 _bss_start_ofs:
130 .word __bss_start - _start
132 .globl _bss_end_ofs
133 _bss_end_ofs:
134 .word _end - _start
136 #ifdef CONFIG_USE_IRQ
137 /* IRQ stack memory (calculated at run-time) */
138 .globl IRQ_STACK_START
139 IRQ_STACK_START:
140 .word 0x0badc0de
142 /* IRQ stack memory (calculated at run-time) */
143 .globl FIQ_STACK_START
144 FIQ_STACK_START:
145 .word 0x0badc0de
146 #endif
148 /* IRQ stack memory (calculated at run-time) + 8 bytes */
149 .globl IRQ_STACK_START_IN
150 IRQ_STACK_START_IN:
151 .word 0x0badc0de
153 /*
154 * the actual reset code
155 */
157 reset:
158 /*
159 * set the cpu to SVC32 mode
160 */
161 mrs r0,cpsr
162 bic r0,r0,#0x1f
163 orr r0,r0,#0xd3
164 msr cpsr,r0
166 /*
167 * we do sys-critical inits only at reboot,
168 * not when booting from ram!
169 */
170 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
171 bl cpu_init_crit
172 #endif
174 /* Set stackpointer in internal RAM to call board_init_f */
175 call_board_init_f:
176 ldr sp, =(CONFIG_SYS_INIT_SP_ADDR)
177 ldr r0,=0x00000000
178 bl board_init_f
180 /*------------------------------------------------------------------------------*/
182 /*
183 * void relocate_code (addr_sp, gd, addr_moni)
184 *
185 * This "function" does not return, instead it continues in RAM
186 * after relocating the monitor code.
187 *
188 */
189 .globl relocate_code
190 relocate_code:
191 mov r4, r0 /* save addr_sp */
192 mov r5, r1 /* save addr of gd */
193 mov r6, r2 /* save addr of destination */
194 mov r7, r2 /* save addr of destination */
196 /* Set up the stack */
197 stack_setup:
198 mov sp, r4
200 adr r0, _start
201 ldr r2, _TEXT_BASE
202 ldr r3, _bss_start_ofs
203 add r2, r0, r3 /* r2 <- source end address */
204 cmp r0, r6
205 beq clear_bss
207 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
208 copy_loop:
209 ldmia r0!, {r9-r10} /* copy from source address [r0] */
210 stmia r6!, {r9-r10} /* copy to target address [r1] */
211 cmp r0, r2 /* until source end address [r2] */
212 blo copy_loop
214 #ifndef CONFIG_PRELOADER
215 /*
216 * fix .rel.dyn relocations
217 */
218 ldr r0, _TEXT_BASE /* r0 <- Text base */
219 sub r9, r7, r0 /* r9 <- relocation offset */
220 ldr r10, _dynsym_start_ofs /* r10 <- sym table ofs */
221 add r10, r10, r0 /* r10 <- sym table in FLASH */
222 ldr r2, _rel_dyn_start_ofs /* r2 <- rel dyn start ofs */
223 add r2, r2, r0 /* r2 <- rel dyn start in FLASH */
224 ldr r3, _rel_dyn_end_ofs /* r3 <- rel dyn end ofs */
225 add r3, r3, r0 /* r3 <- rel dyn end in FLASH */
226 fixloop:
227 ldr r0, [r2] /* r0 <- location to fix up, IN FLASH! */
228 add r0, r0, r9 /* r0 <- location to fix up in RAM */
229 ldr r1, [r2, #4]
230 and r8, r1, #0xff
231 cmp r8, #23 /* relative fixup? */
232 beq fixrel
233 cmp r8, #2 /* absolute fixup? */
234 beq fixabs
235 /* ignore unknown type of fixup */
236 b fixnext
237 fixabs:
238 /* absolute fix: set location to (offset) symbol value */
239 mov r1, r1, LSR #4 /* r1 <- symbol index in .dynsym */
240 add r1, r10, r1 /* r1 <- address of symbol in table */
241 ldr r1, [r1, #4] /* r1 <- symbol value */
242 add r1, r9 /* r1 <- relocated sym addr */
243 b fixnext
244 fixrel:
245 /* relative fix: increase location by offset */
246 ldr r1, [r0]
247 add r1, r1, r9
248 fixnext:
249 str r1, [r0]
250 add r2, r2, #8 /* each rel.dyn entry is 8 bytes */
251 cmp r2, r3
252 blo fixloop
253 #endif
254 #endif /* #ifndef CONFIG_SKIP_RELOCATE_UBOOT */
256 clear_bss:
257 #ifndef CONFIG_PRELOADER
258 ldr r0, _bss_start_ofs
259 ldr r1, _bss_end_ofs
260 ldr r3, _TEXT_BASE /* Text base */
261 mov r4, r7 /* reloc addr */
262 add r0, r0, r4
263 add r1, r1, r4
264 mov r2, #0x00000000 /* clear */
266 clbss_l:str r2, [r0] /* clear loop... */
267 add r0, r0, #4
268 cmp r0, r1
269 bne clbss_l
271 bl coloured_LED_init
272 bl red_LED_on
273 #endif
275 /*
276 * We are done. Do not return, instead branch to second part of board
277 * initialization, now running from RAM.
278 */
279 #ifdef CONFIG_NAND_SPL
280 ldr r0, _nand_boot_ofs
281 mov pc, r0
283 _nand_boot_ofs:
284 .word nand_boot
285 #else
286 ldr r0, _board_init_r_ofs
287 adr r1, _start
288 add lr, r0, r1
289 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
290 add lr, lr, r9
291 #endif
292 /* setup parameters for board_init_r */
293 mov r0, r5 /* gd_t */
294 mov r1, r7 /* dest_addr */
295 /* jump to it ... */
296 mov pc, lr
298 _board_init_r_ofs:
299 .word board_init_r - _start
300 #endif
302 _rel_dyn_start_ofs:
303 .word __rel_dyn_start - _start
304 _rel_dyn_end_ofs:
305 .word __rel_dyn_end - _start
306 _dynsym_start_ofs:
307 .word __dynsym_start - _start
309 /*
310 *************************************************************************
311 *
312 * CPU_init_critical registers
313 *
314 * setup important registers
315 * setup memory timing
316 *
317 *************************************************************************
318 */
319 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
320 cpu_init_crit:
321 /*
322 * flush v4 I/D caches
323 */
324 mov r0, #0
325 mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */
326 mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */
328 /*
329 * disable MMU stuff and caches
330 */
331 mrc p15, 0, r0, c1, c0, 0
332 bic r0, r0, #0x00002300 /* clear bits 13, 9:8 (--V- --RS) */
333 bic r0, r0, #0x00000087 /* clear bits 7, 2:0 (B--- -CAM) */
334 orr r0, r0, #0x00000002 /* set bit 2 (A) Align */
335 orr r0, r0, #0x00001000 /* set bit 12 (I) I-Cache */
336 mcr p15, 0, r0, c1, c0, 0
338 /*
339 * Go setup Memory and board specific bits prior to relocation.
340 */
341 mov ip, lr /* perserve link reg across call */
342 bl lowlevel_init /* go setup pll,mux,memory */
343 mov lr, ip /* restore link */
344 mov pc, lr /* back to my caller */
345 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
347 #ifndef CONFIG_PRELOADER
348 /*
349 *************************************************************************
350 *
351 * Interrupt handling
352 *
353 *************************************************************************
354 */
356 @
357 @ IRQ stack frame.
358 @
359 #define S_FRAME_SIZE 72
361 #define S_OLD_R0 68
362 #define S_PSR 64
363 #define S_PC 60
364 #define S_LR 56
365 #define S_SP 52
367 #define S_IP 48
368 #define S_FP 44
369 #define S_R10 40
370 #define S_R9 36
371 #define S_R8 32
372 #define S_R7 28
373 #define S_R6 24
374 #define S_R5 20
375 #define S_R4 16
376 #define S_R3 12
377 #define S_R2 8
378 #define S_R1 4
379 #define S_R0 0
381 #define MODE_SVC 0x13
382 #define I_BIT 0x80
384 /*
385 * use bad_save_user_regs for abort/prefetch/undef/swi ...
386 * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
387 */
389 .macro bad_save_user_regs
390 @ carve out a frame on current user stack
391 sub sp, sp, #S_FRAME_SIZE
392 stmia sp, {r0 - r12} @ Save user registers (now in svc mode) r0-r12
393 ldr r2, IRQ_STACK_START_IN
394 @ get values for "aborted" pc and cpsr (into parm regs)
395 ldmia r2, {r2 - r3}
396 add r0, sp, #S_FRAME_SIZE @ grab pointer to old stack
397 add r5, sp, #S_SP
398 mov r1, lr
399 stmia r5, {r0 - r3} @ save sp_SVC, lr_SVC, pc, cpsr
400 mov r0, sp @ save current stack into r0 (param register)
401 .endm
403 .macro irq_save_user_regs
404 sub sp, sp, #S_FRAME_SIZE
405 stmia sp, {r0 - r12} @ Calling r0-r12
406 @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
407 add r8, sp, #S_PC
408 stmdb r8, {sp, lr}^ @ Calling SP, LR
409 str lr, [r8, #0] @ Save calling PC
410 mrs r6, spsr
411 str r6, [r8, #4] @ Save CPSR
412 str r0, [r8, #8] @ Save OLD_R0
413 mov r0, sp
414 .endm
416 .macro irq_restore_user_regs
417 ldmia sp, {r0 - lr}^ @ Calling r0 - lr
418 mov r0, r0
419 ldr lr, [sp, #S_PC] @ Get PC
420 add sp, sp, #S_FRAME_SIZE
421 subs pc, lr, #4 @ return & move spsr_svc into cpsr
422 .endm
424 .macro get_bad_stack
425 ldr r13, IRQ_STACK_START_IN @ setup our mode stack
427 str lr, [r13] @ save caller lr in position 0 of saved stack
428 mrs lr, spsr @ get the spsr
429 str lr, [r13, #4] @ save spsr in position 1 of saved stack
430 mov r13, #MODE_SVC @ prepare SVC-Mode
431 @ msr spsr_c, r13
432 msr spsr, r13 @ switch modes, make sure moves will execute
433 mov lr, pc @ capture return pc
434 movs pc, lr @ jump to next instruction & switch modes.
435 .endm
437 .macro get_irq_stack @ setup IRQ stack
438 ldr sp, IRQ_STACK_START
439 .endm
441 .macro get_fiq_stack @ setup FIQ stack
442 ldr sp, FIQ_STACK_START
443 .endm
444 #endif /* CONFIG_PRELOADER */
446 /*
447 * exception handlers
448 */
449 #ifdef CONFIG_PRELOADER
450 .align 5
451 do_hang:
452 ldr sp, _TEXT_BASE /* switch to abort stack */
453 1:
454 bl 1b /* hang and never return */
455 #else /* !CONFIG_PRELOADER */
456 .align 5
457 undefined_instruction:
458 get_bad_stack
459 bad_save_user_regs
460 bl do_undefined_instruction
462 .align 5
463 software_interrupt:
464 get_bad_stack
465 bad_save_user_regs
466 bl do_software_interrupt
468 .align 5
469 prefetch_abort:
470 get_bad_stack
471 bad_save_user_regs
472 bl do_prefetch_abort
474 .align 5
475 data_abort:
476 get_bad_stack
477 bad_save_user_regs
478 bl do_data_abort
480 .align 5
481 not_used:
482 get_bad_stack
483 bad_save_user_regs
484 bl do_not_used
486 #ifdef CONFIG_USE_IRQ
488 .align 5
489 irq:
490 get_irq_stack
491 irq_save_user_regs
492 bl do_irq
493 irq_restore_user_regs
495 .align 5
496 fiq:
497 get_fiq_stack
498 /* someone ought to write a more effiction fiq_save_user_regs */
499 irq_save_user_regs
500 bl do_fiq
501 irq_restore_user_regs
503 #else
505 .align 5
506 irq:
507 get_bad_stack
508 bad_save_user_regs
509 bl do_irq
511 .align 5
512 fiq:
513 get_bad_stack
514 bad_save_user_regs
515 bl do_fiq
517 #endif
518 #endif /* CONFIG_PRELOADER */