configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Ugly Plug-ins, 0.10.15.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-ugly)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER(config.h)
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS([CXX])
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.26
  56 GSTPB_REQ=0.10.26
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION(0.17)
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-ugly-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl check if the compiler supports '-c' and '-o' options
 113 AM_PROG_CC_C_O
 114
 115 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 116 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 117
 118 dnl check if the compiler supports do while(0) macros
 119 AG_GST_CHECK_DOWHILE_MACROS
 120
 121 dnl check for documentation tools
 122 GTK_DOC_CHECK([1.3])
 123 AS_PATH_PYTHON([2.1])
 124 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 125
 126 dnl *** checks for libraries ***
 127
 128 dnl check for libm, for sin()
 129 AC_CHECK_LIBM
 130 AC_SUBST(LIBM)
 131
 132 dnl *** checks for header files ***
 133
 134 dnl used by ext/a52dec
 135 AX_CREATE_STDINT_H
 136
 137 dnl Check for malloc.h
 138 AC_CHECK_HEADERS([malloc.h])
 139
 140 dnl *** checks for types/defines ***
 141
 142 dnl *** checks for structures ***
 143
 144 dnl *** checks for compiler characteristics ***
 145
 146 dnl *** checks for library functions ***
 147
 148 dnl Check for a way to display the function name in debug output
 149 AG_GST_CHECK_FUNCTION
 150
 151 dnl *** checks for dependency libraries ***
 152
 153 dnl GLib is required
 154 AG_GST_GLIB_CHECK([2.20])
 155 ORC_CHECK([0.4.5])
 156
 157 dnl checks for gstreamer
 158 dnl uninstalled is selected preferentially -- see pkg-config(1)
 159 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 160 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 161 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 162 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 163 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 164
 165 dnl Check for documentation xrefs
 166 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 167 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 168 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 169 AC_SUBST(GLIB_PREFIX)
 170 AC_SUBST(GST_PREFIX)
 171 AC_SUBST(GSTPB_PREFIX)
 172
 173 dnl *** set variables based on configure arguments ***
 174
 175 dnl set license and copyright notice
 176 GST_LICENSE="LGPL"
 177 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 178 AC_SUBST(GST_LICENSE)
 179
 180 dnl set location of plugin directory
 181 AG_GST_SET_PLUGINDIR
 182
 183 dnl define an ERROR_CFLAGS Makefile variable
 184 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 185     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 186     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 187     -Winit-self -Wmissing-include-dirs -Waddress
 188     -Waggregate-return -Wno-multichar -Wnested-externs ])
 189
 190 dnl define an ERROR_CXXFLAGS Makefile variable
 191 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 192     -Wmissing-declarations -Wredundant-decls
 193     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 194     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 195     -Wno-multichar])
 196
 197 dnl define correct level for debugging messages
 198 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 199
 200 dnl used in examples
 201 AG_GST_DEFAULT_ELEMENTS
 202
 203 dnl *** plug-ins to include ***
 204
 205 dnl these are all the gst plug-ins, compilable without additional libs
 206 AG_GST_CHECK_PLUGIN(asfdemux)
 207 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 208 AG_GST_CHECK_PLUGIN(dvdsub)
 209 AG_GST_CHECK_PLUGIN(iec958)
 210 AG_GST_CHECK_PLUGIN(mpegaudioparse)
 211 AG_GST_CHECK_PLUGIN(mpegstream)
 212 AG_GST_CHECK_PLUGIN(realmedia)
 213 AG_GST_CHECK_PLUGIN(synaesthesia)
 214
 215 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 216
 217 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 218   WIN32_LIBS="-lws2_32"
 219   AC_SUBST(WIN32_LIBS)
 220 fi
 221
 222 dnl disable experimental plug-ins
 223 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 224   AG_GST_DISABLE_PLUGIN(synaesthesia)
 225 fi
 226
 227 dnl *** ext plug-ins ***
 228 dnl keep this list sorted alphabetically !
 229
 230 if test "x$BUILD_EXTERNAL" = "xyes"; then
 231
 232 echo
 233 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 234 echo
 235
 236 dnl *** a52dec ***
 237 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 238 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 239   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 240 ])
 241
 242 dnl *** amr-nb ***
 243 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 244 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 245   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, HAVE_AMRNB="yes",
 246       [ AG_GST_CHECK_LIBHEADER(AMRNB, opencore-amrnb,
 247                            Decoder_Interface_init, -lm,
 248                            opencore-amrnb/interf_dec.h,
 249                            AMRNB_LIBS="-lopencore-amrnb")
 250       ])
 251   AC_SUBST(AMRNB_CFLAGS)
 252   AC_SUBST(AMRNB_LIBS)
 253 ])
 254
 255 dnl *** amr-wb dec ***
 256 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 257 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 258   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, HAVE_AMRWB="yes",
 259       [ AG_GST_CHECK_LIBHEADER(AMRWB, opencore-amrwb,
 260                            D_IF_decode, ,
 261                            opencore-amrwb/dec_if.h,
 262                            AMRWB_LIBS="-lopencore-amrwb")
 263       ])
 264   AC_SUBST(AMRWB_CFLAGS)
 265   AC_SUBST(AMRWB_LIBS)
 266 ])
 267
 268 dnl *** cdio ***
 269 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 270 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 271   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 272 ])
 273
 274 dnl *** dvdread ***
 275 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 276 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 277   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 278   AC_SUBST(DVDREAD_LIBS)
 279 ])
 280
 281 dnl *** lame ***
 282 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 283 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 284   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h,
 285   [
 286     HAVE_LAME="yes"
 287     LAME_LIBS="-lmp3lame -lm"
 288     dnl is lame presets available
 289     LAME_CFLAGS=""
 290     AC_TRY_COMPILE([#include <lame/lame.h>], [ int preset = MEDIUM ],
 291       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 292       [LAME_CFLAGS=""]
 293     )
 294     AC_TRY_COMPILE([#include <lame/lame.h>], [
 295         void *ptr = &lame_set_VBR_quality
 296       ],
 297       [LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],
 298       [LAME_CFLAGS="$LAME_CFLAGS"]
 299     )
 300   AC_SUBST(LAME_CFLAGS)
 301   AC_SUBST(LAME_LIBS)
 302   ])
 303 ])
 304
 305 dnl *** mad ***
 306 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 307 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 308
 309   dnl check with pkg-config first
 310   AG_GST_PKG_CHECK_MODULES(ID3TAG, id3tag >= 0.15)
 311   if test "x$HAVE_ID3TAG" = "xno"; then
 312     dnl fall back to oldskool detection
 313     AC_CHECK_HEADER(id3tag.h, [
 314       save_LIBS=$LIBS
 315       LIBS="-lz"
 316       AC_CHECK_LIB(id3tag, id3_tag_options,
 317         HAVE_ID3TAG="yes" ID3TAG_LIBS="-lid3tag -lz")
 318       LIBS=$save_LIBS
 319       AC_SUBST(ID3TAG_LIBS)
 320     ])
 321   fi
 322
 323   if test "x$HAVE_ID3TAG" = "xyes"; then
 324     dnl check with pkg-config first
 325     AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 326     MAD_LIBS="$MAD_LIBS $ID3TAG_LIBS"
 327     if test "x$HAVE_MAD" = "xno"; then
 328       dnl fall back to oldskool detection
 329       AC_CHECK_HEADER(mad.h, [
 330         AC_CHECK_LIB(mad, mad_decoder_finish,
 331           HAVE_MAD="yes" MAD_LIBS="-lmad $ID3TAG_LIBS")
 332       ])
 333     fi
 334   else
 335     HAVE_MAD="no"
 336     AC_MSG_WARN([libid3tag not available, cannot build MAD MP3 decoder plugin])
 337   fi
 338 ])
 339 AC_SUBST(MAD_LIBS)
 340
 341 dnl *** mpeg2dec ***
 342 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 343 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 344   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 345 ])
 346
 347 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 348 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 349 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 350   GST_PATH_SIDPLAY()
 351 ])
 352
 353 dnl *** twolame ***
 354 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 355 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 356   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 357       HAVE_TWOLAME="yes"], [
 358       HAVE_TWOLAME="no"
 359       AC_MSG_RESULT(no)
 360   ])
 361   AC_SUBST(TWOLAME_CFLAGS)
 362   AC_SUBST(TWOLAME_LIBS)
 363 ])
 364
 365 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 366 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 367 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 368   AG_GST_CHECK_LIBHEADER(X264, x264, x264_encoder_encode, -lm, x264.h,
 369       AC_MSG_CHECKING([for uptodate x264 API version])
 370       dnl _stdint not yet generated, so no compiling
 371       AC_TRY_CPP([
 372         #include <x264.h>
 373         #if X264_BUILD < 55
 374         #error "x264 build too old"
 375         #endif
 376       ], [
 377         AC_MSG_RESULT(yes)
 378         X264_LIBS="$LDFLAGS -lx264 -lm"
 379         X264_CFLAGS="$CFLAGS"
 380         AC_SUBST(X264_LIBS)
 381         AC_SUBST(X264_CFLAGS)
 382       ], [
 383         AC_MSG_RESULT(no)
 384         HAVE_X264=no
 385       ]))
 386 ])
 387
 388 else
 389
 390 dnl not building plugins with external dependencies,
 391 dnl but we still need to set the conditionals
 392
 393 AM_CONDITIONAL(USE_A52DEC, false)
 394 AM_CONDITIONAL(USE_AMRNB, false)
 395 AM_CONDITIONAL(USE_AMRWB, false)
 396 AM_CONDITIONAL(USE_CDIO, false)
 397 AM_CONDITIONAL(USE_DVDREAD, false)
 398 AM_CONDITIONAL(USE_LAME, false)
 399 AM_CONDITIONAL(USE_MAD, false)
 400 AM_CONDITIONAL(USE_MPEG2DEC, false)
 401 AM_CONDITIONAL(USE_SIDPLAY, false)
 402 AM_CONDITIONAL(USE_TWOLAME, false)
 403 AM_CONDITIONAL(USE_X264, false)
 404
 405 fi dnl of EXT plugins
 406
 407 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 408
 409 dnl Overview:
 410 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 411 dnl GST_*:              flags shared by built objects to link against GStreamer
 412 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 413 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 414 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 415 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 416
 417 dnl GST_OPTION_CFLAGS
 418 if test "x$USE_DEBUG" = xyes; then
 419    PROFILE_CFLAGS="-g"
 420 fi
 421 AC_SUBST(PROFILE_CFLAGS)
 422
 423 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 424   dnl Define _only_ during CVS (not pre-releases or releases)
 425   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 426 else
 427   DEPRECATED_CFLAGS=""
 428 fi
 429 AC_SUBST(DEPRECATED_CFLAGS)
 430
 431 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 432 dnl at make time with e.g. make ERROR_CFLAGS=""
 433 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 434 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 435 AC_SUBST(GST_OPTION_CFLAGS)
 436 AC_SUBST(GST_OPTION_CXXFLAGS)
 437
 438 dnl FIXME: do we want to rename to GST_ALL_* ?
 439 dnl prefer internal headers to already installed ones
 440 dnl also add builddir include for enumtypes and marshal
 441 dnl add GST_OPTION_CFLAGS, but overridable
 442 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 443 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 444 AC_SUBST(GST_CFLAGS)
 445 AC_SUBST(GST_CXXFLAGS)
 446 AC_SUBST(GST_LIBS)
 447
 448 dnl LDFLAGS really should only contain flags, not libs - they get added before
 449 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 450 GST_ALL_LDFLAGS="-no-undefined"
 451 AC_SUBST(GST_ALL_LDFLAGS)
 452
 453 dnl this really should only contain flags, not libs - they get added before
 454 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 455 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 456 AC_SUBST(GST_PLUGIN_LDFLAGS)
 457
 458 dnl *** output files ***
 459
 460 AC_CONFIG_FILES(
 461 Makefile
 462 common/Makefile
 463 common/m4/Makefile
 464 gst-libs/Makefile
 465 gst-libs/gst/Makefile
 466 gst/Makefile
 467 gst/asfdemux/Makefile
 468 gst/dvdlpcmdec/Makefile
 469 gst/dvdsub/Makefile
 470 gst/iec958/Makefile
 471 gst/mpegaudioparse/Makefile
 472 gst/mpegstream/Makefile
 473 gst/realmedia/Makefile
 474 gst/synaesthesia/Makefile
 475 ext/Makefile
 476 ext/a52dec/Makefile
 477 ext/amrnb/Makefile
 478 ext/amrwbdec/Makefile
 479 ext/cdio/Makefile
 480 ext/dvdread/Makefile
 481 ext/lame/Makefile
 482 ext/mad/Makefile
 483 ext/mpeg2dec/Makefile
 484 ext/sidplay/Makefile
 485 ext/twolame/Makefile
 486 ext/x264/Makefile
 487 docs/Makefile
 488 docs/plugins/Makefile
 489 docs/version.entities
 490 tests/Makefile
 491 tests/check/Makefile
 492 m4/Makefile
 493 po/Makefile.in
 494 gst-plugins-ugly.spec
 495 )
 496
 497 dnl Create the config.h file for Visual Studio builds
 498 dnl Beware of spaces and /'s in some of the shell variable contents.
 499 sed \
 500     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 501     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 502     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 503     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 504     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 505     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 506     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 507     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 508     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 509     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 510     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 511     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 512     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 513     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 514     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 515     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 516     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 517     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 518     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 519     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 520     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 521     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 522     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 523     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 524     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 525     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 526     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 527     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 528     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 529     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 530     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 531     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
 532     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 533     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 534     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 535     config.h.in >win32/common/config.h-new
 536
 537 AC_OUTPUT
 538
 539 AG_GST_OUTPUT_PLUGINS
 540
 541 ORC_OUTPUT