arch/m68k/cpu/mcf547x_8x/start.S

   1 /*
   2  * Copyright (C) 2003   Josef Baumgartner <josef.baumgartner@telex.de>
   3  * Based on code from Bernhard Kuhn <bkuhn@metrowerks.com>
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <asm-offsets.h>
  25 #include <config.h>
  26 #include "version.h"
  27 #include <asm/cache.h>
  28
  29 #ifndef  CONFIG_IDENT_STRING
  30 #define  CONFIG_IDENT_STRING ""
  31 #endif
  32
  33 #define _START  _start
  34 #define _FAULT  _fault
  35
  36 #define SAVE_ALL                                                \
  37         move.w  #0x2700,%sr;            /* disable intrs */     \
  38         subl    #60,%sp;                /* space for 15 regs */ \
  39         moveml  %d0-%d7/%a0-%a6,%sp@;
  40
  41 #define RESTORE_ALL                                             \
  42         moveml  %sp@,%d0-%d7/%a0-%a6;                           \
  43         addl    #60,%sp;                /* space for 15 regs */ \
  44         rte;
  45
  46 .text
  47 /*
  48  *      Vector table. This is used for initial platform startup.
  49  *      These vectors are to catch any un-intended traps.
  50  */
  51 _vectors:
  52
  53 INITSP:         .long   0x00000000      /* Initial SP   */
  54 INITPC:         .long   _START  /* Initial PC           */
  55 vector02:       .long   _FAULT  /* Access Error         */
  56 vector03:       .long   _FAULT  /* Address Error        */
  57 vector04:       .long   _FAULT  /* Illegal Instruction  */
  58 vector05:       .long   _FAULT  /* Reserved             */
  59 vector06:       .long   _FAULT  /* Reserved             */
  60 vector07:       .long   _FAULT  /* Reserved             */
  61 vector08:       .long   _FAULT  /* Privilege Violation  */
  62 vector09:       .long   _FAULT  /* Trace                */
  63 vector0A:       .long   _FAULT  /* Unimplemented A-Line */
  64 vector0B:       .long   _FAULT  /* Unimplemented F-Line */
  65 vector0C:       .long   _FAULT  /* Debug Interrupt      */
  66 vector0D:       .long   _FAULT  /* Reserved             */
  67 vector0E:       .long   _FAULT  /* Format Error         */
  68 vector0F:       .long   _FAULT  /* Unitialized Int.     */
  69
  70 /* Reserved */
  71 vector10_17:
  72 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  73
  74 vector18:       .long   _FAULT  /* Spurious Interrupt   */
  75 vector19:       .long   _FAULT  /* Autovector Level 1   */
  76 vector1A:       .long   _FAULT  /* Autovector Level 2   */
  77 vector1B:       .long   _FAULT  /* Autovector Level 3   */
  78 vector1C:       .long   _FAULT  /* Autovector Level 4   */
  79 vector1D:       .long   _FAULT  /* Autovector Level 5   */
  80 vector1E:       .long   _FAULT  /* Autovector Level 6   */
  81 vector1F:       .long   _FAULT  /* Autovector Level 7   */
  82
  83 /* TRAP #0 - #15 */
  84 vector20_2F:
  85 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  86 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  87
  88 /* Reserved     */
  89 vector30_3F:
  90 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  91 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  92
  93 vector64_127:
  94 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  95 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  96 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  97 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  98 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  99 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 100 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 101 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 102
 103 vector128_191:
 104 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 105 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 106 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 107 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 108 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 109 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 110 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 111 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 112
 113 vector192_255:
 114 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 115 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 116 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 117 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 118 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 119 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 120 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 121 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 122
 123         .text
 124
 125         .globl  _start
 126 _start:
 127         nop
 128         nop
 129         move.w #0x2700,%sr              /* Mask off Interrupt */
 130
 131         /* Set vector base register at the beginning of the Flash */
 132         move.l  #CONFIG_SYS_FLASH_BASE, %d0
 133         movec   %d0, %VBR
 134
 135         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_RAM_CTRL), %d0
 136         movec   %d0, %RAMBAR0
 137
 138         move.l  #(CONFIG_SYS_INIT_RAM1_ADDR + CONFIG_SYS_INIT_RAM1_CTRL), %d0
 139         movec   %d0, %RAMBAR1
 140
 141         move.l  #CONFIG_SYS_MBAR, %d0           /* set MBAR address */
 142         move.c  %d0, %MBAR
 143
 144         /* invalidate and disable cache */
 145         move.l  #0x01040100, %d0        /* Invalidate cache cmd */
 146         movec   %d0, %CACR              /* Invalidate cache */
 147         move.l  #0, %d0
 148         movec   %d0, %ACR0
 149         movec   %d0, %ACR1
 150         movec   %d0, %ACR2
 151         movec   %d0, %ACR3
 152
 153         /* initialize general use internal ram */
 154         move.l #0, %d0
 155         move.l #(ICACHE_STATUS), %a1    /* icache */
 156         move.l #(DCACHE_STATUS), %a2    /* icache */
 157         move.l %d0, (%a1)
 158         move.l %d0, (%a2)
 159
 160         /* set stackpointer to end of internal ram to get some stackspace for the
 161            first c-code */
 162         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_SP_OFFSET), %sp
 163         clr.l %sp@-
 164
 165         move.l #__got_start, %a5        /* put relocation table address to a5 */
 166
 167         jbsr cpu_init_f                 /* run low-level CPU init code (from flash) */
 168         jbsr board_init_f               /* run low-level board init code (from flash) */
 169
 170         /* board_init_f() does not return */
 171
 172 /*------------------------------------------------------------------------------*/
 173
 174 /*
 175  * void relocate_code (addr_sp, gd, addr_moni)
 176  *
 177  * This "function" does not return, instead it continues in RAM
 178  * after relocating the monitor code.
 179  *
 180  * r3 = dest
 181  * r4 = src
 182  * r5 = length in bytes
 183  * r6 = cachelinesize
 184  */
 185         .globl  relocate_code
 186 relocate_code:
 187         link.w %a6,#0
 188         move.l 8(%a6), %sp              /* set new stack pointer */
 189
 190         move.l 12(%a6), %d0             /* Save copy of Global Data pointer */
 191         move.l 16(%a6), %a0             /* Save copy of Destination Address */
 192
 193         move.l #CONFIG_SYS_MONITOR_BASE, %a1
 194         move.l #__init_end, %a2
 195         move.l %a0, %a3
 196
 197         /* copy the code to RAM */
 198 1:
 199         move.l (%a1)+, (%a3)+
 200         cmp.l  %a1,%a2
 201         bgt.s    1b
 202
 203 /*
 204  * We are done. Do not return, instead branch to second part of board
 205  * initialization, now running from RAM.
 206  */
 207         move.l  %a0, %a1
 208         add.l   #(in_ram - CONFIG_SYS_MONITOR_BASE), %a1
 209         jmp     (%a1)
 210
 211 in_ram:
 212
 213 clear_bss:
 214         /*
 215          * Now clear BSS segment
 216          */
 217         move.l  %a0, %a1
 218         add.l   #(_sbss - CONFIG_SYS_MONITOR_BASE),%a1
 219         move.l  %a0, %d1
 220         add.l   #(_ebss - CONFIG_SYS_MONITOR_BASE),%d1
 221 6:
 222         clr.l   (%a1)+
 223         cmp.l   %a1,%d1
 224         bgt.s   6b
 225
 226         /*
 227          * fix got table in RAM
 228          */
 229         move.l  %a0, %a1
 230         add.l   #(__got_start - CONFIG_SYS_MONITOR_BASE),%a1
 231         move.l  %a1,%a5         /* * fix got pointer register a5 */
 232
 233         move.l  %a0, %a2
 234         add.l   #(__got_end - CONFIG_SYS_MONITOR_BASE),%a2
 235
 236 7:
 237         move.l  (%a1),%d1
 238         sub.l   #_start,%d1
 239         add.l   %a0,%d1
 240         move.l  %d1,(%a1)+
 241         cmp.l   %a2, %a1
 242         bne     7b
 243
 244         /* calculate relative jump to board_init_r in ram */
 245         move.l %a0, %a1
 246         add.l #(board_init_r - CONFIG_SYS_MONITOR_BASE), %a1
 247
 248         /* set parameters for board_init_r */
 249         move.l %a0,-(%sp)               /* dest_addr */
 250         move.l %d0,-(%sp)               /* gd */
 251         jsr     (%a1)
 252
 253 /*------------------------------------------------------------------------------*/
 254 /* exception code */
 255         .globl _fault
 256 _fault:
 257         bra _fault
 258         .globl  _exc_handler
 259
 260 _exc_handler:
 261         SAVE_ALL
 262         movel   %sp,%sp@-
 263         bsr exc_handler
 264         addql   #4,%sp
 265         RESTORE_ALL
 266
 267         .globl  _int_handler
 268 _int_handler:
 269         SAVE_ALL
 270         movel   %sp,%sp@-
 271         bsr int_handler
 272         addql   #4,%sp
 273         RESTORE_ALL
 274
 275 /*------------------------------------------------------------------------------*/
 276
 277         .globl  version_string
 278 version_string:
 279         .ascii U_BOOT_VERSION_STRING, "\0"
 280         .align 4