board/tqc/tqm8xx/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34
  35     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  36     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  37     arch/powerpc/cpu/mpc8xx/libmpc8xx.o (.text*)
  38     arch/powerpc/lib/libpowerpc.o       (.text*)
  39     board/tqc/tqm8xx/libtqm8xx.o        (.text*)
  40     disk/libdisk.o                      (.text*)
  41     drivers/net/libnet.o                (.text*)
  42     drivers/pcmcia/libpcmcia.o          (.text.pcmcia_on)
  43     drivers/pcmcia/libpcmcia.o          (.text.pcmcia_hardware_enable)
  44     drivers/rtc/librtc.o                (.text*)
  45     drivers/misc/libmisc.o              (.text*)
  46
  47     . = DEFINED(env_offset) ? env_offset : .;
  48     common/env_embedded.o       (.ppcenv*)
  49
  50     *(.text*)
  51   }
  52   _etext = .;
  53   PROVIDE (etext = .);
  54   .rodata    :
  55   {
  56     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  57   }
  58
  59   /* Read-write section, merged into data segment: */
  60   . = (. + 0x00FF) & 0xFFFFFF00;
  61   _erotext = .;
  62   PROVIDE (erotext = .);
  63   .reloc   :
  64   {
  65     _GOT2_TABLE_ = .;
  66     KEEP(*(.got2))
  67     KEEP(*(.got))
  68     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  69     _FIXUP_TABLE_ = .;
  70     KEEP(*(.fixup))
  71   }
  72   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  73   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  74
  75   .data    :
  76   {
  77     *(.data*)
  78     *(.sdata*)
  79   }
  80   _edata  =  .;
  81   PROVIDE (edata = .);
  82
  83   . = .;
  84
  85   . = ALIGN(4);
  86   .u_boot_list : {
  87         #include <u-boot.lst>
  88   }
  89
  90
  91   . = .;
  92   __start___ex_table = .;
  93   __ex_table : { *(__ex_table) }
  94   __stop___ex_table = .;
  95
  96   . = ALIGN(256);
  97   __init_begin = .;
  98   .text.init : { *(.text.init) }
  99   .data.init : { *(.data.init) }
 100   . = ALIGN(256);
 101   __init_end = .;
 102
 103   __bss_start = .;
 104   .bss (NOLOAD)       :
 105   {
 106    *(.bss*)
 107    *(.sbss*)
 108    *(COMMON)
 109    . = ALIGN(4);
 110   }
 111   __bss_end__ = . ;
 112   PROVIDE (end = .);
 113 }