1 AC_PREREQ(2.52)
3 dnl please read gstreamer/docs/random/autotools before changing this file
5 dnl initialize autoconf
6 dnl releases only do -Wall, cvs and prerelease does -Werror too
7 dnl use a three digit version number for releases, and four for cvs/prerelease
8 AC_INIT(GStreamer Ugly Plug-ins, 0.10.14.3,
9 http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
10 gst-plugins-ugly)
12 AG_GST_INIT
14 dnl initialize automake
15 AM_INIT_AUTOMAKE([-Wno-portability])
17 dnl define PACKAGE_VERSION_* variables
18 AS_VERSION
20 dnl check if this is a release version
21 AS_NANO(GST_GIT="no", GST_GIT="yes")
23 dnl can autoconf find the source ?
24 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
26 dnl define the output header for config
27 AM_CONFIG_HEADER(config.h)
29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
30 AM_MAINTAINER_MODE
32 dnl sets host_* variables
33 AC_CANONICAL_HOST
35 dnl use pretty build output with automake >= 1.11
36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
37 [AM_DEFAULT_VERBOSITY=1
38 AC_SUBST(AM_DEFAULT_VERBOSITY)])
40 dnl our libraries and install dirs use major.minor as a version
41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
42 dnl we override it here if we need to for the release candidate of new series
43 GST_MAJORMINOR=0.10
44 AC_SUBST(GST_MAJORMINOR)
46 dnl FIXME: this macro doesn't actually work;
47 dnl the generated libtool script has no support for the listed tags.
48 dnl So this needs to be fixed first if we want to use this
49 dnl AS_LIBTOOL_TAGS([CXX])
51 AC_LIBTOOL_WIN32_DLL
52 AM_PROG_LIBTOOL
54 dnl *** required versions of GStreamer stuff ***
55 GST_REQ=0.10.26
56 GSTPB_REQ=0.10.26
58 dnl *** autotools stuff ****
60 dnl allow for different autotools
61 AS_AUTOTOOLS_ALTERNATE
63 dnl Add parameters for aclocal
64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
66 dnl set up gettext
67 dnl the version check needs to stay here because autopoint greps for it
68 AM_GNU_GETTEXT_VERSION(0.17)
69 AM_GNU_GETTEXT([external])
70 AG_GST_GETTEXT([gst-plugins-ugly-$GST_MAJORMINOR])
72 dnl *** check for arguments to configure ***
74 AG_GST_ARG_DEBUG
75 AG_GST_ARG_PROFILING
76 AG_GST_ARG_VALGRIND
77 AG_GST_ARG_GCOV
79 AG_GST_ARG_EXAMPLES
81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
82 AG_GST_ARG_WITH_PACKAGE_NAME
83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
85 AG_GST_ARG_WITH_PLUGINS
87 AG_GST_ARG_ENABLE_EXTERNAL
89 AG_GST_ARG_ENABLE_EXPERIMENTAL
91 dnl *** checks for platform ***
93 dnl * hardware/architecture *
95 dnl common/m4/gst-arch.m4
96 dnl check CPU type
97 AG_GST_ARCH
99 dnl Determine endianness
100 AC_C_BIGENDIAN
102 dnl *** checks for programs ***
104 dnl find a compiler
105 AC_PROG_CC
107 dnl determine c++ compiler
108 AC_PROG_CXX
109 dnl determine if c++ is available on this system
110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
112 dnl check if the compiler supports '-c' and '-o' options
113 AM_PROG_CC_C_O
115 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
116 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
118 dnl check if the compiler supports do while(0) macros
119 AG_GST_CHECK_DOWHILE_MACROS
121 dnl check for documentation tools
122 GTK_DOC_CHECK([1.3])
123 AS_PATH_PYTHON([2.1])
124 AG_GST_PLUGIN_DOCS([1.3],[2.1])
126 dnl *** checks for libraries ***
128 dnl check for libm, for sin()
129 AC_CHECK_LIBM
130 AC_SUBST(LIBM)
132 dnl *** checks for header files ***
134 dnl used by ext/a52dec
135 AX_CREATE_STDINT_H
137 dnl Check for malloc.h
138 AC_CHECK_HEADERS([malloc.h])
140 dnl *** checks for types/defines ***
142 dnl *** checks for structures ***
144 dnl *** checks for compiler characteristics ***
146 dnl *** checks for library functions ***
148 dnl Check for a way to display the function name in debug output
149 AG_GST_CHECK_FUNCTION
151 dnl *** checks for dependency libraries ***
153 dnl GLib is required
154 AG_GST_GLIB_CHECK([2.18])
156 dnl liboil is required
157 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
158 if test "x$HAVE_LIBOIL" != "xyes"; then
159 AC_ERROR([liboil-0.3.14 or later is required])
160 fi
162 dnl checks for gstreamer
163 dnl uninstalled is selected preferentially -- see pkg-config(1)
164 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
165 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
166 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
167 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
168 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
170 dnl Check for documentation xrefs
171 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
172 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
173 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
174 AC_SUBST(GLIB_PREFIX)
175 AC_SUBST(GST_PREFIX)
176 AC_SUBST(GSTPB_PREFIX)
178 dnl *** set variables based on configure arguments ***
180 dnl set license and copyright notice
181 GST_LICENSE="LGPL"
182 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
183 AC_SUBST(GST_LICENSE)
185 dnl set location of plugin directory
186 AG_GST_SET_PLUGINDIR
188 dnl define an ERROR_CFLAGS Makefile variable
189 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
190 -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
191 -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
192 -Winit-self -Wmissing-include-dirs -Waddress
193 -Waggregate-return -Wno-multichar -Wnested-externs ])
195 dnl define an ERROR_CXXFLAGS Makefile variable
196 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
197 -Wmissing-declarations -Wredundant-decls
198 -Wwrite-strings -Wformat-nonliteral -Wformat-security
199 -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
200 -Wno-multichar])
202 dnl define correct level for debugging messages
203 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
205 dnl used in examples
206 AG_GST_DEFAULT_ELEMENTS
208 dnl *** plug-ins to include ***
210 dnl these are all the gst plug-ins, compilable without additional libs
211 AG_GST_CHECK_PLUGIN(asfdemux)
212 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
213 AG_GST_CHECK_PLUGIN(dvdsub)
214 AG_GST_CHECK_PLUGIN(iec958)
215 AG_GST_CHECK_PLUGIN(mpegaudioparse)
216 AG_GST_CHECK_PLUGIN(mpegstream)
217 AG_GST_CHECK_PLUGIN(realmedia)
218 AG_GST_CHECK_PLUGIN(synaesthesia)
220 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
222 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
223 WIN32_LIBS="-lws2_32"
224 AC_SUBST(WIN32_LIBS)
225 fi
227 dnl disable experimental plug-ins
228 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
229 AG_GST_DISABLE_PLUGIN(synaesthesia)
230 fi
232 dnl *** ext plug-ins ***
233 dnl keep this list sorted alphabetically !
235 if test "x$BUILD_EXTERNAL" = "xyes"; then
237 echo
238 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
239 echo
241 dnl *** a52dec ***
242 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
243 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
244 AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
245 ])
247 dnl *** amr-nb ***
248 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
249 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
250 PKG_CHECK_MODULES(AMRNB, opencore-amrnb, HAVE_AMRNB="yes",
251 [ AG_GST_CHECK_LIBHEADER(AMRNB, opencore-amrnb,
252 Decoder_Interface_init, -lm,
253 opencore-amrnb/interf_dec.h,
254 AMRNB_LIBS="-lopencore-amrnb")
255 ])
256 AC_SUBST(AMRNB_CFLAGS)
257 AC_SUBST(AMRNB_LIBS)
258 ])
260 dnl *** amr-wb dec ***
261 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
262 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
263 PKG_CHECK_MODULES(AMRWB, opencore-amrwb, HAVE_AMRWB="yes",
264 [ AG_GST_CHECK_LIBHEADER(AMRWB, opencore-amrwb,
265 D_IF_decode, ,
266 opencore-amrwb/dec_if.h,
267 AMRWB_LIBS="-lopencore-amrwb")
268 ])
269 AC_SUBST(AMRWB_CFLAGS)
270 AC_SUBST(AMRWB_LIBS)
271 ])
273 dnl *** cdio ***
274 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
275 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
276 AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
277 ])
279 dnl *** dvdread ***
280 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
281 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
282 AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
283 AC_SUBST(DVDREAD_LIBS)
284 ])
286 dnl *** lame ***
287 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
288 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
289 AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h,
290 [
291 HAVE_LAME="yes"
292 LAME_LIBS="-lmp3lame -lm"
293 dnl is lame presets available
294 LAME_CFLAGS=""
295 AC_TRY_COMPILE([#include <lame/lame.h>], [ int preset = MEDIUM ],
296 [LAME_CFLAGS="-DGSTLAME_PRESET"],
297 [LAME_CFLAGS=""]
298 )
299 AC_TRY_COMPILE([#include <lame/lame.h>], [
300 void *ptr = &lame_set_VBR_quality
301 ],
302 [LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],
303 [LAME_CFLAGS="$LAME_CFLAGS"]
304 )
305 AC_SUBST(LAME_CFLAGS)
306 AC_SUBST(LAME_LIBS)
307 ])
308 ])
310 dnl *** mad ***
311 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
312 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
314 dnl check with pkg-config first
315 AG_GST_PKG_CHECK_MODULES(ID3TAG, id3tag >= 0.15)
316 if test "x$HAVE_ID3TAG" = "xno"; then
317 dnl fall back to oldskool detection
318 AC_CHECK_HEADER(id3tag.h, [
319 save_LIBS=$LIBS
320 LIBS="-lz"
321 AC_CHECK_LIB(id3tag, id3_tag_options,
322 HAVE_ID3TAG="yes" ID3TAG_LIBS="-lid3tag -lz")
323 LIBS=$save_LIBS
324 AC_SUBST(ID3TAG_LIBS)
325 ])
326 fi
328 if test "x$HAVE_ID3TAG" = "xyes"; then
329 dnl check with pkg-config first
330 AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
331 MAD_LIBS="$MAD_LIBS $ID3TAG_LIBS"
332 if test "x$HAVE_MAD" = "xno"; then
333 dnl fall back to oldskool detection
334 AC_CHECK_HEADER(mad.h, [
335 AC_CHECK_LIB(mad, mad_decoder_finish,
336 HAVE_MAD="yes" MAD_LIBS="-lmad $ID3TAG_LIBS")
337 ])
338 fi
339 else
340 HAVE_MAD="no"
341 AC_MSG_WARN([libid3tag not available, cannot build MAD MP3 decoder plugin])
342 fi
343 ])
344 AC_SUBST(MAD_LIBS)
346 dnl *** mpeg2dec ***
347 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
348 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
349 AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
350 ])
352 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
353 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
354 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
355 GST_PATH_SIDPLAY()
356 ])
358 dnl *** twolame ***
359 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
360 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
361 PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
362 HAVE_TWOLAME="yes"], [
363 HAVE_TWOLAME="no"
364 AC_MSG_RESULT(no)
365 ])
366 AC_SUBST(TWOLAME_CFLAGS)
367 AC_SUBST(TWOLAME_LIBS)
368 ])
370 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
371 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
372 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
373 AG_GST_CHECK_LIBHEADER(X264, x264, x264_encoder_encode, -lm, x264.h,
374 AC_MSG_CHECKING([for uptodate x264 API version])
375 dnl _stdint not yet generated, so no compiling
376 AC_TRY_CPP([
377 #include <x264.h>
378 #if X264_BUILD < 55
379 #error "x264 build too old"
380 #endif
381 ], [
382 AC_MSG_RESULT(yes)
383 X264_LIBS="$LDFLAGS -lx264 -lm"
384 X264_CFLAGS="$CFLAGS"
385 AC_SUBST(X264_LIBS)
386 AC_SUBST(X264_CFLAGS)
387 ], [
388 AC_MSG_RESULT(no)
389 HAVE_X264=no
390 ]))
391 ])
393 else
395 dnl not building plugins with external dependencies,
396 dnl but we still need to set the conditionals
398 AM_CONDITIONAL(USE_A52DEC, false)
399 AM_CONDITIONAL(USE_AMRNB, false)
400 AM_CONDITIONAL(USE_AMRWB, false)
401 AM_CONDITIONAL(USE_CDIO, false)
402 AM_CONDITIONAL(USE_DVDREAD, false)
403 AM_CONDITIONAL(USE_LAME, false)
404 AM_CONDITIONAL(USE_MAD, false)
405 AM_CONDITIONAL(USE_MPEG2DEC, false)
406 AM_CONDITIONAL(USE_SIDPLAY, false)
407 AM_CONDITIONAL(USE_TWOLAME, false)
408 AM_CONDITIONAL(USE_X264, false)
410 fi dnl of EXT plugins
412 dnl *** finalize CFLAGS, LDFLAGS, LIBS
414 dnl Overview:
415 dnl GST_OPTION_CFLAGS: common flags for profiling, debugging, errors, ...
416 dnl GST_*: flags shared by built objects to link against GStreamer
417 dnl GST_ALL_LDFLAGS: linker flags shared by all
418 dnl GST_LIB_LDFLAGS: additional linker flags for all libaries
419 dnl GST_LT_LDFLAGS: library versioning of our libraries
420 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
422 dnl GST_OPTION_CFLAGS
423 if test "x$USE_DEBUG" = xyes; then
424 PROFILE_CFLAGS="-g"
425 fi
426 AC_SUBST(PROFILE_CFLAGS)
428 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
429 dnl Define _only_ during CVS (not pre-releases or releases)
430 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
431 else
432 DEPRECATED_CFLAGS=""
433 fi
434 AC_SUBST(DEPRECATED_CFLAGS)
436 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
437 dnl at make time with e.g. make ERROR_CFLAGS=""
438 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
439 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
440 AC_SUBST(GST_OPTION_CFLAGS)
441 AC_SUBST(GST_OPTION_CXXFLAGS)
443 dnl FIXME: do we want to rename to GST_ALL_* ?
444 dnl prefer internal headers to already installed ones
445 dnl also add builddir include for enumtypes and marshal
446 dnl add GST_OPTION_CFLAGS, but overridable
447 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
448 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
449 AC_SUBST(GST_CFLAGS)
450 AC_SUBST(GST_CXXFLAGS)
451 AC_SUBST(GST_LIBS)
453 dnl LDFLAGS really should only contain flags, not libs - they get added before
454 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
455 GST_ALL_LDFLAGS="-no-undefined"
456 AC_SUBST(GST_ALL_LDFLAGS)
458 dnl this really should only contain flags, not libs - they get added before
459 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
460 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
461 AC_SUBST(GST_PLUGIN_LDFLAGS)
463 dnl *** output files ***
465 AC_CONFIG_FILES(
466 Makefile
467 common/Makefile
468 common/m4/Makefile
469 gst-libs/Makefile
470 gst-libs/gst/Makefile
471 gst/Makefile
472 gst/asfdemux/Makefile
473 gst/dvdlpcmdec/Makefile
474 gst/dvdsub/Makefile
475 gst/iec958/Makefile
476 gst/mpegaudioparse/Makefile
477 gst/mpegstream/Makefile
478 gst/realmedia/Makefile
479 gst/synaesthesia/Makefile
480 ext/Makefile
481 ext/a52dec/Makefile
482 ext/amrnb/Makefile
483 ext/amrwbdec/Makefile
484 ext/cdio/Makefile
485 ext/dvdread/Makefile
486 ext/lame/Makefile
487 ext/mad/Makefile
488 ext/mpeg2dec/Makefile
489 ext/sidplay/Makefile
490 ext/twolame/Makefile
491 ext/x264/Makefile
492 docs/Makefile
493 docs/plugins/Makefile
494 docs/version.entities
495 tests/Makefile
496 tests/check/Makefile
497 m4/Makefile
498 po/Makefile.in
499 gst-plugins-ugly.spec
500 )
502 dnl Create the config.h file for Visual Studio builds
503 dnl Beware of spaces and /'s in some of the shell variable contents.
504 sed \
505 -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
506 -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
507 -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
508 -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
509 -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
510 -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
511 -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
512 -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
513 -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
514 -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
515 -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
516 -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
517 -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
518 -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
519 -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
520 -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
521 -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
522 -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
523 -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
524 -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
525 -e 's/.* LIBDIR$/#ifdef _DEBUG\n# define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n# define LIBDIR PREFIX "\\\\lib"\n#endif/' \
526 -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
527 -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
528 -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
529 -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
530 -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
531 -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
532 -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
533 -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n# define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n# define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
534 -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
535 -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
536 -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
537 -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
538 -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
539 -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
540 config.h.in >win32/common/config.h-new
542 AC_OUTPUT
544 AG_GST_OUTPUT_PLUGINS