configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 9, 0, 1, GST_CVS="no", GST_CVS="yes")
  16
  17 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  18
  19 dnl our libraries and install dirs use major.minor as a version
  20 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  21 dnl we override it here if we need to for the release candidate of new series
  22 GST_MAJORMINOR=0.9
  23 AC_SUBST(GST_MAJORMINOR)
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 dnl for 0.8.3 release, gst_play_get_all_by_interface was added, so update
  31 AS_LIBTOOL(GST_PLUGINS, 1, 0, 1)
  32 AS_LIBTOOL_TAGS([CXX])
  33 AM_PROG_LIBTOOL
  34
  35 dnl FIXME take something else ?
  36 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  37 AM_CONFIG_HEADER(config.h)
  38
  39 dnl Add parameters for aclocal
  40 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  41 ACLOCAL_FLAGS="-I m4 -I common/m4"
  42 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  43
  44 AC_PROG_CC
  45 AM_PROG_CC_STDC
  46 AM_PROG_AS
  47 AS="${CC}"
  48 AS_PROG_OBJC
  49
  50 dnl the gettext stuff needed
  51 AM_GNU_GETTEXT_VERSION(0.11.5)
  52 AM_GNU_GETTEXT([external])
  53
  54 GETTEXT_PACKAGE=gst-plugins-$GST_MAJORMINOR
  55 AC_SUBST(GETTEXT_PACKAGE)
  56 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  57                   [gettext package name])
  58
  59 dnl define LOCALEDIR in config.h
  60 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  61 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  62                    [gettext locale dir])
  63
  64 dnl decide on error flags
  65 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
  66
  67 if test "x$GST_WALL" = "xyes"; then
  68    GST_ERROR="$GST_ERROR -Wall"
  69
  70    if test "x$GST_CVS" = "xyes"; then
  71      AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  72    fi
  73 fi
  74
  75 dnl determine c++ compiler
  76 AC_PROG_CXX
  77 dnl determine if c++ is available on this system
  78 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  79 dnl determine c++ preprocessor
  80 AC_PROG_CXXCPP
  81 AC_ISC_POSIX
  82
  83 AC_HEADER_STDC([])
  84 AC_C_INLINE
  85 AX_CREATE_STDINT_H
  86
  87 dnl Check for malloc.h
  88 AC_CHECK_HEADER(malloc.h,[
  89   AC_DEFINE(HAVE_MALLOC_H, 1, [whether malloc.h available])
  90 ])
  91
  92 dnl Check for a way to display the function name in debug output
  93 GST_CHECK_FUNCTION()
  94
  95 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  96 dnl messages printed when running cvs builds
  97 if test "x$GST_CVS" = "xyes"; then
  98   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  99 fi
 100
 101 dnl Check for FIONREAD ioctl declaration :
 102 GST_CHECK_FIONREAD()
 103
 104 DEFAULT_AUDIOSINK="autoaudiosink"
 105 DEFAULT_VIDEOSINK="autovideosink"
 106 DEFAULT_AUDIOSRC="alsasrc"
 107 DEFAULT_VIDEOSRC="v4lsrc"
 108 DEFAULT_VISUALIZER="goom"
 109 case "$host" in
 110   *-sun-* | *pc-solaris* )
 111     DEFAULT_AUDIOSRC="sunaudiosrc"
 112     ;;
 113   *-darwin* )
 114     DEFAULT_AUDIOSRC="osxaudiosrc"
 115     ;;
 116 esac
 117
 118 AC_SUBST(DEFAULT_AUDIOSINK)
 119 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSINK,"$DEFAULT_AUDIOSINK",[Default audio sink])
 120 AC_SUBST(DEFAULT_AUDIOSRC)
 121 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSRC,"$DEFAULT_AUDIOSRC",[Default audio source])
 122 AC_SUBST(DEFAULT_VIDEOSINK)
 123 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSINK,"$DEFAULT_VIDEOSINK",[Default video sink])
 124 AC_SUBST(DEFAULT_VIDEOSRC)
 125 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSRC,"$DEFAULT_VIDEOSRC",[Default video source])
 126 AC_SUBST(DEFAULT_VISUALIZER)
 127 AC_DEFINE_UNQUOTED(DEFAULT_VISUALIZER,"$DEFAULT_VISUALIZER",[Default visualizer])
 128
 129 dnl ############################################
 130 dnl # Super Duper options for plug-in building #
 131 dnl ############################################
 132
 133 dnl ext plug-ins; plug-ins that have external dependencies
 134 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 135 [HAVE_EXTERNAL=yes],enabled,
 136 [
 137   AC_MSG_WARN(building external plug-ins)
 138   BUILD_EXTERNAL="yes"
 139 ],[
 140   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 141   BUILD_EXTERNAL="no"
 142 ])
 143 # make BUILD_EXTERNAL available to Makefile.am
 144 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 145
 146 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 147 dnl read 'builds, but might not work'UTO
 148 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 149 [HAVE_EXPERIMENTAL=yes],disabled,
 150 [
 151   AC_MSG_WARN(building experimental plug-ins)
 152   USE_TARKIN="yes"
 153 ],[
 154   AC_MSG_NOTICE(not building experimental plug-ins)
 155   USE_TARKIN="no"
 156 ])
 157
 158 dnl broken plug-ins; stuff that doesn't seem to build at the moment
 159 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
 160 HAVE_BROKEN=yes,disabled,
 161 [
 162   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
 163 ],[
 164   AC_MSG_NOTICE([not building broken plug-ins])
 165 ])
 166
 167 dnl ##############################
 168 dnl # Do automated configuration #
 169 dnl ##############################
 170
 171 dnl Check for tools:
 172 dnl ================
 173
 174 dnl allow for different autotools
 175 AS_AUTOTOOLS_ALTERNATE()
 176
 177 dnl modify pkg-config path
 178 AC_ARG_WITH(pkg-config-path,
 179    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 180    [export PKG_CONFIG_PATH=${withval}])
 181
 182 GST_DOC()
 183 dnl check architecture
 184 GST_ARCH()
 185
 186 dnl check for gconftool-2
 187
 188 dnl this macro defines an am conditional, so it needs to be run always
 189 AM_GCONF_SOURCE_2
 190
 191 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 192 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 193   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 194   if test x$GCONFTOOL = xno; then
 195     AC_MSG_WARN(Not installing GConf schemas)
 196     HAVE_GCONFTOOL="no"
 197   else
 198     HAVE_GCONFTOOL="yes"
 199   fi
 200   AC_SUBST(HAVE_GCONFTOOL)
 201 ])
 202
 203 dnl check for GConf libraries
 204 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 205 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 206   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 207   AC_SUBST(GCONF_CFLAGS)
 208   AC_SUBST(GCONF_LIBS)
 209 ])
 210
 211 dnl check for gstreamer
 212 dnl uninstalled is selected preferentially -- see pkg-config(1)
 213 GST_REQ=0.9.0.1
 214 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_REQ,
 215   HAVE_GST="yes", HAVE_GST="no")
 216
 217 if test "x$HAVE_GST" = "xno"; then
 218   AC_MSG_ERROR(no GStreamer found)
 219 fi
 220
 221 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 dnl check for gstreamer-base; uninstalled is selected preferentially
 228 PKG_CHECK_MODULES(GST_BASE, gstreamer-base-$GST_MAJORMINOR >= $GST_REQ,
 229   HAVE_GST_BASE="yes", HAVE_GST_BASE="no")
 230
 231 if test "x$HAVE_GST_BASE" = "xno"; then
 232   AC_MSG_ERROR(no GStreamer Base Libs found)
 233 fi
 234
 235 AC_SUBST(GST_BASE_LIBS)
 236 AC_SUBST(GST_BASE_CFLAGS)
 237
 238 dnl check for gstreamer-plugins-base; uinstalled is selected preferentially
 239 PKG_CHECK_MODULES(GST_PLUGINS_BASE,
 240   gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_REQ,
 241   HAVE_GST_PLUGINS_BASE="yes", HAVE_GST_PLUGINS_BASE="no")
 242
 243 if test "x$HAVE_GST_PLUGINS_BASE" = "xno"; then
 244   AC_MSG_ERROR(no GStreamer Base Plugins development files found)
 245 fi
 246
 247 AC_SUBST(GST_PLUGINS_BASE_LIBS)
 248 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 249
 250 dnl Determine endianness
 251 AC_C_BIGENDIAN
 252
 253 dnl Check for fast float to int casting as defined in C99
 254 AC_C99_FUNC_LRINT()
 255 AC_C99_FUNC_LRINTF()
 256
 257 dnl Check for essential libraries first:
 258 dnl ====================================
 259
 260 GST_GLIB2_CHECK()
 261
 262 dnl Check for additional libraries that we might use:
 263 dnl =================================================
 264
 265 # we set the defaults always to make sure we have non-empty variables
 266 # for the Makefile
 267
 268 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.0, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 269 AC_SUBST(LIBOIL_CFLAGS)
 270 AC_SUBST(LIBOIL_LIBS)
 271 if test "x${HAVE_LIBOIL}" = xyes ; then
 272   #AC_DEFINE_UNQUOTED(HAVE_LIBOIL, 1, [Define if liboil is being used])
 273   true
 274 fi
 275
 276 dnl ===========================================================================
 277 dnl ============================= gst plug-ins ================================
 278 dnl ===========================================================================
 279
 280 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 281 AC_SUBST(plugindir)
 282
 283 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '[_]*(gst_|Gst|GST_).*' $GST_LIBS"
 284 AC_SUBST(GST_PLUGIN_LDFLAGS)
 285
 286 dnl these are all the gst plug-ins, compilable without additional libs
 287 GST_PLUGINS_ALL="\
 288                 videofilter \
 289                 alpha \
 290                 autodetect \
 291                 avi \
 292                 effectv \
 293                 fdsrc \
 294                 goom \
 295                 law \
 296                 level \
 297                 qtdemux \
 298                 realmedia \
 299                 rtp     \
 300                 rtsp    \
 301                 smpte   \
 302                 silence \
 303                 udp     \
 304                 videobox \
 305                 wavparse \
 306                 "
 307
 308 dnl see if we can build C++ plug-ins
 309 if test "x$HAVE_CXX" = "xyes"; then
 310   GST_PLUGINS_ALL="$GST_PLUGINS_ALL"
 311 else
 312   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 313 fi
 314
 315 AC_SUBST(GST_PLUGINS_ALL)
 316
 317 GST_PLUGINS_SELECTED=""
 318
 319 AC_ARG_WITH(plugins,
 320     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 321     [for i in `echo $withval | tr , ' '`; do
 322         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 323         then
 324             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 325         else
 326             echo "plug-in $i not recognized, ignoring..."
 327         fi
 328     done],
 329     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 330
 331 AC_SUBST(GST_PLUGINS_SELECTED)
 332
 333 dnl ==========================================================================
 334 dnl ============================= sys plug-ins ================================
 335 dnl ==========================================================================
 336
 337 dnl *** OSS audio *** (Linux, *BSD)
 338 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 339 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 340  HAVE_OSS="yes"
 341 dnl Linux and newer BSD versions :
 342  AC_CHECK_HEADER(sys/soundcard.h, [
 343    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 344    ] , [
 345 dnl Some old BSD versions :
 346    AC_CHECK_HEADER(soundcard.h, [
 347      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 348      ], [
 349   dnl Some old BSD versions :
 350      AC_CHECK_HEADER(machine/soundcard.h, [
 351        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,, [Define if OSS includes are in /machine/])
 352        ], [
 353        HAVE_OSS="no"
 354      ])
 355    ])
 356  ])
 357 ])
 358
 359 dnl ###########################
 360 dnl # Configure external libs #
 361 dnl ###########################
 362
 363 dnl *** aalib ***
 364 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 365 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 366   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 367   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 368 ])
 369
 370 dnl *** AMR-NB ***
 371 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 372 GST_CHECK_FEATURE(AMRNB, [AMR-NB], amrnbdec amrnbenc, [
 373   GST_CHECK_LIBHEADER(AMRNB, amrnb,
 374                       Decoder_Interface_init, -lm,
 375                       amrnb/interf_dec.h,
 376                       AMRNB_LIBS="-lamrnb -lm"
 377                       AC_SUBST(AMRNB_LIBS))
 378 ])
 379
 380 dnl **** Free AAC Decoder (FAAD) ****
 381 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 382 GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 383   HAVE_FAAD="yes"
 384   GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h, FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 385   if test $HAVE_FAAD = "yes"; then
 386     AC_MSG_CHECKING([Checking for FAAD >= 2])
 387     AC_TRY_RUN([
 388
 389 #include <faad.h>
 390 #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 391 #error Not faad2
 392 #else
 393 #include <string.h>
 394
 395 int main()
 396 {
 397 char version[9] = FAAD2_VERSION;
 398 // a release candidate of 2.0 is not enought for us
 399 if ( strstr( version, "2.0 RC" ) ) { return 1; }
 400
 401 return 0;
 402 }
 403
 404 #endif
 405     ],
 406        [ HAVE_FAAD="yes" && AC_MSG_RESULT(yes)],
 407        [ HAVE_FAAD="no"  && AC_MSG_RESULT(no)])
 408   fi;
 409   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 410   AC_SUBST(FAAD_LIBS)
 411 ])
 412
 413 dnl *** lame ***
 414 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 415 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 416   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h,
 417   [
 418     HAVE_LAME="yes"
 419     LAME_LIBS="-lmp3lame -lm"
 420     dnl is lame presets available
 421     LAME_CFLAGS=""
 422     AC_TRY_RUN([
 423 #include <lame/lame.h>
 424 int main (int argc, char *argv[])
 425 {
 426   printf("%d\n", MEDIUM);
 427   return 0;
 428 }
 429       ],
 430       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 431       [LAME_CFLAGS=""]
 432     )
 433   AC_SUBST(LAME_CFLAGS)
 434   AC_SUBST(LAME_LIBS)
 435   ])
 436 ])
 437
 438 dnl *** libcaca ***
 439 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 440 GST_CHECK_FEATURE(LIBCACA, [libcaca], libcaca, [
 441   GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 442   AC_SUBST(LIBCACA_CFLAGS)
 443   AC_SUBST(LIBCACA_LIBS)
 444 ])
 445
 446 dnl *** libdv ***
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 448 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
 449   PKG_CHECK_MODULES(LIBDV, libdv >= 0.100, HAVE_LIBDV="yes", HAVE_LIBDV="no")
 450   AC_SUBST(LIBDV_CFLAGS)
 451   AC_SUBST(LIBDV_LIBS)
 452 ])
 453
 454 dnl *** shout2 ***
 455 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 456 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
 457   PKG_CHECK_MODULES(SHOUT2, shout >= 2.0, [
 458     HAVE_SHOUT2="yes"
 459     AC_SUBST(SHOUT2_CFLAGS)
 460     AC_SUBST(SHOUT2_LIBS)
 461   ], [
 462     AM_PATH_SHOUT2(HAVE_SHOUT2="yes", HAVE_SHOUT2="no")
 463     AC_SUBST(SHOUT2_CFLAGS)
 464     AC_SUBST(SHOUT2_LIBS)
 465   ])
 466 ])
 467
 468 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 469 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 470 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
 471   GST_PATH_SIDPLAY()
 472 ])
 473
 474 dnl *** jpeg ***
 475 dnl FIXME: we could use header checks here as well IMO
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 477 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
 478   AC_ARG_WITH(jpeg-mmx,
 479     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 480   OLD_LIBS="$LIBS"
 481   if test x$with_jpeg_mmx != x; then
 482     LIBS="$LIBS -L$with_jpeg_mmx"
 483   fi
 484   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 485   JPEG_LIBS="$LIBS -ljpeg-mmx"
 486   LIBS="$OLD_LIBS"
 487   if test x$HAVE_JPEG != xyes; then
 488     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 489     JPEG_LIBS="-ljpeg"
 490   fi
 491   AC_SUBST(JPEG_LIBS)
 492 ])
 493
 494
 495 dnl *** mad ***
 496 dnl FIXME: we could use header checks here as well IMO
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 498 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 499   dnl check with pkg-config first
 500   PKG_CHECK_MODULES(MAD, mad >= 0.15 id3tag >= 0.15, HAVE_MAD="yes", HAVE_MAD="no")
 501   if test "x$HAVE_MAD" = "xno"; then
 502     dnl fall back to oldskool detection
 503     AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
 504     if test "x$HAVE_MAD" = "xyes"; then
 505       HAVE_MAD="no"
 506       save_LIBS=$LIBS
 507       LIBS="-lz"
 508       AC_CHECK_LIB(id3tag, id3_tag_options, HAVE_MAD="yes" MAD_LIBS="-lmad -lid3tag -lz")
 509       LIBS=$save_LIBS
 510     fi
 511   fi
 512 ])
 513 AC_SUBST(MAD_LIBS)
 514
 515 dnl *** mpeg2dec ***
 516 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 517 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 518   PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0,
 519       HAVE_MPEG2DEC="yes", HAVE_MPEG2DEC="no")
 520   AC_SUBST(MPEG2DEC_CFLAGS)
 521   AC_SUBST(MPEG2DEC_LIBS)
 522 ])
 523
 524 dnl *** dv1394 ***
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 526 GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], dv1394src, [
 527   dnl we need to test three headers and three libs
 528   GST_CHECK_LIBHEADER(RAW1394,
 529     raw1394, raw1394_new_handle,,
 530     libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
 531   GST_CHECK_LIBHEADER(AVC1394,
 532     avc1394, avc1394_send_command, $RAW1394_LIBS,
 533     libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 534   GST_CHECK_LIBHEADER(ROM1394,
 535     rom1394, rom1394_free_directory, $RAW1394_LIBS,
 536     libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 537
 538   dnl now see how far we got
 539   if test x$HAVE_RAW1394 = xyes && \
 540      test x$HAVE_AVC1394 = xyes && \
 541      test x$HAVE_ROM1394 = xyes; then
 542        HAVE_DV1394=yes
 543        DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 544        AC_SUBST(DV1394_LIBS)
 545   else
 546        HAVE_DV1394=no
 547   fi
 548 ])
 549
 550 dnl **** ESound ****
 551 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 552 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink, [
 553   PKG_CHECK_MODULES(ESD, esound >= 0.2.12, [
 554     HAVE_ESD="yes"
 555     AC_SUBST(ESD_CFLAGS)
 556     AC_SUBST(ESD_LIBS)
 557   ], [
 558     AM_PATH_ESD(0.2.12, HAVE_ESD="yes", HAVE_ESD="no")
 559     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 560   ])
 561 ])
 562
 563 dnl *** libpng ***
 564 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 565 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
 566   PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
 567   AC_SUBST(LIBPNG_CFLAGS)
 568   AC_SUBST(LIBPNG_LIBS)
 569 ])
 570
 571
 572
 573 dnl also add builddir include for enumtypes and marshal
 574 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GST_ERROR"
 575
 576 AC_SUBST(GST_LIBS)
 577 AC_SUBST(GST_CFLAGS)
 578
 579 dnl ############################
 580 dnl # Set up some more defines #
 581 dnl ############################
 582
 583 dnl set license and copyright notice
 584 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 585
 586 dnl package name in plugins
 587 AC_ARG_WITH(package-name,
 588 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 589 [case "${withval}" in
 590   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 591   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 592   *) GST_PACKAGE="${withval}" ;;
 593 esac],
 594 [
 595 dnl default value
 596 if test "x$GST_CVS" = "xyes"
 597 then
 598   dnl nano >= 1
 599   GST_PACKAGE="GStreamer CVS/prerelease"
 600 else
 601   GST_PACKAGE="GStreamer source release"
 602 fi
 603 ]
 604 )
 605 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 606 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 607
 608 dnl package origin URL
 609 AC_ARG_WITH(package-origin,
 610 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 611 [case "${withval}" in
 612   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 613   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 614   *) GST_ORIGIN="${withval}" ;;
 615 esac],
 616 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 617 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 618 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 619
 620 dnl #########################
 621 dnl # Make the output files #
 622 dnl #########################
 623
 624 AC_CONFIG_FILES(
 625 Makefile
 626 gst-plugins.spec
 627 gst/Makefile
 628 gst/alpha/Makefile
 629 gst/autodetect/Makefile
 630 gst/avi/Makefile
 631 gst/effectv/Makefile
 632 gst/fdsrc/Makefile
 633 gst/goom/Makefile
 634 gst/law/Makefile
 635 gst/level/Makefile
 636 gst/realmedia/Makefile
 637 gst/rtp/Makefile
 638 gst/rtsp/Makefile
 639 gst/smpte/Makefile
 640 gst/silence/Makefile
 641 gst/udp/Makefile
 642 gst/videobox/Makefile
 643 gst/videofilter/Makefile
 644 ext/jpeg/Makefile
 645 gst/qtdemux/Makefile
 646 gst/wavparse/Makefile
 647 gst-libs/Makefile
 648 gst-libs/gst/Makefile
 649 sys/Makefile
 650 sys/oss/Makefile
 651 ext/Makefile
 652 ext/aalib/Makefile
 653 ext/dv/Makefile
 654 ext/gconf/Makefile
 655 ext/lame/Makefile
 656 ext/libcaca/Makefile
 657 ext/libpng/Makefile
 658 ext/mad/Makefile
 659 ext/raw1394/Makefile
 660 ext/shout2/Makefile
 661 ext/sidplay/Makefile
 662 ext/esd/Makefile
 663 ext/mpeg2dec/Makefile
 664 ext/faad/Makefile
 665 ext/amrnb/Makefile
 666 po/Makefile.in
 667 common/Makefile
 668 common/m4/Makefile
 669 m4/Makefile
 670 )
 671 AC_OUTPUT
 672
 673 echo -n "configure: *** Plug-ins that will be built :"
 674 echo -e "$GST_PLUGINS_YES" | sort
 675 echo
 676 echo -n "configure: *** Plug-ins that will not be built :"
 677 echo -e "$GST_PLUGINS_NO" | sort
 678 echo
 679 if test "x$BUILD_EXTERNAL" = "xno"; then
 680   echo "configure: *** No external plug-ins will be built"
 681 fi