1 dnl autoconf configuration file for gst-plugins
2 AC_INIT
3 AC_CANONICAL_TARGET([])
5 dnl We disable static building for development, for time savings
6 dnl this goes before AS_LIBTOOL to appease autoconf
7 dnl *NOTE*: dnl this line before release, so release does static too
8 AM_DISABLE_STATIC
10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
11 AM_MAINTAINER_MODE
13 dnl when going to/from release please set the nano (fourth number) right !
14 dnl releases only do Wall, cvs and prerelease does Werror too
15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 7, 0, 1, GST_CVS="no", GST_CVS="yes")
16 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
18 dnl our libraries and install dirs use major.minor as a version
19 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
20 AC_SUBST(GST_MAJORMINOR)
22 dnl CURRENT, REVISION, AGE
23 dnl - library source changed -> increment REVISION
24 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
25 dnl - interfaces added -> increment AGE
26 dnl - interfaces removed -> AGE = 0
27 AS_LIBTOOL(GST_PLUGINS, 1, 0, 0)
29 dnl FIXME take something else ?
30 AC_CONFIG_SRCDIR([gst/law/alaw.c])
31 AM_CONFIG_HEADER(config.h)
33 dnl Add parameters for aclocal
34 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
35 ACLOCAL_FLAGS="-I m4 -I common/m4"
36 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
38 AC_PROG_CC
39 AM_PROG_CC_STDC
40 AM_PROG_AS
41 AS="${CC}"
43 dnl decide on error flags
44 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
46 if test "x$GST_WALL" = "xyes"; then
47 GST_ERROR="$GST_ERROR -Wall"
49 if test "x$GST_CVS" = "xyes"; then
50 AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
51 fi
53 dnl set gcc-style optimization flags if using the gnu compiler.
54 GST_FUNROLL_CFLAGS="$GST_FUNROLL_CFLAGS -funroll-all-loops"
55 GST_FINLINE_CFLAGS="$GST_FINLINE_CFLAGS -finline-functions"
56 GST_FFASTMATH_CFLAGS="$GST_FFASTMATH_CFLAGS -ffast-math"
57 GST_FSCHEDULE_CFLAGS="$GST_FSCHEDULE_CFLAGS -fschedule-insns2"
58 GST_FNOEXCEPTIONS_CFLAGS="$GST_FNOEXCEPTIONS_CFLAGS -fno-exceptions"
59 fi
61 dnl determine c++ compiler
62 AC_PROG_CXX
63 dnl determine if c++ is available on this system
64 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
65 dnl determine c++ preprocessor
66 AC_PROG_CXXCPP
67 AC_ISC_POSIX
69 AC_HEADER_STDC([])
71 dnl ############################################
72 dnl # Super Duper options for plug-in building #
73 dnl ############################################
75 dnl ext plug-ins; plug-ins that have external dependencies
76 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
77 [HAVE_EXTERNAL=yes],enabled,
78 [
79 AC_MSG_WARN(building external plug-ins)
80 BUILD_EXTERNAL="yes"
81 ],[
82 AC_MSG_WARN(all plug-ins with external dependencies will not be built)
83 BUILD_EXTERNAL="no"
84 ])
85 # make BUILD_EXTERNAL available to Makefile.am
86 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
88 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
89 dnl read 'builds, but might not work'UTO
90 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
91 [HAVE_EXPERIMENTAL=yes],disabled,
92 [
93 AC_MSG_WARN(building experimental plug-ins)
94 USE_TARKIN="yes"
95 USE_SHOUT2="yes"
96 ],[
97 AC_MSG_NOTICE(not building experimental plug-ins)
98 USE_TARKIN="no"
99 USE_SHOUT2="no"
100 ])
102 dnl broken plug-ins; stuff that doesn't seem to build at the moment
103 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
104 HAVE_BROKEN=yes,disabled,
105 [
106 AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
107 USE_SMOOTHWAVE="yes"
108 ],[
109 USE_SMOOTHWAVE="no"
110 AC_MSG_NOTICE([not building broken plug-ins])
111 ])
113 dnl ##############################
114 dnl # Do automated configuration #
115 dnl ##############################
117 dnl Check for tools:
118 dnl ================
120 dnl allow for different autotools
121 AS_AUTOTOOLS_ALTERNATE()
123 dnl modify pkg-config path
124 AC_ARG_WITH(pkg-config-path,
125 AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
126 [export PKG_CONFIG_PATH=${withval}])
128 dnl Check for nasm
129 AC_PATH_PROG(NASM_PATH, nasm, no)
130 AC_SUBST(NASM_PATH)
131 if test x$NASM_PATH = xno; then
132 AC_MSG_WARN(Couldn't find nasm)
133 HAVE_NASM="no"
134 else
135 AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
136 HAVE_NASM="yes"
137 fi
139 dnl check for gconftool-2
140 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
141 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
142 AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
143 if test x$GCONFTOOL = xno; then
144 AC_MSG_WARN(Not installing GConf schemas)
145 HAVE_GCONFTOOL="no"
146 else
147 AM_GCONF_SOURCE_2
148 HAVE_GCONFTOOL="yes"
149 fi
150 AC_SUBST(HAVE_GCONFTOOL)
151 ])
153 dnl check for GConf libraries
154 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
155 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
156 PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
157 AC_SUBST(GCONF_CFLAGS)
158 AC_SUBST(GCONF_LIBS)
159 ])
161 dnl check for gstreamer; uninstalled is selected preferentially -- see pkg-config(1)
162 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR.$GST_PLUGINS_VERSION_MICRO,
163 HAVE_GST="yes", HAVE_GST="no")
165 if test "x$HAVE_GST" = "xno"; then
166 AC_MSG_ERROR(no GStreamer found)
167 fi
169 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
170 if test -z $GST_TOOLS_DIR; then
171 AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
172 fi
173 AC_SUBST(GST_TOOLS_DIR)
175 dnl check for gstreamer-control; uninstalled is selected preferentially
176 PKG_CHECK_MODULES(GST_CONTROL, gstreamer-control-$GST_MAJORMINOR >= $GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR.$GST_PLUGINS_VERSION_MICRO,
177 HAVE_GST_CONTROL="yes", HAVE_GST_CONTROL="no")
179 if test "x$HAVE_GST_CONTROL" = "xno"; then
180 AC_MSG_ERROR(no GStreamer Control Libs found)
181 fi
183 AC_SUBST(GST_CONTROL_LIBS)
186 dnl Set up conditionals for (target) architecture:
187 dnl ==============================================
189 dnl Determine CPU
190 case "x${target_cpu}" in
191 xi?86 | k?) HAVE_CPU_I386=yes
192 AC_DEFINE(HAVE_CPU_I386, 1, [Define if the target CPU is an x86])
193 dnl FIXME could use some better detection
194 dnl (ie CPUID)
195 case "x${target_cpu}" in
196 xi386 | xi486) ;;
197 *) AC_DEFINE(HAVE_RDTSC, 1, [Define if RDTSC is available]) ;;
198 esac ;;
199 xpowerpc) HAVE_CPU_PPC=yes
200 AC_DEFINE(HAVE_CPU_PPC, 1, [Define if the target CPU is a PPC]) ;;
201 xalpha) HAVE_CPU_ALPHA=yes
202 AC_DEFINE(HAVE_CPU_ALPHA, 1, [Define if the target CPU is an Alpha]) ;;
203 xarm*) HAVE_CPU_ARM=yes
204 AC_DEFINE(HAVE_CPU_ARM, 1, [Define if the target CPU is an ARM]) ;;
205 xsparc*) HAVE_CPU_SPARC=yes
206 AC_DEFINE(HAVE_CPU_SPARC, 1, [Define if the target CPU is a PPC]) ;;
207 xmips*) HAVE_CPU_MIPS=yes
208 AC_DEFINE(HAVE_CPU_MIPS, 1, [Define if the target CPU is a MIPS]) ;;
209 xhppa*) HAVE_CPU_HPPA=yes
210 AC_DEFINE(HAVE_CPU_HPPA, 1, [Define if the target CPU is a HPPA]) ;;
211 esac
213 dnl Determine endianness
214 AC_C_BIGENDIAN
216 dnl Check for fast float to int casting as defined in C99
217 AC_C99_FUNC_LRINT()
218 AC_C99_FUNC_LRINTF()
220 dnl Check for essential libraries first:
221 dnl ====================================
223 GST_GLIB2_CHECK()
224 PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK=yes, HAVE_GTK=no)
225 GTK_CFLAGS=$GTK2_CFLAGS
226 GTK_LIBS=$GTK2_LIBS
227 AC_SUBST(GTK_LIBS)
228 AC_SUBST(GTK_CFLAGS)
231 dnl Check for X11 extensions
232 AC_PATH_XTRA
233 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
234 AC_MSG_NOTICE([cannot find X11, the build system needs fixage])
235 fi
236 AC_SUBST(X_CFLAGS)
237 AC_SUBST(X_PRE_LIBS)
238 AC_SUBST(X_EXTRA_LIBS)
239 AC_SUBST(X_LIBS)
241 dnl ===========================================================================
242 dnl ============================= gst plug-ins ================================
243 dnl ===========================================================================
245 GST_PLUGIN_LDFLAGS='-module -avoid-version'
246 AC_SUBST(GST_PLUGIN_LDFLAGS)
248 dnl these are all the gst plug-ins, compilable without additional libs
249 GST_PLUGINS_ALL="\
250 ac3parse adder audioscale auparse avi \
251 asfdemux audioconvert cdxaparse chart \
252 cutter debug deinterlace effectv festival \
253 filter flx goom intfloat law level median mixmatrix \
254 mpeg1enc mpeg1sys mpeg1videoparse mpeg2enc mpeg2sub \
255 mpegaudio mpegaudioparse mpegstream mpegtypes \
256 monoscope oneton overlay passthrough playondemand qtdemux \
257 realmedia rtp rtjpeg silence sine smooth smpte \
258 spectrum speed stereo synaesthesia udp vbidec \
259 videocrop videofilter videoflip videoscale videotestsrc \
260 volenv volume wavenc wavparse y4m"
262 dnl see if we can build C++ plug-ins
263 if test "x$HAVE_CXX" = "xyes"; then
264 GST_PLUGINS_ALL="$GST_PLUGINS_ALL \
265 modplug"
266 else
267 AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
268 fi
270 AC_SUBST(GST_PLUGINS_ALL)
272 GST_PLUGINS_SELECTED=""
274 AC_ARG_WITH(plugins,
275 AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
276 [for i in `echo $withval | tr , ' '`; do
277 if test -n `echo $i | grep $GST_PLUGINS_ALL`; then
278 GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
279 else
280 echo "plug-in $i not recognized, ignoring..."
281 fi
282 done],
283 [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
285 AC_SUBST(GST_PLUGINS_SELECTED)
287 dnl ==========================================================================
288 dnl ============================= sys plug-ins ================================
289 dnl ==========================================================================
291 dnl *** DXR3 card ***
292 translit(dnm, m, l) AM_CONDITIONAL(USE_DXR3, true)
293 GST_CHECK_FEATURE(DXR3, [DXR3 hardware MPEG DVD decoder],
294 dxr3videosink dxr3audiosink dxr3spusink, [
295 HAVE_DXR3=yes
296 AC_CHECK_HEADER(linux/em8300.h, ,
297 [ AC_MSG_WARN([DXR3/em8300 header file not found]) &&
298 HAVE_DXR3=no ] )
299 AC_CHECK_HEADER(linux/soundcard.h, ,
300 [ AC_MSG_WARN([Generic sound header file not found]) &&
301 HAVE_DXR3=no ] )
302 ])
304 dnl *** OSS audio ***
305 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
306 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
307 AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS="yes", HAVE_OSS="no")
308 ])
310 dnl *** QuickCam ***
311 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
312 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, [
313 if test "x$HAVE_CPU_I386" != "xyes";
314 then
315 HAVE_QCAM="no"
316 else
317 AC_CHECK_HEADER(sys/io.h, HAVE_QCAM="yes", HAVE_QCAM="no")
318 fi
319 if test "x$HAVE_QCAM" != "xyes";
320 then
321 AC_MSG_WARN([QuickCam only works on i386-linux])
322 fi
323 ])
325 dnl *** Video 4 Linux ***
326 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
327 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
328 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
329 AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_V4L="yes", HAVE_V4L="no", [
330 #include <sys/types.h>
331 #define _LINUX_TIME_H
332 #include <linux/videodev.h>
333 ])
334 ])
336 dnl *** Video 4 Linux 2***
337 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
338 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L2, true)
339 GST_CHECK_FEATURE(V4L2, [Video 4 Linux 2], v4l2src, [
340 AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
341 AC_TRY_COMPILE([
342 #include <sys/types.h>
343 #include <linux/types.h>
344 #define _LINUX_TIME_H
345 #include <linux/videodev2.h>
346 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
347 #error too early v4l2 version or no v4l2 at all
348 #endif
349 ], [
350 return 0;
351 ], [ HAVE_V4L2="yes" && AC_MSG_RESULT(yes)],
352 [ HAVE_V4L2="no" && AC_MSG_RESULT(no) &&
353 AC_CHECK_HEADER(linux/videodev2.h,
354 [ AC_MSG_WARN([video4linux2 headers were found, but they're old. Please update v4l2 to compile the v4l2 plugins])],
355 [ AC_MSG_WARN([video4linux2 was not found])])])
356 ])
358 dnl *** Video CD ***
359 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
360 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
361 AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
362 ])
364 dnl *** CDROM Audio ***
365 translit(dnm, m, l) AM_CONDITIONAL(USE_CDROM, true)
366 GST_CHECK_FEATURE(CDROM, [CDROM Audio], cdrom, [
367 AC_CHECK_HEADERS(linux/cdrom.h) dnl linux
368 AC_CHECK_HEADERS(sys/cdio.h) dnl almost everything else
369 dnl AC_CHECK_HEADERS(dmedia/cdaudio.h) dnl irix
371 if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes" || test "${ac_cv_header_dmedia_cdaudio_h}" = "yes"; then
372 case "$host" in
373 *-sun-* | *-*-linux*)
374 AC_DEFINE(HAVE_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
375 ;;
376 *-*-freebsd*)
377 AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
378 ;;
379 *-*-netbsd* | *-*-openbsd*)
380 AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
381 AC_DEFINE(HAVE_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
382 ;;
383 *-*darwin*)
384 AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
385 AC_DEFINE(HAVE_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
386 ;;
387 dnl *-irix-*)
388 dnl AC_DEFINE(HAVE_CDROM_IRIX,, [Define if cdrom access is in Irix DMedia style])
389 dnl ;;
390 esac
392 HAVE_CDROM="yes"
393 else
394 HAVE_CDROM="no"
395 fi
396 ])
398 dnl *** XVideo ***
399 dnl Look for the PIC library first, Debian requires it.
400 dnl Check debian-devel archives for gory details.
401 dnl 20020110:
402 dnl At the moment XFree86 doesn't distribute shared libXv due
403 dnl to unstable API. On many platforms you CAN NOT link a shared
404 dnl lib to a static non-PIC lib. This is what the xvideo GStreamer
405 dnl plug-in wants to do. So Debian distributes a PIC compiled
406 dnl version of the static lib for plug-ins to link to when it is
407 dnl inappropriate to link the main application to libXv directly.
408 dnl FIXME: add check if this platform can support linking to a
409 dnl non-PIC libXv, if not then don not use Xv.
410 dnl FIXME: perhaps warn user if they have a shared libXv since
411 dnl this is an error until XFree86 starts shipping one
412 translit(dnm, m, l) AM_CONDITIONAL(USE_XFREE, true)
413 GST_CHECK_FEATURE(XFREE, [X11 XFree86], xvideosink-X, [
414 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
415 HAVE_XFREE=no
416 else
417 HAVE_XFREE=yes
418 fi
419 ])
421 dnl Check for Xv extension
422 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
423 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions], xvideosink-Xv, [
424 if test x$HAVE_XFREE = xyes; then
425 AC_CHECK_LIB(Xv_pic, XvQueryExtension,
426 HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
427 $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
428 XVIDEO_LIBS="-lXv_pic -lXext"
430 dnl try again using something else if we didn't find it first
431 if test x$HAVE_XVIDEO = xno; then
432 AC_CHECK_LIB(Xv, XvQueryExtension,
433 HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
434 $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
435 XVIDEO_LIBS="-lXv -lXext"
436 fi
438 AC_SUBST(XVIDEO_LIBS)
439 fi
440 ])
442 dnl Next, check for the optional libraries:
443 dnl These are all libraries used in building plug-ins
444 dnl ================================================
445 dnl let's try and sort them alphabetically, shall we ?
447 if test "x$BUILD_EXTERNAL" = "xyes"; then
449 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
451 dnl *** a52dec ***
452 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
453 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
454 AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
455 ])
457 dnl *** aalib ***
458 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
459 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
460 AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
461 AS_SCRUB_INCLUDE(AALIB_CFLAGS)
462 ])
464 dnl *** alsa ***
465 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
466 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
467 AM_PATH_ALSA(0.9.0, HAVE_ALSA=yes, HAVE_ALSA=no)
468 ])
470 dnl *** arts ***
471 dnl if mcopidl can't be found there's no use in compiling it
472 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
473 if test "x$HAVE_MCOPIDL" = "xno";
474 then
475 USE_ARTS=no
476 fi
478 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
479 GST_CHECK_FEATURE(ARTS, [arts plug-ins], arts, [
480 AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
481 ])
483 dnl *** artsc ***
484 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
485 GST_CHECK_FEATURE(ARTSC, [artsd plug-ins], artsdsink, [
486 GST_CHECK_ARTSC()
487 ])
489 dnl *** audiofile ***
490 dnl this check uses the GST_CHECK_CONFIGPROG macro
491 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
492 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
493 translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
494 translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
495 dnl check with pkg-config first
496 PKG_CHECK_MODULES(AUDIOFILE, audiofile, HAVE_AUDIOFILE="yes", HAVE_AUDIOFILE="no")
497 if test "x$HAVE_AUDIOFILE" = "xno"; then
498 GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
499 dnl we need this function
500 AC_CHECK_LIB(audiofile, afOpenVirtualFile, , HAVE_AUDIOFILE="no")
501 fi])
503 dnl *** CDParanoia ***
504 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
505 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
506 GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
507 cdda_open, -lm,
508 cdda_interface.h,
509 CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
510 HEADER_DIR="no"
511 FOUND_CDPARANOIA="yes")
512 if test "x$FOUND_CDPARANOIA" != "xyes";
513 then
514 GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
515 cdda_open, -lm,
516 cdda/cdda_interface.h,
517 CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
518 HEADER_DIR="yes"
519 FOUND_CDPARANOIA="yes")
520 fi
521 if test "x$HEADER_DIR" = "xyes";
522 then
523 AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
524 defined if cdda headers are in a cdda/ directory)
525 fi
526 AC_SUBST(CDPARANOIA_LIBS)
527 ])
528 dnl FIXME : add second check somehow if that is necessary
529 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
530 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
532 dnl *** DIVX ***
533 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
534 GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
535 HAVE_DIVX=yes
536 AC_CHECK_HEADER(encore2.h, ,
537 [ AC_MSG_WARN([Divx4linux encore headers not found]) &&
538 HAVE_DIVX=no ] )
539 if [ test x$HAVE_DIVX = xyes ]; then
540 AC_MSG_CHECKING([Checking for valid divx4linux encore version])
541 AC_TRY_COMPILE([
542 #include <encore2.h>
543 #if ENCORE_VERSION != 20021024
544 #error Wrong version of divx encore libraries
545 #endif
546 ], [
547 return 0;
548 ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
549 [ HAVE_DIVX=no && AC_MSG_RESULT(no) &&
550 AC_MSG_WARN([Wrong version of divx4linux installed]) ])
551 fi
552 if [ test x$HAVE_DIVX = xyes ]; then
553 AC_CHECK_HEADER(decore.h, ,
554 [ AC_MSG_WARN([Divx4linux decoder headers not found]) &&
555 HAVE_DIVX=no ] )
556 fi
557 if [ test x$HAVE_DIVX = xyes ]; then
558 AC_MSG_CHECKING([Checking for valid divx4linux decore version])
559 AC_TRY_COMPILE([
560 #include <decore.h>
561 #if DECORE_VERSION != 20021112
562 #error Wrong version of divx decore libraries
563 #endif
564 ], [
565 return 0;
566 ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
567 [ HAVE_DIVX=no && AC_MSG_RESULT(no) &&
568 AC_MSG_WARN([Wrong version of divx4linux installed]) ])
569 fi
570 LIBS="-lm"
571 if test x$HAVE_DIVX = xyes; then
572 AC_CHECK_LIB(divxencore, encore, ,
573 [ AC_MSG_WARN([Divx4linux encore libs not found]) &&
574 HAVE_DIVX=no ] )
575 fi
576 if test x$HAVE_DIVX = xyes; then
577 AC_CHECK_LIB(divxdecore, decore, ,
578 [ AC_MSG_WARN([Divx4linux decore libs not found]) &&
579 HAVE_DIVX=no ] )
580 fi
581 if test x$HAVE_DIVX = xyes; then
582 DIVXENC_LIBS="-ldivxencore -lm"
583 DIVXDEC_LIBS="-ldivxdecore -lm"
584 AC_SUBST(DIVXENC_LIBS)
585 AC_SUBST(DIVXDEC_LIBS)
586 fi
587 ])
589 dnl *** dvdread ***
590 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
591 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
592 GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
593 AC_SUBST(DVDREAD_LIBS)
594 ])
596 dnl *** dvdnav ***
597 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
598 GST_CHECK_FEATURE(DVDNAV, [dvdnav library], dvdnavsrc, [
599 translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
600 translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
601 GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
602 if test x"$HAVE_DVDNAV" = x"yes"; then
603 dnl check version
604 DVDNAV_VERSION=`dvdnav-config --version|head -n 1|sed 's/^.*) //'|sed 's/ (.*)//'`
605 DVDNAV_MAJOR=`echo $DVDNAV_VERSION | cut -d. -f1 | sed s/[a-zA-Z\-].*//g`
606 DVDNAV_MINOR=`echo $DVDNAV_VERSION | cut -d. -f2 | sed s/[a-zA-Z\-].*//g`
607 DVDNAV_MICRO=`echo $DVDNAV_VERSION | cut -d. -f3 | sed s/[a-zA-Z\-].*//g`
608 if [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
609 [[ "$DVDNAV_MINOR" -lt "1" ]]; then
610 AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
611 HAVE_DVDNAV="no"
612 elif [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
613 [[ "$DVDNAV_MINOR" -eq "1" ]] && \
614 [[ "$DVDNAV_MICRO" -lt "7" ]]; then
615 AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
616 HAVE_DVDNAV="no"
617 fi
618 fi
619 AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
620 ])
622 dnl *** MAS ***
623 translit(dnm, m, l) AM_CONDITIONAL(USE_MAS, true)
624 GST_CHECK_FEATURE(MAS, [mas library], massink, [
625 translit(dnm, m, l) AC_SUBST(MAS_LIBS)
626 translit(dnm, m, l) AC_SUBST(MAS_CFLAGS)
627 GST_CHECK_CONFIGPROG(MAS, mas-config)
628 AS_SCRUB_INCLUDE(MAS_CFLAGS)
629 ])
631 dnl **** ESound ****
632 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
633 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink esdmon, [
634 AM_PATH_ESD(0.2.12, HAVE_ESD=yes, HAVE_ESD=no)
635 AS_SCRUB_INCLUDE(ESD_CFLAGS)
636 ])
638 dnl **** festival ****
639 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
640 dnl GST_CHECK_FEATURE(FESTIVAL, [festival plug-ins], festivalsrc, [
641 dnl NOTE: just using local net connection now, add this lib check
642 dnl in the future if needed
643 dnl AC_LANG_PUSH(C++)
644 dnl dnl FIXME: took out func to check for
645 dnl dnl This check puts festival_tidy_up in extern "C".
646 dnl dnl But, at least on Debian as of 20020110, it is compiled with name
647 dnl dnl mangling C++ nonsense and symbols can't resolve
648 dnl dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, festival_tidy_up, , festival/festival.h, FESTIVAL_LIBS="-lFestival")
649 dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, , , festival/festival.h, FESTIVAL_LIBS="-lFestival")
650 dnl AC_LANG_POP(C++)
651 dnl AC_SUBST(FESTIVAL_LIBS)
652 dnl HAVE_FESTIVAL=yes
653 dnl])
655 dnl *** FLAC ***
656 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
657 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
658 GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
659 AC_SUBST(FLAC_LIBS)
660 ])
662 dnl *** FFMPEG ***
663 translit(dnm, m, l) AM_CONDITIONAL(USE_FFMPEG, true)
664 GST_CHECK_FEATURE(FFMPEG, [ffmpeg plug-ins], ffmpeg, [
665 # only slurp in the case where we are in CVS mode;
666 # prerelease and release should get it disted
667 if test "x$GST_PLUGINS_VERSION_NANO" = x1; then
668 AC_MSG_NOTICE(slurping FFmpeg CVS source)
669 AS_SLURP_FFMPEG(gst-libs/ext/ffmpeg, 2003-06-09 22:00 GMT,
670 HAVE_FFMPEG=yes, HAVE_FFMPEG=no)
671 else
672 AC_MSG_NOTICE(FFmpeg CVS code should be included already)
673 HAVE_FFMPEG=yes
674 fi
675 # we only bother with uninstalled (included) ffmpeg for now
676 AC_DEFINE_UNQUOTED(HAVE_FFMPEG_UNINSTALLED, 1,
677 [defined if we use uninstalled ffmpeg])
678 ])
680 dnl *** GDK pixbuf ***
681 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
682 GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbufsrc, [
683 if test $HAVE_GTK = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
684 ])
686 dnl *** Gnome VFS ***
687 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
688 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
689 PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
690 AC_SUBST(GNOME_VFS_CFLAGS)
691 AC_SUBST(GNOME_VFS_LIBS)
692 ])
694 dnl *** gsm ***
695 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
696 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
697 GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
698 if test $HAVE_GSM != "yes"; then
699 GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
700 if test $HAVE_GSM = "yes"; then
701 AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
702 fi
703 fi
704 AC_SUBST(GSM_LIBS)
705 ])
707 dnl *** Hermes ***
708 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
709 GST_CHECK_FEATURE(HERMES, [Hermes library], colorspace, [
710 GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
711 ], AC_SUBST(HERMES_LIBS))
713 dnl *** http ***
714 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
715 dnl GST_CHECK_FEATURE(HTTP, [http plug-ins], gsthttpsrc, [
716 dnl dnl FIXME: need to check for header
717 dnl GHTTP_LIBS=
718 dnl GST_HTTPSRC_GET_TYPE=
719 dnl if test x$USE_GLIB2 = xyes; then
720 dnl AC_MSG_WARN(ghttp disabled for glib2.0)
721 dnl else
722 dnl AC_CHECK_LIB(ghttp, ghttp_request_new,
723 dnl [HTTP_LIBS="-lghttp"
724 dnl GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
725 dnl HAVE_HTTP=yes
726 dnl ], :, $LIBS)
727 dnl fi
728 dnl AC_SUBST(HTTP_LIBS)
729 dnl AC_SUBST(GST_HTTPSRC_GET_TYPE)
730 dnl ])
732 dnl *** ivorbis ***
733 dnl AM_PATH_IVORBIS only takes two options
734 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
735 GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
736 XIPH_PATH_IVORBIS(HAVE_IVORBIS=yes, HAVE_IVORBIS=no)
737 AS_SCRUB_INCLUDE(IVORBIS_CFLAGS)
738 ])
740 dnl *** Jack ***
741 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
742 GST_CHECK_FEATURE(JACK, Jack, jack, [
743 PKG_CHECK_MODULES(JACK, jack >= 0.29.0, HAVE_JACK="yes", HAVE_JACK="no")
744 AC_SUBST(JACK_CFLAGS)
745 AC_SUBST(JACK_LIBS)
746 ])
748 dnl *** jpeg ***
749 dnl FIXME: we could use header checks here as well IMO
750 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
751 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
752 AC_ARG_WITH(jpeg-mmx,
753 [ --with-jpeg-mmx, path to MMX'ified JPEG library])
754 OLD_LIBS="$LIBS"
755 if test x$with_jpeg_mmx != x; then
756 LIBS="$LIBS -L$with_jpeg_mmx"
757 fi
758 AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
759 JPEG_LIBS="$LIBS -ljpeg-mmx"
760 LIBS="$OLD_LIBS"
761 if test x$HAVE_JPEG != xyes; then
762 AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
763 JPEG_LIBS="-ljpeg"
764 fi
765 AC_SUBST(JPEG_LIBS)
766 ])
768 dnl *** ladspa ***
769 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
770 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
771 AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
772 ])
774 dnl *** lame ***
775 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
776 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
777 GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, HAVE_LAME="yes" LAME_LIBS="-lmp3lame")
778 ])
779 AC_SUBST(LAME_LIBS)
781 dnl *** libcolorspace ***
782 translit(dnm, m, l) AM_CONDITIONAL(USE_LCS, true)
783 GST_CHECK_FEATURE(LCS, Lcs, lcs, [
784 PKG_CHECK_MODULES(LCS, lcs, HAVE_LCS="yes", HAVE_LCS="no")
785 AC_SUBST(LCS_CFLAGS)
786 AC_SUBST(LCS_LIBS)
787 ])
789 dnl *** libdv ***
790 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
791 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
792 PKG_CHECK_MODULES(LIBDV, libdv >= 0.98, HAVE_LIBDV="yes", HAVE_LIBDV="no")
793 AC_SUBST(LIBDV_CFLAGS)
794 AC_SUBST(LIBDV_LIBS)
795 ])
797 dnl *** libfame ***
798 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBFAME, true)
799 GST_CHECK_FEATURE(LIBFAME, [libfame MPEG1/4 encoder], libfame, [
800 AM_PATH_LIBFAME(0.9.0, HAVE_LIBFAME="yes", HAVE_LIBFAME="no")
801 AC_SUBST(LIBFAME_CFLAGS)
802 AC_SUBST(LIBFAME_LIBS)
803 ])
805 dnl *** libpng ***
806 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
807 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
808 PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
809 AC_SUBST(LIBPNG_CFLAGS)
810 AC_SUBST(LIBPNG_LIBS)
811 ])
814 dnl *** mad ***
815 dnl FIXME: we could use header checks here as well IMO
816 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
817 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
818 dnl check with pkg-config first
819 PKG_CHECK_MODULES(MAD, mad id3tag, HAVE_MAD="yes", HAVE_MAD="no")
820 if test "x$HAVE_MAD" = "xno"; then
821 dnl fall back to oldskool detection
822 AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
823 if test "x$HAVE_MAD" = "xyes"; then
824 # installed with mad >= 0.14
825 HAVE_MAD="no"
826 save_libs=$LIBS
827 LIBS="-lz"
828 AC_CHECK_LIB(id3tag, id3_tag_query, HAVE_MAD="yes" MAD_LIBS="$MAD_LIBS -lid3tag")
829 LIBS=$save_LIBS
830 fi
831 fi
832 ])
833 AC_SUBST(MAD_LIBS)
835 dnl *** mikmod ***
836 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
837 GST_CHECK_FEATURE(MIKMOD, [mikmod plug-in], mikmod, [
838 AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
839 AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
840 AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMODCFLAGS")
841 ])
843 dnl *** mpeg2dec ***
844 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
845 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
846 PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.3.1,
847 HAVE_MPEG2DEC="yes", HAVE_MPEG2DEC="no")
848 AC_SUBST(MPEG2DEC_CFLAGS)
849 AC_SUBST(MPEG2DEC_LIBS)
850 ])
852 dnl *** pango ***
853 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
854 GST_CHECK_FEATURE(PANGO, [pango], pango, [
855 PKG_CHECK_MODULES(PANGO, pango pangoft2,
856 HAVE_PANGO="yes", HAVE_PANGO="no")
857 AC_SUBST(PANGO_CFLAGS)
858 AC_SUBST(PANGO_LIBS)
859 ])
861 dnl *** raw1394 ***
862 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
863 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
864 GST_CHECK_LIBHEADER(RAW1394, raw1394, raw1394_new_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
865 AC_SUBST(RAW1394_LIBS)
866 ])
868 dnl *** SDL ***
869 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
870 GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink, [
871 AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
872 ])
874 dnl *** shout ***
875 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
876 GST_CHECK_FEATURE(SHOUT, [shout plug-in], icecastsend, [
877 GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
878 AC_SUBST(SHOUT_LIBS)
879 ])
881 dnl *** shout2 ***
882 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
883 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
884 AM_PATH_SHOUT2(HAVE_SHOUT2=yes, HAVE_SHOUT2=no)
885 AC_SUBST(SHOUT2_CFLAGS)
886 AC_SUBST(SHOUT2_LIBS)
887 ])
889 dnl *** sidplay ***
890 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
891 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
892 GST_PATH_SIDPLAY()
893 ])
895 dnl *** smoothwave ***
896 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
897 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plug-in], smoothwave, [
898 if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
899 ])
902 dnl *** snapshot ***
903 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
904 GST_CHECK_FEATURE(LIBPNG, [snapshot plug-in], snapshot, [
905 GST_CHECK_LIBHEADER(LIBPNG, png, png_read_info, -lz -lm, png.h, LIBPNG_LIBS="-lpng -lz -lm")
906 AC_SUBST(LIBPNG_LIBS)
907 ])
909 dnl *** sndfile ***
910 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
911 GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
912 PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.0, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
913 AC_SUBST(SNDFILE_CFLAGS)
914 AC_SUBST(SNDFILE_LIBS)
915 ])
917 dnl *** swfdec ***
918 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
919 GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
920 PKG_CHECK_MODULES(SWFDEC, swfdec >= 0.1.3.1, HAVE_SWFDEC=yes, HAVE_SWFDEC=no)
921 AC_SUBST(SWFDEC_CFLAGS)
922 AC_SUBST(SWFDEC_LIBS)
923 ])
925 dnl *** tarkin ***
926 dnl for now the sources are included in the plug-in
927 dnl and should be moved to ext-libs/ perhaps
928 translit(dnm, m, l) AM_CONDITIONAL(USE_TARKIN, true)
929 GST_CHECK_FEATURE(TARKIN, [tarkinenc tarkindec], tarkin, [
930 HAVE_TARKIN="yes"
931 ])
933 dnl *** vorbis ***
934 dnl AM_PATH_VORBIS only takes two options
935 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
936 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
937 XIPH_PATH_VORBIS(HAVE_VORBIS=yes, HAVE_VORBIS=no)
938 AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
939 ])
941 dnl *** XVID ***
942 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
943 GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
944 HAVE_XVID=yes
945 AC_CHECK_HEADER(xvid.h, ,
946 [ AC_MSG_WARN([Xvid headers not found]) &&
947 HAVE_XVID=no ] )
948 LIBS="-lm"
949 AC_CHECK_LIB(xvidcore, xvid_encore, ,
950 [ AC_MSG_WARN([Xvid encore libs not found]) &&
951 HAVE_XVID=no ] )
952 AC_CHECK_LIB(xvidcore, xvid_decore, ,
953 [ AC_MSG_WARN([Xvid decore libs not found]) &&
954 HAVE_XVID=no ] )
955 if test x$HAVE_XVID = xyes; then
956 XVID_LIBS="-lxvidcore -lm"
957 AC_SUBST(XVID_LIBS)
958 fi
959 ])
962 fi dnl of EXT plugins
964 dnl Check for atomic.h
965 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
966 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
967 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
968 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
969 if test x$HAVE_ATOMIC_H = xyes; then
970 AC_TRY_RUN([
971 #include "asm/atomic.h"
972 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
973 ],, [
974 # Not successful
975 if test x$HAVE_ATOMIC_H = xyes; then
976 AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
977 fi
978 HAVE_ATOMIC_H=no
979 ], [
980 # Cross compiling
981 AC_MSG_RESULT(yes)
982 AC_MSG_WARN(Can't check properly for atomic reference counting. Assuming OK.)
983 ])
984 fi
987 dnl ######################################################################
988 dnl # Check command line parameters, and set shell variables accordingly #
989 dnl ######################################################################
991 AC_ARG_ENABLE(libmmx,
992 AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
993 [case "${enableval}" in
994 yes) USE_LIBMMX=$HAVE_LIBMMX ;;
995 no) USE_LIBMMX=no ;;
996 *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
997 esac],
998 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
1000 AC_ARG_ENABLE(atomic,
1001 AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
1002 [case "${enableval}" in
1003 yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1004 noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1005 no) USE_ATOMIC_H=no;;
1006 *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
1007 esac],
1008 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
1010 AC_ARG_ENABLE(profiling,
1011 AC_HELP_STRING([--enable-profiling],
1012 [-pg to compiler commandline, for profiling]),
1013 [case "${enableval}" in
1014 yes) USE_PROFILING=yes ;;
1015 no) UES_PROFILING=no ;;
1016 *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
1017 esac],
1018 [USE_PROFILING=no]) dnl Default value
1020 AC_ARG_ENABLE(tests,
1021 AC_HELP_STRING([--disable-tests],[disable building test apps]),
1022 [case "${enableval}" in
1023 yes) BUILD_TESTS=yes ;;
1024 no) BUILD_TESTS=no ;;
1025 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
1026 esac],
1027 [BUILD_TESTS=yes]) dnl Default value
1029 AC_ARG_ENABLE(examples,
1030 AC_HELP_STRING([--disable-examples],[disable building examples]),
1031 [case "${enableval}" in
1032 yes) BUILD_EXAMPLES=yes ;;
1033 no) BUILD_EXAMPLES=no ;;
1034 *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
1035 esac],
1036 [BUILD_EXAMPLES=yes]) dnl Default value
1038 dnl seeking needs freetype, so check for it here
1039 AC_CHECK_FT2(2.0.9,HAVE_FT2=yes,HAVE_FT2=no)
1040 dnl make the HAVE_FT2 variable available to automake and Makefile.am
1041 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
1042 AC_SUBST(FT2_CFLAGS)
1043 AC_SUBST(FT2_LIBS)
1045 dnl ################################################
1046 dnl # Set defines according to variables set above #
1047 dnl ################################################
1050 if test "x$USE_LIBMMX" = xyes; then
1051 AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
1052 fi
1054 if test "x$USE_ATOMIC_H" = xyes; then
1055 AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
1056 fi
1058 # do not use deprecated stuff
1059 GST_CFLAGS="$GST_CFLAGS -DGST_DISABLE_DEPRECATED"
1061 if test "x$USE_DEBUG" = xyes; then
1062 GST_CFLAGS="$GST_CFLAGS -g"
1063 fi
1065 if test "x$USE_PROFILING" = xyes; then
1066 dnl CFLAGS="$CFLAGS -pg -fprofile-arcs"
1067 FOMIT_FRAME_POINTER=""
1068 else
1069 FOMIT_FRAME_POINTER="-fomit-frame-pointer"
1070 fi
1072 dnl
1073 dnl AC_SUBST(FOMIT_FRAME_POINTER)
1074 dnl
1076 dnl #############################
1077 dnl # Set automake conditionals #
1078 dnl #############################
1080 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
1081 dnl HAVE_ and it is likely to be easier to stick with the old name
1082 AM_CONDITIONAL(HAVE_CPU_I386, test "x$HAVE_CPU_I386" = "xyes")
1083 AM_CONDITIONAL(HAVE_CPU_PPC, test "x$HAVE_CPU_PPC" = "xyes")
1084 AM_CONDITIONAL(HAVE_CPU_ALPHA, test "x$HAVE_CPU_ALPHA" = "xyes")
1085 AM_CONDITIONAL(HAVE_CPU_ARM, test "x$HAVE_CPU_ARM" = "xyes")
1086 AM_CONDITIONAL(HAVE_CPU_SPARC, test "x$HAVE_CPU_SPARC" = "xyes")
1087 AM_CONDITIONAL(HAVE_LIBMMX, test "x$USE_LIBMMX" = "xyes")
1089 AM_CONDITIONAL(HAVE_ATOMIC_H, test "x$USE_ATOMIC_H" = "xyes")
1091 AM_CONDITIONAL(EXPERIMENTAL, test "$EXPERIMENTAL" = "$xyes")
1092 AM_CONDITIONAL(BROKEN, test "$BROKEN" = "$xyes")
1094 AM_CONDITIONAL(HAVE_NASM, test "x$HAVE_NASM" = "xyes")
1095 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
1096 AM_CONDITIONAL(HAVE_GTK_DOC, $HAVE_GTK_DOC)
1097 AM_CONDITIONAL(BUILD_DOCS, test "x$BUILD_DOCS" = "xyes")
1098 AM_CONDITIONAL(BUILD_TESTS, test "x$BUILD_TESTS" = "xyes")
1099 AM_CONDITIONAL(BUILD_EXAMPLES, test "x$BUILD_EXAMPLES" = "xyes")
1100 AM_CONDITIONAL(BUILD_PLUGIN_DOCS, test "x$BUILD_PLUGIN_DOCS" = "xyes")
1101 AM_CONDITIONAL(HAVE_FIG2DEV_PNG, $HAVE_FIG2DEV_PNG)
1102 AM_CONDITIONAL(HAVE_FIG2DEV_PDF, $HAVE_FIG2DEV_PDF)
1103 AM_CONDITIONAL(HAVE_RAW1394, test "x$HAVE_RAW1394" = "xyes")
1105 dnl prefer internal headers to already installed ones
1106 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GST_ERROR"
1107 GST_OPT_CFLAGS="$GST_FINLINE_CFLAGS $GST_FFASTMATH_CFLAGS"
1109 AC_SUBST(GST_LIBS)
1110 AC_SUBST(GST_CFLAGS)
1111 AC_SUBST(GST_FUNROLL_CFLAGS)
1112 AC_SUBST(GST_FINLINE_CFLAGS)
1113 AC_SUBST(GST_FFASTMATH_CFLAGS)
1114 AC_SUBST(GST_FSCHEDULE_CFLAGS)
1115 AC_SUBST(GST_FNOEXCEPTIONS_CFLAGS)
1116 AC_SUBST(GST_OPT_CFLAGS)
1118 dnl ###########################
1119 dnl # Configure external libs #
1120 dnl ###########################
1121 if test "x$HAVE_FFMPEG" = xyes; then
1122 AC_CONFIG_SUBDIRS(gst-libs/ext/ffmpeg/ffmpeg)
1123 fi
1125 dnl #########################
1126 dnl # Make the output files #
1127 dnl #########################
1129 AC_CONFIG_FILES(
1130 Makefile
1131 pkgconfig/gstreamer-libs.pc
1132 pkgconfig/gstreamer-libs-uninstalled.pc
1133 pkgconfig/gstreamer-play.pc
1134 pkgconfig/gstreamer-play-uninstalled.pc
1135 gst-libs/gst/gconf/gstreamer-gconf.pc
1136 gst-libs/gst/gconf/gstreamer-gconf-uninstalled.pc
1137 gst-plugins.spec
1138 gst/Makefile
1139 gst/ac3parse/Makefile
1140 gst/adder/Makefile
1141 gst/audioconvert/Makefile
1142 gst/audioscale/Makefile
1143 gst/auparse/Makefile
1144 gst/avi/Makefile
1145 gst/asfdemux/Makefile
1146 gst/cdxaparse/Makefile
1147 gst/chart/Makefile
1148 gst/cutter/Makefile
1149 gst/debug/Makefile
1150 gst/deinterlace/Makefile
1151 gst/effectv/Makefile
1152 gst/festival/Makefile
1153 gst/filter/Makefile
1154 gst/flx/Makefile
1155 gst/goom/Makefile
1156 gst/intfloat/Makefile
1157 gst/law/Makefile
1158 gst/level/Makefile
1159 gst/median/Makefile
1160 gst/mixmatrix/Makefile
1161 gst/mpeg1enc/Makefile
1162 gst/mpeg1sys/Makefile
1163 gst/mpeg1videoparse/Makefile
1164 gst/mpeg2enc/Makefile
1165 gst/mpeg2sub/Makefile
1166 gst/mpegaudio/Makefile
1167 gst/mpegaudioparse/Makefile
1168 gst/mpegstream/Makefile
1169 gst/mpegtypes/Makefile
1170 gst/modplug/Makefile
1171 gst/modplug/libmodplug/Makefile
1172 gst/monoscope/Makefile
1173 gst/oneton/Makefile
1174 gst/overlay/Makefile
1175 gst/passthrough/Makefile
1176 gst/playondemand/Makefile
1177 gst/qtdemux/Makefile
1178 gst/realmedia/Makefile
1179 gst/rtjpeg/Makefile
1180 gst/rtp/Makefile
1181 gst/silence/Makefile
1182 gst/sine/Makefile
1183 gst/smooth/Makefile
1184 gst/smpte/Makefile
1185 gst/spectrum/Makefile
1186 gst/speed/Makefile
1187 gst/stereo/Makefile
1188 gst/synaesthesia/Makefile
1189 gst/udp/Makefile
1190 gst/vbidec/Makefile
1191 gst/videocrop/Makefile
1192 gst/videofilter/Makefile
1193 gst/videoflip/Makefile
1194 gst/videoscale/Makefile
1195 gst/videotestsrc/Makefile
1196 gst/volenv/Makefile
1197 gst/volume/Makefile
1198 gst/wavenc/Makefile
1199 gst/wavparse/Makefile
1200 gst/y4m/Makefile
1201 sys/Makefile
1202 sys/cdrom/Makefile
1203 sys/dxr3/Makefile
1204 sys/oss/Makefile
1205 sys/qcam/Makefile
1206 sys/v4l/Makefile
1207 sys/v4l2/Makefile
1208 sys/vcd/Makefile
1209 sys/xvideo/Makefile
1210 ext/Makefile
1211 ext/a52dec/Makefile
1212 ext/aalib/Makefile
1213 ext/alsa/Makefile
1214 ext/arts/Makefile
1215 ext/artsd/Makefile
1216 ext/audiofile/Makefile
1217 ext/cdparanoia/Makefile
1218 ext/divx/Makefile
1219 ext/dv/Makefile
1220 ext/dvdread/Makefile
1221 ext/dvdnav/Makefile
1222 ext/esd/Makefile
1223 ext/ffmpeg/Makefile
1224 ext/flac/Makefile
1225 ext/gdk_pixbuf/Makefile
1226 ext/gnomevfs/Makefile
1227 ext/gsm/Makefile
1228 ext/hermes/Makefile
1229 dnl ext/http/Makefile
1230 ext/jack/Makefile
1231 ext/jpeg/Makefile
1232 ext/ladspa/Makefile
1233 ext/lame/Makefile
1234 ext/ivorbis/Makefile
1235 ext/lcs/Makefile
1236 ext/libfame/Makefile
1237 ext/libpng/Makefile
1238 ext/mad/Makefile
1239 ext/mas/Makefile
1240 ext/mikmod/Makefile
1241 ext/mpeg2dec/Makefile
1242 ext/pango/Makefile
1243 ext/raw1394/Makefile
1244 ext/sdl/Makefile
1245 ext/shout/Makefile
1246 ext/shout2/Makefile
1247 ext/sidplay/Makefile
1248 ext/smoothwave/Makefile
1249 ext/snapshot/Makefile
1250 ext/sndfile/Makefile
1251 ext/swfdec/Makefile
1252 ext/vorbis/Makefile
1253 ext/tarkin/Makefile
1254 ext/xvid/Makefile
1255 gst-libs/Makefile
1256 gst-libs/gst/Makefile
1257 gst-libs/gst/audio/Makefile
1258 gst-libs/gst/floatcast/Makefile
1259 gst-libs/gst/gconf/Makefile
1260 gst-libs/gst/idct/Makefile
1261 gst-libs/gst/media-info/Makefile
1262 gst-libs/gst/play/Makefile
1263 gst-libs/gst/resample/Makefile
1264 gst-libs/gst/riff/Makefile
1265 gst-libs/gst/video/Makefile
1266 gst-libs/ext/Makefile
1267 gst-libs/ext/ffmpeg/Makefile
1268 examples/dynparams/Makefile
1269 examples/capsfilter/Makefile
1270 examples/seeking/Makefile
1271 examples/indexing/Makefile
1272 examples/Makefile
1273 testsuite/autoplug/Makefile
1274 testsuite/spider/Makefile
1275 testsuite/alsa/Makefile
1276 testsuite/Makefile
1277 tools/Makefile
1278 gconf/Makefile
1279 pkgconfig/Makefile
1280 )
1281 AC_OUTPUT
1283 echo -e "configure: *** Plug-ins that will be built : $GST_PLUGINS_YES"
1284 echo
1285 echo -e "configure: *** Plug-ins that will not be built : $GST_PLUGINS_NO"
1286 echo
1287 if test "x$BUILD_EXTERNAL" = "xno"; then
1288 echo "configure: *** No external plug-ins will be built"
1289 fi