configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Ugly Plug-ins, 0.10.17.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-ugly)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER(config.h)
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS([CXX])
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.26
  56 GSTPB_REQ=0.10.26
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION(0.17)
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-ugly-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106 AC_PROG_CC_STDC
 107
 108 dnl determine c++ compiler
 109 AC_PROG_CXX
 110 dnl determine if c++ is available on this system
 111 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 117 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 118
 119 dnl check if the compiler supports do while(0) macros
 120 AG_GST_CHECK_DOWHILE_MACROS
 121
 122 dnl check for documentation tools
 123 GTK_DOC_CHECK([1.3])
 124 AS_PATH_PYTHON([2.1])
 125 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 126
 127 dnl *** checks for libraries ***
 128
 129 dnl check for libm, for sin()
 130 AC_CHECK_LIBM
 131 AC_SUBST(LIBM)
 132
 133 dnl *** checks for header files ***
 134
 135 dnl used by ext/a52dec
 136 AX_CREATE_STDINT_H
 137
 138 dnl Check for malloc.h
 139 AC_CHECK_HEADERS([malloc.h])
 140
 141 dnl *** checks for types/defines ***
 142
 143 dnl *** checks for structures ***
 144
 145 dnl *** checks for compiler characteristics ***
 146
 147 dnl *** checks for library functions ***
 148
 149 dnl Check for a way to display the function name in debug output
 150 AG_GST_CHECK_FUNCTION
 151
 152 dnl *** checks for dependency libraries ***
 153
 154 dnl GLib is required
 155 AG_GST_GLIB_CHECK([2.20])
 156 ORC_CHECK([0.4.6])
 157
 158 dnl checks for gstreamer
 159 dnl uninstalled is selected preferentially -- see pkg-config(1)
 160 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 161 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 162 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 163 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 164 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 165
 166 dnl Check for documentation xrefs
 167 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 168 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 169 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 170 AC_SUBST(GLIB_PREFIX)
 171 AC_SUBST(GST_PREFIX)
 172 AC_SUBST(GSTPB_PREFIX)
 173
 174 dnl *** set variables based on configure arguments ***
 175
 176 dnl set license and copyright notice
 177 GST_LICENSE="LGPL"
 178 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 179 AC_SUBST(GST_LICENSE)
 180
 181 dnl set location of plugin directory
 182 AG_GST_SET_PLUGINDIR
 183
 184 dnl set release date/time
 185 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 186   ["${srcdir}/gst-plugins-ugly.doap"],
 187   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 188
 189 dnl define an ERROR_CFLAGS Makefile variable
 190 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 191     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 192     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 193     -Winit-self -Wmissing-include-dirs -Waddress
 194     -Waggregate-return -Wno-multichar -Wnested-externs ])
 195
 196 dnl define an ERROR_CXXFLAGS Makefile variable
 197 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 198     -Wmissing-declarations -Wredundant-decls
 199     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 200     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 201     -Wno-multichar])
 202
 203 dnl define correct level for debugging messages
 204 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 205
 206 dnl used in examples
 207 AG_GST_DEFAULT_ELEMENTS
 208
 209 dnl *** plug-ins to include ***
 210
 211 dnl these are all the gst plug-ins, compilable without additional libs
 212 AG_GST_CHECK_PLUGIN(asfdemux)
 213 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 214 AG_GST_CHECK_PLUGIN(dvdsub)
 215 AG_GST_CHECK_PLUGIN(iec958)
 216 AG_GST_CHECK_PLUGIN(mpegaudioparse)
 217 AG_GST_CHECK_PLUGIN(mpegstream)
 218 AG_GST_CHECK_PLUGIN(realmedia)
 219 AG_GST_CHECK_PLUGIN(synaesthesia)
 220
 221 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 222
 223 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 224   WIN32_LIBS="-lws2_32"
 225   AC_SUBST(WIN32_LIBS)
 226 fi
 227
 228 dnl disable experimental plug-ins
 229 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 230   AG_GST_DISABLE_PLUGIN(synaesthesia)
 231 fi
 232
 233 dnl *** ext plug-ins ***
 234 dnl keep this list sorted alphabetically !
 235
 236 if test "x$BUILD_EXTERNAL" = "xyes"; then
 237
 238 echo
 239 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 240 echo
 241
 242 dnl *** a52dec ***
 243 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 244 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 245   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 246 ])
 247
 248 dnl *** amr-nb ***
 249 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 250 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 251   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, HAVE_AMRNB="yes",
 252       [ AG_GST_CHECK_LIBHEADER(AMRNB, opencore-amrnb,
 253                            Decoder_Interface_init, $LIBM,
 254                            opencore-amrnb/interf_dec.h,
 255                            AMRNB_LIBS="-lopencore-amrnb")
 256       ])
 257   AC_SUBST(AMRNB_CFLAGS)
 258   AC_SUBST(AMRNB_LIBS)
 259 ])
 260
 261 dnl *** amr-wb dec ***
 262 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 263 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 264   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, HAVE_AMRWB="yes",
 265       [ AG_GST_CHECK_LIBHEADER(AMRWB, opencore-amrwb,
 266                            D_IF_decode, ,
 267                            opencore-amrwb/dec_if.h,
 268                            AMRWB_LIBS="-lopencore-amrwb")
 269       ])
 270   AC_SUBST(AMRWB_CFLAGS)
 271   AC_SUBST(AMRWB_LIBS)
 272 ])
 273
 274 dnl *** cdio ***
 275 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 276 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 277   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 278 ])
 279
 280 dnl *** dvdread ***
 281 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 282 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 283   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 284   AC_SUBST(DVDREAD_LIBS)
 285 ])
 286
 287 dnl *** lame ***
 288 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 289 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 290   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 291   [
 292     HAVE_LAME="yes"
 293     LAME_LIBS="-lmp3lame $LIBM"
 294     dnl is lame presets available
 295     LAME_CFLAGS=""
 296     AC_TRY_COMPILE([#include <lame/lame.h>], [ int preset = MEDIUM ],
 297       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 298       [LAME_CFLAGS=""]
 299     )
 300     AC_TRY_COMPILE([#include <lame/lame.h>], [
 301         void *ptr = &lame_set_VBR_quality
 302       ],
 303       [LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],
 304       [LAME_CFLAGS="$LAME_CFLAGS"]
 305     )
 306   AC_SUBST(LAME_CFLAGS)
 307   AC_SUBST(LAME_LIBS)
 308   ])
 309 ])
 310
 311 dnl *** mad ***
 312 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 313 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 314
 315   dnl check with pkg-config first
 316   AG_GST_PKG_CHECK_MODULES(ID3TAG, id3tag >= 0.15)
 317   if test "x$HAVE_ID3TAG" = "xno"; then
 318     dnl fall back to oldskool detection
 319     AC_CHECK_HEADER(id3tag.h, [
 320       save_LIBS=$LIBS
 321       LIBS="-lz"
 322       AC_CHECK_LIB(id3tag, id3_tag_options,
 323         HAVE_ID3TAG="yes" ID3TAG_LIBS="-lid3tag -lz")
 324       LIBS=$save_LIBS
 325       AC_SUBST(ID3TAG_LIBS)
 326     ])
 327   fi
 328
 329   if test "x$HAVE_ID3TAG" = "xyes"; then
 330     dnl check with pkg-config first
 331     AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 332     MAD_LIBS="$MAD_LIBS $ID3TAG_LIBS"
 333     if test "x$HAVE_MAD" = "xno"; then
 334       dnl fall back to oldskool detection
 335       AC_CHECK_HEADER(mad.h, [
 336         AC_CHECK_LIB(mad, mad_decoder_finish,
 337           HAVE_MAD="yes" MAD_LIBS="-lmad $ID3TAG_LIBS")
 338       ])
 339     fi
 340   else
 341     HAVE_MAD="no"
 342     AC_MSG_WARN([libid3tag not available, cannot build MAD MP3 decoder plugin])
 343   fi
 344 ])
 345 AC_SUBST(MAD_LIBS)
 346
 347 dnl *** mpeg2dec ***
 348 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 349 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 350   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 351 ])
 352
 353 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 354 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 355 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 356   GST_PATH_SIDPLAY()
 357 ])
 358
 359 dnl *** twolame ***
 360 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 361 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 362   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 363       HAVE_TWOLAME="yes"], [
 364       HAVE_TWOLAME="no"
 365       AC_MSG_RESULT(no)
 366   ])
 367   AC_SUBST(TWOLAME_CFLAGS)
 368   AC_SUBST(TWOLAME_LIBS)
 369 ])
 370
 371 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 372 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 373 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 374   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.55.0)
 375 ])
 376
 377 else
 378
 379 dnl not building plugins with external dependencies,
 380 dnl but we still need to set the conditionals
 381
 382 AM_CONDITIONAL(USE_A52DEC, false)
 383 AM_CONDITIONAL(USE_AMRNB, false)
 384 AM_CONDITIONAL(USE_AMRWB, false)
 385 AM_CONDITIONAL(USE_CDIO, false)
 386 AM_CONDITIONAL(USE_DVDREAD, false)
 387 AM_CONDITIONAL(USE_LAME, false)
 388 AM_CONDITIONAL(USE_MAD, false)
 389 AM_CONDITIONAL(USE_MPEG2DEC, false)
 390 AM_CONDITIONAL(USE_SIDPLAY, false)
 391 AM_CONDITIONAL(USE_TWOLAME, false)
 392 AM_CONDITIONAL(USE_X264, false)
 393
 394 fi dnl of EXT plugins
 395
 396 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 397
 398 dnl Overview:
 399 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 400 dnl GST_*:              flags shared by built objects to link against GStreamer
 401 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 402 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 403 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 404 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 405
 406 dnl GST_OPTION_CFLAGS
 407 if test "x$USE_DEBUG" = xyes; then
 408    PROFILE_CFLAGS="-g"
 409 fi
 410 AC_SUBST(PROFILE_CFLAGS)
 411
 412 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 413   dnl Define _only_ during CVS (not pre-releases or releases)
 414   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 415 else
 416   DEPRECATED_CFLAGS=""
 417 fi
 418 AC_SUBST(DEPRECATED_CFLAGS)
 419
 420 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 421 dnl at make time with e.g. make ERROR_CFLAGS=""
 422 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 423 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 424 AC_SUBST(GST_OPTION_CFLAGS)
 425 AC_SUBST(GST_OPTION_CXXFLAGS)
 426
 427 dnl FIXME: do we want to rename to GST_ALL_* ?
 428 dnl prefer internal headers to already installed ones
 429 dnl also add builddir include for enumtypes and marshal
 430 dnl add GST_OPTION_CFLAGS, but overridable
 431 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 432 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 433 AC_SUBST(GST_CFLAGS)
 434 AC_SUBST(GST_CXXFLAGS)
 435 AC_SUBST(GST_LIBS)
 436
 437 dnl LDFLAGS really should only contain flags, not libs - they get added before
 438 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 439 GST_ALL_LDFLAGS="-no-undefined"
 440 AC_SUBST(GST_ALL_LDFLAGS)
 441
 442 dnl this really should only contain flags, not libs - they get added before
 443 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 444 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 445 AC_SUBST(GST_PLUGIN_LDFLAGS)
 446
 447 dnl *** output files ***
 448
 449 AC_CONFIG_FILES(
 450 Makefile
 451 common/Makefile
 452 common/m4/Makefile
 453 gst-libs/Makefile
 454 gst-libs/gst/Makefile
 455 gst/Makefile
 456 gst/asfdemux/Makefile
 457 gst/dvdlpcmdec/Makefile
 458 gst/dvdsub/Makefile
 459 gst/iec958/Makefile
 460 gst/mpegaudioparse/Makefile
 461 gst/mpegstream/Makefile
 462 gst/realmedia/Makefile
 463 gst/synaesthesia/Makefile
 464 ext/Makefile
 465 ext/a52dec/Makefile
 466 ext/amrnb/Makefile
 467 ext/amrwbdec/Makefile
 468 ext/cdio/Makefile
 469 ext/dvdread/Makefile
 470 ext/lame/Makefile
 471 ext/mad/Makefile
 472 ext/mpeg2dec/Makefile
 473 ext/sidplay/Makefile
 474 ext/twolame/Makefile
 475 ext/x264/Makefile
 476 docs/Makefile
 477 docs/plugins/Makefile
 478 docs/version.entities
 479 tests/Makefile
 480 tests/check/Makefile
 481 m4/Makefile
 482 po/Makefile.in
 483 pkgconfig/Makefile
 484 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 485 gst-plugins-ugly.spec
 486 )
 487
 488 dnl Create the config.h file for Visual Studio builds
 489 dnl Beware of spaces and /'s in some of the shell variable contents.
 490 sed \
 491     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 492     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 493     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 494     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 495     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 496     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 497     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 498     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 499     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 500     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 501     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 502     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 503     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 504     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 505     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 506     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 507     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 508     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 509     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 510     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 511     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 512     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 513     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 514     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 515     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 516     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 517     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 518     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 519     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 520     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 521     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 522     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 523     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 524     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 525     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 526     config.h.in >win32/common/config.h-new
 527
 528 AC_OUTPUT
 529
 530 AG_GST_OUTPUT_PLUGINS
 531
 532 ORC_OUTPUT