1 /*
2 * Copyright (c) 2004-2008 Texas Instruments
3 *
4 * (C) Copyright 2002
5 * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
6 *
7 * See file CREDITS for list of people who contributed to this
8 * project.
9 *
10 * This program is free software; you can redistribute it and/or
11 * modify it under the terms of the GNU General Public License as
12 * published by the Free Software Foundation; either version 2 of
13 * the License, or (at your option) any later version.
14 *
15 * This program is distributed in the hope that it will be useful,
16 * but WITHOUT ANY WARRANTY; without even the implied warranty of
17 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 * GNU General Public License for more details.
19 *
20 * You should have received a copy of the GNU General Public License
21 * along with this program; if not, write to the Free Software
22 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
23 * MA 02111-1307 USA
24 */
26 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
27 OUTPUT_ARCH(arm)
28 ENTRY(_start)
29 SECTIONS
30 {
31 . = 0x00000000;
33 . = ALIGN(4);
34 .text :
35 {
36 __image_copy_start = .;
37 CPUDIR/start.o (.text*)
38 *(.text*)
39 }
41 . = ALIGN(4);
42 .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
44 . = ALIGN(4);
45 .data : {
46 *(.data*)
47 }
49 . = ALIGN(4);
51 . = .;
53 . = ALIGN(4);
54 .u_boot_list : {
55 KEEP(*(SORT(.u_boot_list*)));
56 }
58 . = ALIGN(4);
60 __image_copy_end = .;
62 .rel.dyn : {
63 __rel_dyn_start = .;
64 *(.rel*)
65 __rel_dyn_end = .;
66 }
68 .dynsym : {
69 __dynsym_start = .;
70 *(.dynsym)
71 }
73 _end = .;
75 /*
76 * Deprecated: this MMU section is used by pxa at present but
77 * should not be used by new boards/CPUs.
78 */
79 . = ALIGN(4096);
80 .mmutable : {
81 *(.mmutable)
82 }
84 /*
85 * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
86 * __bss_base and __bss_limit are for linker only (overlay ordering)
87 */
89 .bss_start __rel_dyn_start (OVERLAY) : {
90 KEEP(*(.__bss_start));
91 __bss_base = .;
92 }
94 .bss __bss_base (OVERLAY) : {
95 *(.bss*)
96 . = ALIGN(4);
97 __bss_limit = .;
98 }
100 .bss_end __bss_limit (OVERLAY) : {
101 KEEP(*(.__bss_end));
102 }
104 /DISCARD/ : { *(.dynstr*) }
105 /DISCARD/ : { *(.dynamic*) }
106 /DISCARD/ : { *(.plt*) }
107 /DISCARD/ : { *(.interp*) }
108 /DISCARD/ : { *(.gnu*) }
109 }