configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Ugly Plug-ins, 0.10.15.4,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-ugly)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER(config.h)
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS([CXX])
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.26
  56 GSTPB_REQ=0.10.26
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION(0.17)
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-ugly-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106 AC_PROG_CC_STDC
 107
 108 dnl determine c++ compiler
 109 AC_PROG_CXX
 110 dnl determine if c++ is available on this system
 111 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 117 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 118
 119 dnl check if the compiler supports do while(0) macros
 120 AG_GST_CHECK_DOWHILE_MACROS
 121
 122 dnl check for documentation tools
 123 GTK_DOC_CHECK([1.3])
 124 AS_PATH_PYTHON([2.1])
 125 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 126
 127 dnl *** checks for libraries ***
 128
 129 dnl check for libm, for sin()
 130 AC_CHECK_LIBM
 131 AC_SUBST(LIBM)
 132
 133 dnl *** checks for header files ***
 134
 135 dnl used by ext/a52dec
 136 AX_CREATE_STDINT_H
 137
 138 dnl Check for malloc.h
 139 AC_CHECK_HEADERS([malloc.h])
 140
 141 dnl *** checks for types/defines ***
 142
 143 dnl *** checks for structures ***
 144
 145 dnl *** checks for compiler characteristics ***
 146
 147 dnl *** checks for library functions ***
 148
 149 dnl Check for a way to display the function name in debug output
 150 AG_GST_CHECK_FUNCTION
 151
 152 dnl *** checks for dependency libraries ***
 153
 154 dnl GLib is required
 155 AG_GST_GLIB_CHECK([2.20])
 156 ORC_CHECK([0.4.5])
 157
 158 dnl checks for gstreamer
 159 dnl uninstalled is selected preferentially -- see pkg-config(1)
 160 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 161 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 162 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 163 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 164 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 165
 166 dnl Check for documentation xrefs
 167 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 168 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 169 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 170 AC_SUBST(GLIB_PREFIX)
 171 AC_SUBST(GST_PREFIX)
 172 AC_SUBST(GSTPB_PREFIX)
 173
 174 dnl *** set variables based on configure arguments ***
 175
 176 dnl set license and copyright notice
 177 GST_LICENSE="LGPL"
 178 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 179 AC_SUBST(GST_LICENSE)
 180
 181 dnl set location of plugin directory
 182 AG_GST_SET_PLUGINDIR
 183
 184 dnl define an ERROR_CFLAGS Makefile variable
 185 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 186     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 187     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 188     -Winit-self -Wmissing-include-dirs -Waddress
 189     -Waggregate-return -Wno-multichar -Wnested-externs ])
 190
 191 dnl define an ERROR_CXXFLAGS Makefile variable
 192 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 193     -Wmissing-declarations -Wredundant-decls
 194     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 195     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 196     -Wno-multichar])
 197
 198 dnl define correct level for debugging messages
 199 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 200
 201 dnl used in examples
 202 AG_GST_DEFAULT_ELEMENTS
 203
 204 dnl *** plug-ins to include ***
 205
 206 dnl these are all the gst plug-ins, compilable without additional libs
 207 AG_GST_CHECK_PLUGIN(asfdemux)
 208 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 209 AG_GST_CHECK_PLUGIN(dvdsub)
 210 AG_GST_CHECK_PLUGIN(iec958)
 211 AG_GST_CHECK_PLUGIN(mpegaudioparse)
 212 AG_GST_CHECK_PLUGIN(mpegstream)
 213 AG_GST_CHECK_PLUGIN(realmedia)
 214 AG_GST_CHECK_PLUGIN(synaesthesia)
 215
 216 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 217
 218 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 219   WIN32_LIBS="-lws2_32"
 220   AC_SUBST(WIN32_LIBS)
 221 fi
 222
 223 dnl disable experimental plug-ins
 224 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 225   AG_GST_DISABLE_PLUGIN(synaesthesia)
 226 fi
 227
 228 dnl *** ext plug-ins ***
 229 dnl keep this list sorted alphabetically !
 230
 231 if test "x$BUILD_EXTERNAL" = "xyes"; then
 232
 233 echo
 234 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 235 echo
 236
 237 dnl *** a52dec ***
 238 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 239 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 240   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 241 ])
 242
 243 dnl *** amr-nb ***
 244 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 245 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 246   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, HAVE_AMRNB="yes",
 247       [ AG_GST_CHECK_LIBHEADER(AMRNB, opencore-amrnb,
 248                            Decoder_Interface_init, -lm,
 249                            opencore-amrnb/interf_dec.h,
 250                            AMRNB_LIBS="-lopencore-amrnb")
 251       ])
 252   AC_SUBST(AMRNB_CFLAGS)
 253   AC_SUBST(AMRNB_LIBS)
 254 ])
 255
 256 dnl *** amr-wb dec ***
 257 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 258 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 259   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, HAVE_AMRWB="yes",
 260       [ AG_GST_CHECK_LIBHEADER(AMRWB, opencore-amrwb,
 261                            D_IF_decode, ,
 262                            opencore-amrwb/dec_if.h,
 263                            AMRWB_LIBS="-lopencore-amrwb")
 264       ])
 265   AC_SUBST(AMRWB_CFLAGS)
 266   AC_SUBST(AMRWB_LIBS)
 267 ])
 268
 269 dnl *** cdio ***
 270 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 271 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 272   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 273 ])
 274
 275 dnl *** dvdread ***
 276 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 277 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 278   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 279   AC_SUBST(DVDREAD_LIBS)
 280 ])
 281
 282 dnl *** lame ***
 283 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 284 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 285   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h,
 286   [
 287     HAVE_LAME="yes"
 288     LAME_LIBS="-lmp3lame -lm"
 289     dnl is lame presets available
 290     LAME_CFLAGS=""
 291     AC_TRY_COMPILE([#include <lame/lame.h>], [ int preset = MEDIUM ],
 292       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 293       [LAME_CFLAGS=""]
 294     )
 295     AC_TRY_COMPILE([#include <lame/lame.h>], [
 296         void *ptr = &lame_set_VBR_quality
 297       ],
 298       [LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],
 299       [LAME_CFLAGS="$LAME_CFLAGS"]
 300     )
 301   AC_SUBST(LAME_CFLAGS)
 302   AC_SUBST(LAME_LIBS)
 303   ])
 304 ])
 305
 306 dnl *** mad ***
 307 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 308 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 309
 310   dnl check with pkg-config first
 311   AG_GST_PKG_CHECK_MODULES(ID3TAG, id3tag >= 0.15)
 312   if test "x$HAVE_ID3TAG" = "xno"; then
 313     dnl fall back to oldskool detection
 314     AC_CHECK_HEADER(id3tag.h, [
 315       save_LIBS=$LIBS
 316       LIBS="-lz"
 317       AC_CHECK_LIB(id3tag, id3_tag_options,
 318         HAVE_ID3TAG="yes" ID3TAG_LIBS="-lid3tag -lz")
 319       LIBS=$save_LIBS
 320       AC_SUBST(ID3TAG_LIBS)
 321     ])
 322   fi
 323
 324   if test "x$HAVE_ID3TAG" = "xyes"; then
 325     dnl check with pkg-config first
 326     AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 327     MAD_LIBS="$MAD_LIBS $ID3TAG_LIBS"
 328     if test "x$HAVE_MAD" = "xno"; then
 329       dnl fall back to oldskool detection
 330       AC_CHECK_HEADER(mad.h, [
 331         AC_CHECK_LIB(mad, mad_decoder_finish,
 332           HAVE_MAD="yes" MAD_LIBS="-lmad $ID3TAG_LIBS")
 333       ])
 334     fi
 335   else
 336     HAVE_MAD="no"
 337     AC_MSG_WARN([libid3tag not available, cannot build MAD MP3 decoder plugin])
 338   fi
 339 ])
 340 AC_SUBST(MAD_LIBS)
 341
 342 dnl *** mpeg2dec ***
 343 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 344 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 345   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 346 ])
 347
 348 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 350 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 351   GST_PATH_SIDPLAY()
 352 ])
 353
 354 dnl *** twolame ***
 355 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 356 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 357   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 358       HAVE_TWOLAME="yes"], [
 359       HAVE_TWOLAME="no"
 360       AC_MSG_RESULT(no)
 361   ])
 362   AC_SUBST(TWOLAME_CFLAGS)
 363   AC_SUBST(TWOLAME_LIBS)
 364 ])
 365
 366 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 367 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 368 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 369   AG_GST_CHECK_LIBHEADER(X264, x264, x264_encoder_encode, -lm, x264.h,
 370       AC_MSG_CHECKING([for uptodate x264 API version])
 371       dnl _stdint not yet generated, so no compiling
 372       AC_TRY_CPP([
 373         #include <x264.h>
 374         #if X264_BUILD < 55
 375         #error "x264 build too old"
 376         #endif
 377       ], [
 378         AC_MSG_RESULT(yes)
 379         X264_LIBS="$LDFLAGS -lx264 -lm"
 380         X264_CFLAGS="$CFLAGS"
 381         AC_SUBST(X264_LIBS)
 382         AC_SUBST(X264_CFLAGS)
 383       ], [
 384         AC_MSG_RESULT(no)
 385         HAVE_X264=no
 386       ]))
 387 ])
 388
 389 else
 390
 391 dnl not building plugins with external dependencies,
 392 dnl but we still need to set the conditionals
 393
 394 AM_CONDITIONAL(USE_A52DEC, false)
 395 AM_CONDITIONAL(USE_AMRNB, false)
 396 AM_CONDITIONAL(USE_AMRWB, false)
 397 AM_CONDITIONAL(USE_CDIO, false)
 398 AM_CONDITIONAL(USE_DVDREAD, false)
 399 AM_CONDITIONAL(USE_LAME, false)
 400 AM_CONDITIONAL(USE_MAD, false)
 401 AM_CONDITIONAL(USE_MPEG2DEC, false)
 402 AM_CONDITIONAL(USE_SIDPLAY, false)
 403 AM_CONDITIONAL(USE_TWOLAME, false)
 404 AM_CONDITIONAL(USE_X264, false)
 405
 406 fi dnl of EXT plugins
 407
 408 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 409
 410 dnl Overview:
 411 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 412 dnl GST_*:              flags shared by built objects to link against GStreamer
 413 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 414 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 415 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 416 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 417
 418 dnl GST_OPTION_CFLAGS
 419 if test "x$USE_DEBUG" = xyes; then
 420    PROFILE_CFLAGS="-g"
 421 fi
 422 AC_SUBST(PROFILE_CFLAGS)
 423
 424 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 425   dnl Define _only_ during CVS (not pre-releases or releases)
 426   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 427 else
 428   DEPRECATED_CFLAGS=""
 429 fi
 430 AC_SUBST(DEPRECATED_CFLAGS)
 431
 432 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 433 dnl at make time with e.g. make ERROR_CFLAGS=""
 434 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 435 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 436 AC_SUBST(GST_OPTION_CFLAGS)
 437 AC_SUBST(GST_OPTION_CXXFLAGS)
 438
 439 dnl FIXME: do we want to rename to GST_ALL_* ?
 440 dnl prefer internal headers to already installed ones
 441 dnl also add builddir include for enumtypes and marshal
 442 dnl add GST_OPTION_CFLAGS, but overridable
 443 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 444 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 445 AC_SUBST(GST_CFLAGS)
 446 AC_SUBST(GST_CXXFLAGS)
 447 AC_SUBST(GST_LIBS)
 448
 449 dnl LDFLAGS really should only contain flags, not libs - they get added before
 450 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 451 GST_ALL_LDFLAGS="-no-undefined"
 452 AC_SUBST(GST_ALL_LDFLAGS)
 453
 454 dnl this really should only contain flags, not libs - they get added before
 455 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 456 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 457 AC_SUBST(GST_PLUGIN_LDFLAGS)
 458
 459 dnl *** output files ***
 460
 461 AC_CONFIG_FILES(
 462 Makefile
 463 common/Makefile
 464 common/m4/Makefile
 465 gst-libs/Makefile
 466 gst-libs/gst/Makefile
 467 gst/Makefile
 468 gst/asfdemux/Makefile
 469 gst/dvdlpcmdec/Makefile
 470 gst/dvdsub/Makefile
 471 gst/iec958/Makefile
 472 gst/mpegaudioparse/Makefile
 473 gst/mpegstream/Makefile
 474 gst/realmedia/Makefile
 475 gst/synaesthesia/Makefile
 476 ext/Makefile
 477 ext/a52dec/Makefile
 478 ext/amrnb/Makefile
 479 ext/amrwbdec/Makefile
 480 ext/cdio/Makefile
 481 ext/dvdread/Makefile
 482 ext/lame/Makefile
 483 ext/mad/Makefile
 484 ext/mpeg2dec/Makefile
 485 ext/sidplay/Makefile
 486 ext/twolame/Makefile
 487 ext/x264/Makefile
 488 docs/Makefile
 489 docs/plugins/Makefile
 490 docs/version.entities
 491 tests/Makefile
 492 tests/check/Makefile
 493 m4/Makefile
 494 po/Makefile.in
 495 gst-plugins-ugly.spec
 496 )
 497
 498 dnl Create the config.h file for Visual Studio builds
 499 dnl Beware of spaces and /'s in some of the shell variable contents.
 500 sed \
 501     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 502     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 503     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 504     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 505     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 506     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 507     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 508     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 509     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 510     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 511     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 512     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 513     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 514     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 515     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 516     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 517     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 518     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 519     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 520     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 521     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 522     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 523     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 524     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 525     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 526     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 527     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 528     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 529     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 530     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 531     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 532     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
 533     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 534     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 535     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 536     config.h.in >win32/common/config.h-new
 537
 538 AC_OUTPUT
 539
 540 AG_GST_OUTPUT_PLUGINS
 541
 542 ORC_OUTPUT