board/evb64260/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Josh Huber <huber@mclx.com>, Mission Critical Linux, Inc.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 /*
  25  * u-boot.lds - linker script for U-Boot on the Galileo Eval Board.
  26  */
  27
  28 OUTPUT_ARCH(powerpc)
  29
  30 SECTIONS
  31 {
  32   /* Read-only sections, merged into text segment: */
  33   .text      :
  34   {
  35     arch/powerpc/cpu/74xx_7xx/start.o   (.text*)
  36     *(.text*)
  37
  38     . = DEFINED(env_offset) ? env_offset : .;
  39     common/env_embedded.o       (.ppcenv*)
  40   }
  41   _etext = .;
  42   PROVIDE (etext = .);
  43   .rodata    :
  44   {
  45     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  46   }
  47
  48   /* Read-write section, merged into data segment: */
  49   . = (. + 0x00FF) & 0xFFFFFF00;
  50   _erotext = .;
  51   PROVIDE (erotext = .);
  52   .reloc   :
  53   {
  54     _GOT2_TABLE_ = .;
  55     KEEP(*(.got2))
  56     KEEP(*(.got))
  57     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  58     _FIXUP_TABLE_ = .;
  59     KEEP(*(.fixup))
  60   }
  61   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  62   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  63
  64   .data    :
  65   {
  66     *(.data*)
  67     *(.sdata*)
  68   }
  69   _edata  =  .;
  70   PROVIDE (edata = .);
  71
  72   . = .;
  73
  74   . = ALIGN(4);
  75   .u_boot_list : {
  76         #include <u-boot.lst>
  77   }
  78
  79
  80   . = .;
  81   __start___ex_table = .;
  82   __ex_table : { *(__ex_table) }
  83   __stop___ex_table = .;
  84
  85   . = ALIGN(256);
  86   __init_begin = .;
  87   .text.init : { *(.text.init) }
  88   .data.init : { *(.data.init) }
  89   . = ALIGN(256);
  90   __init_end = .;
  91
  92   __bss_start = .;
  93   .bss (NOLOAD)       :
  94   {
  95    *(.bss*)
  96    *(.sbss*)
  97    *(COMMON)
  98    . = ALIGN(4);
  99   }
 100   __bss_end__ = . ;
 101   PROVIDE (end = .);
 102 }