configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.26,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 23, 0, 23)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4 -I .")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.17])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 113 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 dnl building of tests
 129 AC_ARG_ENABLE(tests,
 130   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 131   [
 132     case "${enableval}" in
 133       yes) BUILD_TESTS=yes ;;
 134       no)  BUILD_TESTS=no ;;
 135       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 136     esac
 137   ],
 138 [BUILD_TESTS=yes]) dnl Default value
 139 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 140
 141 dnl tests known to fail
 142 AC_ARG_ENABLE(failing-tests,
 143   AC_HELP_STRING([--disable-failing-tests],
 144     [disable building tests known to fail]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_FAILING_TESTS=yes ;;
 148       no)  BUILD_FAILING_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 150     esac
 151   ],
 152   [BUILD_FAILING_TESTS=no]) dnl Default value
 153 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 154 if test x$BUILD_FAILING_TESTS = xyes; then
 155   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 156 else
 157   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 158 fi
 159
 160 dnl poison destroyed objects
 161 AC_ARG_ENABLE(poisoning,
 162   AC_HELP_STRING([--enable-poisoning],
 163     [enable poisoning of deallocated objects]),
 164   [
 165     case "${enableval}" in
 166       yes) USE_POISONING=yes ;;
 167       no)  USE_POISONING=no ;;
 168       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 169     esac
 170   ],
 171   [USE_POISONING=no]) dnl Default value
 172 if test "x$USE_POISONING" = xyes; then
 173   AC_DEFINE(USE_POISONING, 1,
 174     [Define if we should poison deallocated memory])
 175 fi
 176
 177 dnl *** checks for platform ***
 178
 179 dnl * hardware/architecture *
 180
 181 dnl common/m4/gst-arch.m4
 182 dnl check CPU type
 183 AG_GST_ARCH
 184 dnl substitution for win32/common/config.h
 185 HOST_CPU=$host_cpu
 186 AC_SUBST(HOST_CPU)
 187
 188 dnl common/m4/gst-arch.m4
 189 dnl check for unaligned access
 190 AG_GST_UNALIGNED_ACCESS
 191 dnl create a configure variable for gst/gstconfig.h
 192 if test x${as_cv_unaligned_access} = xyes ; then
 193   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 194 else
 195   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 196 fi
 197 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 198
 199 dnl check for platform specific settings
 200 AG_GST_PLATFORM
 201
 202 dnl * software *
 203
 204 dnl check for large file support
 205 dnl affected plugins must include config.h
 206 AC_SYS_LARGEFILE
 207
 208 dnl *** checks for programs ***
 209
 210 dnl find a compiler
 211 AC_PROG_CC
 212
 213 dnl check if the compiler supports '-c' and '-o' options
 214 AM_PROG_CC_C_O
 215
 216 dnl find an assembler
 217 AM_PROG_AS
 218
 219 dnl Perl is used in building documentation and in the version checks
 220 AC_PATH_PROG(PERL_PATH, perl, no)
 221 if test x$PERL_PATH = xno; then
 222   AC_MSG_ERROR(Could not find perl)
 223 fi
 224
 225 dnl we require flex and bison for building the parser
 226 if test "x$GST_DISABLE_PARSE" != xyes; then
 227   AG_GST_BISON_CHECK
 228   AG_GST_FLEX_CHECK
 229 fi
 230
 231 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 232 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 233
 234 dnl check for gobject-introspection
 235 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 236
 237 dnl check for documentation tools
 238 AG_GST_DOCBOOK_CHECK
 239 GTK_DOC_CHECK([1.3])
 240 AS_PATH_PYTHON([2.1])
 241 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 242
 243 dnl *** checks for libraries ***
 244
 245 dnl check for libm, for sin()
 246 AC_CHECK_LIBM
 247 AC_SUBST(LIBM)
 248
 249 dnl *** checks for header files ***
 250
 251 dnl check if we have ANSI C header files
 252 AC_HEADER_STDC
 253
 254 dnl Check for ucontext.h
 255 AC_CHECK_HEADERS([ucontext.h])
 256
 257 dnl Check for sys/socket.h
 258 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 259 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 260
 261 dnl check for sys/times.h for tests/examples/adapter/
 262 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 263 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 264 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 265
 266 dnl Check for process.h for getpid() on win32
 267 AC_CHECK_HEADERS([process.h])
 268
 269 dnl Check for sys/utsname.h for uname
 270 AC_CHECK_HEADERS([sys/utsname.h])
 271
 272 dnl Check for stdio_ext.f for __fbufsize
 273 AC_CHECK_HEADERS([stdio_ext.h])
 274
 275 dnl check for pthreads
 276 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 277 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 278
 279 dnl Check for valgrind.h
 280 dnl separate from HAVE_VALGRIND because you can have the program, but not
 281 dnl the dev package
 282 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 283
 284 dnl used in gst/gstpoll.c
 285 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 286 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 287 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 288   WIN32_LIBS="-lws2_32"
 289   AC_SUBST(WIN32_LIBS)
 290 fi
 291
 292 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 293 if test "x$BUILD_TESTS" = "xyes"; then
 294   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 295                          __gmpz_init_set_d, ,
 296                          gmp.h,
 297                          GMP_LIBS="-lgmp"
 298                          AC_SUBST(GMP_LIBS)
 299                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 300   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 301                          gsl_rng_uniform_int, -lgslcblas,
 302                          gsl/gsl_rng.h,
 303                          GSL_LIBS="-lgsl -lgslcblas"
 304                          AC_SUBST(GSL_LIBS)
 305                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 306 fi
 307
 308 dnl *** checks for types/defines ***
 309
 310 dnl *** checks for structures ***
 311
 312 dnl *** checks for compiler characteristics ***
 313
 314 dnl check if the compiler supports __uint128_t (gcc)
 315 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 316     AC_TRY_COMPILE([ ], [
 317       unsigned long long v1 = 1024ULL;
 318       unsigned long long v2 = 0x8000000000000000ULL;
 319       __uint128_t u = ((__uint128_t)v1)*((__uint128_t)v2);
 320
 321       return 0;
 322     ], [
 323       gst_cv_uint128_t=yes
 324     ], [
 325       gst_cv_uint128_t=no
 326     ])
 327 )
 328 if test x$gst_cv_uint128_t = xyes; then
 329   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 330 fi
 331
 332 OPT_CFLAGS=
 333 dnl Check for some compiler flags that optimize our code.
 334 if test "x$GCC" = xyes; then
 335   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 336 fi
 337
 338 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 339 dnl flag
 340 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 341 dnl symbolic register names in inline asm
 342 if test x$HAVE_CPU_PPC = xyes ; then
 343   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 344     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 345 fi
 346
 347 dnl *** checks for library functions ***
 348
 349 AC_CHECK_FUNCS([sigaction])
 350
 351 dnl check for fseeko()
 352 AC_FUNC_FSEEKO
 353 dnl check for ftello()
 354 AC_CHECK_FUNCS([ftello])
 355
 356 AC_CHECK_FUNCS([fgetpos])
 357 AC_CHECK_FUNCS([fsetpos])
 358
 359 dnl check for poll(), ppoll() and pselect()
 360 AC_CHECK_FUNCS([poll])
 361 AC_CHECK_FUNCS([ppoll])
 362 AC_CHECK_FUNCS([pselect])
 363
 364 dnl ****************************************
 365 dnl *** GLib POLL* compatibility defines ***
 366 dnl ****************************************
 367
 368 AC_MSG_CHECKING([for broken poll])
 369 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 370         #include <stdlib.h>
 371         #include <fcntl.h>
 372         #include <poll.h>
 373         #ifdef HAVE_SYS_POLL_H
 374         #include <sys/poll.h>
 375         #endif
 376         int main(void) {
 377           struct pollfd fds[1];
 378           int fd;
 379           fd = open("/dev/null", 1);
 380           fds[0].fd = fd;
 381           fds[0].events = POLLIN;
 382           fds[0].revents = 0;
 383           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 384                 exit(1);  /* Does not work for devices -- fail */
 385           }
 386           exit(0);
 387         }]])],
 388   [broken_poll=no],
 389   [broken_poll=yes
 390    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 391   [broken_poll="no (cross compiling)"])
 392 AC_MSG_RESULT($broken_poll)
 393
 394 dnl check for mmap()
 395 AC_FUNC_MMAP
 396 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 397
 398 dnl Check for POSIX timers
 399 AC_CHECK_FUNCS(clock_gettime, [], [
 400   AC_CHECK_LIB(rt, clock_gettime, [
 401     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 402     LIBS="$LIBS -lrt"
 403   ])
 404 ])
 405
 406 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 407     AC_TRY_COMPILE([
 408 #include <time.h>
 409 #ifdef HAVE_UNISTD_H
 410 #include <unistd.h>
 411 #endif
 412     ], [
 413 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 414 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 415 #endif
 416       return 0;
 417     ], [
 418       gst_cv_posix_timers=yes
 419     ], [
 420       gst_cv_posix_timers=no
 421     ])
 422 )
 423
 424 if test "$gst_cv_posix_timers" = "yes"; then
 425   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 426   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 427 else
 428   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 429 fi
 430 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 431 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 432
 433 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 434     AC_TRY_COMPILE([
 435 #include <time.h>
 436 #ifdef HAVE_UNISTD_H
 437 #include <unistd.h>
 438 #endif
 439     ], [
 440 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 441 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 442 #endif
 443       return 0;
 444     ], [
 445       gst_cv_monotonic_clock=yes
 446     ], [
 447       gst_cv_monotonic_clock=no
 448     ])
 449 )
 450
 451 if test "$gst_cv_monotonic_clock" = "yes"; then
 452   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 453   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 454 else
 455   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 456 fi
 457 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 458 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 459
 460 dnl Check for a way to display the function name in debug output
 461 AG_GST_CHECK_FUNCTION
 462
 463 dnl test for register_printf_specifier or register_printf_function
 464 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 465     [HAVE_PRINTF_EXTENSION=yes])
 466
 467 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 468   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 469   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 470   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 471   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 472       [Defined if we have printf specifier extensions available])
 473 else
 474     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 475     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 476     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 477 fi
 478 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 479 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 480 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 481
 482 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 483 save_cflags="$CFLAGS"
 484 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 485 AC_CHECK_LIB(dl, dladdr,
 486    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 487    LIBS="$LIBS -ldl")
 488 CFLAGS="$save_cflags"
 489
 490 dnl *** checks for socket and nsl libraries ***
 491 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 492 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 493
 494 dnl check for inet_aton()
 495 save_libs="$LIBS"
 496 AC_CHECK_FUNC(inet_aton, ,
 497    AC_CHECK_LIB(nsl, inet_aton, ,
 498       AC_CHECK_LIB(socket, inet_aton, ,
 499          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 500 INET_ATON_LIBS=$LIBS
 501 AC_SUBST(INET_ATON_LIBS)
 502 LIBS="$save_libs"
 503
 504 dnl *** checks for dependency libraries ***
 505
 506 dnl GLib
 507 GLIB_REQ=2.18
 508
 509 AG_GST_GLIB_CHECK([$GLIB_REQ])
 510
 511 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 512 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 513 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 514
 515 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 516 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 517
 518 dnl Check for documentation xrefs
 519 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 520 AC_SUBST(GLIB_PREFIX)
 521
 522 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 523 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 524 then
 525   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 526   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 527 else
 528   dnl check for libxml2 with minimum req version
 529   AG_GST_LIBXML2_CHECK(2.4.9)
 530   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 531 fi
 532 AC_SUBST(GST_DISABLE_XML_DEFINE)
 533
 534 dnl building of unit test libraries
 535 AC_ARG_ENABLE(check,
 536   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 537   [
 538     case "${enableval}" in
 539       yes) BUILD_CHECK=yes ;;
 540       no)  BUILD_CHECK=no ;;
 541       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 542     esac
 543   ], [
 544     dnl Default value
 545     case $host_os in
 546       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 547       *) BUILD_CHECK=yes ;;
 548     esac
 549 ])
 550 dnl bit of a misnomer, but keep the conditional named like this so we don't
 551 dnl have to change too much elsewhere
 552 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 553
 554
 555 dnl *** set variables based on configure arguments
 556
 557 dnl set license and copyright notice
 558 GST_LICENSE="LGPL"
 559 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 560 AC_SUBST(GST_LICENSE)
 561
 562 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 563 AS_AC_EXPAND(LIBDIR, $libdir)
 564 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 565 AS_AC_EXPAND(DATADIR, $datadir)
 566 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 567
 568 dnl set location of plugin directory
 569 AG_GST_SET_PLUGINDIR
 570
 571 dnl FIXME: add LIBXML_PKG here if we use it
 572 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 573 AC_SUBST(GST_PKG_DEPS)
 574
 575 dnl define an ERROR_CFLAGS Makefile variable
 576 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 577
 578 dnl define correct level for debugging messages
 579 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 580
 581 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 582
 583 dnl Overview:
 584 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 585 dnl GST_ALL_*:          vars shared by all built objects
 586 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 587 dnl GST_OBJ_*:          additional vars to link to the core library
 588 dnl                     include GST_ALL_*
 589 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 590 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 591
 592 dnl GST_OPTION_CFLAGS
 593 if test "x$USE_DEBUG" = xyes; then
 594    PROFILE_CFLAGS="-g"
 595 fi
 596 AC_SUBST(PROFILE_CFLAGS)
 597
 598 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 599 # functionality from the API that gstreamer uses
 600 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 601 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 602   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 603   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 604 else
 605   DEPRECATED_CFLAGS=""
 606 fi
 607 AC_SUBST(DEPRECATED_CFLAGS)
 608
 609 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 610 dnl make DEPRECATED_CFLAGS=''
 611 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 612 AC_SUBST(GST_OPTION_CFLAGS)
 613
 614 dnl GST_ALL_*
 615 dnl vars common to for all internal objects (core libs, elements, applications)
 616 dnl CFLAGS:
 617 dnl - XML needs to be added because xmlPtr is used in core
 618 dnl - src and build dirs need to be added because every piece that gets built
 619 dnl   will need the GStreamer source and generated headers
 620 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 621 dnl       from LibXML except for in the core library
 622 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS) -DG_THREADS_MANDATORY"
 623
 624 dnl FIXME: check if LTLIBINTL is needed everywhere
 625 dnl I presume it is given that it contains the symbols that _() stuff maps to
 626 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 627
 628 dnl LDFLAGS really should only contain flags, not libs - they get added before
 629 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 630 GST_ALL_LDFLAGS="-no-undefined"
 631
 632 AC_SUBST(GST_ALL_CFLAGS)
 633 AC_SUBST(GST_ALL_LIBS)
 634 AC_SUBST(GST_ALL_LDFLAGS)
 635
 636 dnl GST_LIB_LDFLAGS
 637 dnl linker flags shared by all libraries
 638 dnl LDFLAGS modifier defining exported symbols from built libraries
 639 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 640 AC_SUBST(GST_LIB_LDFLAGS)
 641
 642 dnl GST_OBJ_*
 643 dnl default vars for all internal objects built on libgstreamer
 644 dnl includes GST_ALL_*
 645 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 646 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 647 AC_SUBST(GST_OBJ_CFLAGS)
 648 AC_SUBST(GST_OBJ_LIBS)
 649
 650 dnl GST_PLUGIN_LDFLAGS
 651 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 652 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 653 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 654
 655 dnl plugin scanner locations
 656 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 657 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 658     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 659
 660 dnl things for our internal libcheck (must be called even if building
 661 dnl libcheck is disabled because it defines conditionals)
 662 AG_GST_CHECK_CHECKS()
 663
 664 SHAVE_INIT([common],[enable])
 665
 666 AC_CONFIG_FILES(
 667 Makefile
 668 common/shave
 669 common/shave-libtool
 670 gst/Makefile
 671 gst/gstconfig.h
 672 gst/gstversion.h
 673 gst/parse/Makefile
 674 libs/Makefile
 675 libs/gst/Makefile
 676 libs/gst/base/Makefile
 677 libs/gst/check/Makefile
 678 libs/gst/check/libcheck/Makefile
 679 libs/gst/check/libcheck/check.h
 680 libs/gst/controller/Makefile
 681 libs/gst/dataprotocol/Makefile
 682 libs/gst/helpers/Makefile
 683 libs/gst/net/Makefile
 684 plugins/Makefile
 685 plugins/indexers/Makefile
 686 plugins/elements/Makefile
 687 po/Makefile.in
 688 tests/Makefile
 689 tests/benchmarks/Makefile
 690 tests/check/Makefile
 691 tests/misc/Makefile
 692 tests/examples/Makefile
 693 tests/examples/adapter/Makefile
 694 tests/examples/controller/Makefile
 695 tests/examples/stepping/Makefile
 696 tests/examples/helloworld/Makefile
 697 tests/examples/launch/Makefile
 698 tests/examples/manual/Makefile
 699 tests/examples/metadata/Makefile
 700 tests/examples/queue/Makefile
 701 tests/examples/streams/Makefile
 702 tests/examples/typefind/Makefile
 703 tests/examples/xml/Makefile
 704 tools/Makefile
 705 common/Makefile
 706 common/m4/Makefile
 707 docs/Makefile
 708 docs/design/Makefile
 709 docs/faq/Makefile
 710 docs/gst/Makefile
 711 docs/gst/gstreamer.types
 712 docs/libs/Makefile
 713 docs/plugins/Makefile
 714 docs/manual/Makefile
 715 docs/pwg/Makefile
 716 docs/slides/Makefile
 717 docs/xsl/Makefile
 718 docs/version.entities
 719 pkgconfig/Makefile
 720 stamp.h
 721 pkgconfig/gstreamer.pc
 722 pkgconfig/gstreamer-uninstalled.pc
 723 pkgconfig/gstreamer-base.pc
 724 pkgconfig/gstreamer-base-uninstalled.pc
 725 pkgconfig/gstreamer-check.pc
 726 pkgconfig/gstreamer-check-uninstalled.pc
 727 pkgconfig/gstreamer-controller.pc
 728 pkgconfig/gstreamer-controller-uninstalled.pc
 729 pkgconfig/gstreamer-dataprotocol.pc
 730 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 731 pkgconfig/gstreamer-net.pc
 732 pkgconfig/gstreamer-net-uninstalled.pc
 733 gst-element-check.m4
 734 gstreamer.spec
 735 )
 736
 737 dnl Create the config.h file for Visual Studio builds
 738 dnl Beware of spaces and /'s in some of the shell variable contents.
 739 sed \
 740     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 741     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 742     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 743     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 744     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 745     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 746     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 747     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 748     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 749     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 750     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 751     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 752     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 753     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 754     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 755     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 756     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 757     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 758     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 759     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 760     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 761     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 762     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 763     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 764     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 765     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 766     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 767     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 768     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 769     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 770     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 771     config.h.in >win32/common/config.h-new
 772
 773 AC_OUTPUT
 774
 775 dnl negate for output
 776 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 777 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 778 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 779 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 780 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 781 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 782 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 783 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 784 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 785
 786 echo "
 787
 788 Configuration
 789         Version                    : ${VERSION}
 790         Source code location       : ${srcdir}
 791         Prefix                     : ${prefix}
 792         Compiler                   : ${SHAVE_SAVED_CC}
 793         Package name               : ${GST_PACKAGE_NAME}
 794         Package origin             : ${GST_PACKAGE_ORIGIN}
 795
 796         Documentation (manuals)    : ${enable_docbook}
 797         Documentation (API)        : ${enable_gtk_doc}
 798
 799         Debug Logging              : ${enable_gst_debug}
 800         Pipeline XML load/save     : ${enable_loadsave}
 801         Command-line parser        : ${enable_parse}
 802         Option parsing in gst_init : ${enable_option_parsing}
 803         Tracing subsystem          : ${enable_trace}
 804         Allocation tracing         : ${enable_alloc_trace}
 805         Plugin registry            : ${enable_registry}
 806         Plugin support             : ${enable_plugin}
 807         Network support            : ${enable_net}
 808         Unit testing support       : ${BUILD_CHECK}
 809
 810         Debug                      : ${USE_DEBUG}
 811         Profiling                  : ${USE_PROFILING}
 812
 813         Building examples          : ${BUILD_EXAMPLES}
 814         Building test apps         : ${BUILD_TESTS}
 815         Building tests that fail   : ${BUILD_FAILING_TESTS}
 816 "