gststructure: clarify _get docs about the returned reference
[glsdk/gstreamer0-10.git] / configure.ac
1 AC_PREREQ(2.60)
3 dnl initialize autoconf
4 dnl when going to/from release please set the nano (fourth number) right !
5 dnl releases only do Wall, git and prerelease does Werror too
6 AC_INIT(GStreamer, 0.10.35.2,
7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
8     gstreamer)
9 AG_GST_INIT
11 dnl initialize automake (we require GNU make)
12 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
14 dnl define PACKAGE_VERSION_* variables
15 AS_VERSION
17 dnl check if this is a release version
18 AS_NANO(GST_GIT="no", GST_GIT="yes")
20 dnl can autoconf find the source ?
21 AC_CONFIG_SRCDIR([gst/gst.c])
23 dnl define the output header for config
24 AM_CONFIG_HEADER([config.h])
26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
27 AM_MAINTAINER_MODE
29 dnl sets host_* variables
30 AC_CANONICAL_HOST
32 dnl use pretty build output with automake >= 1.11
33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
34   [AM_DEFAULT_VERBOSITY=1
35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
37 dnl our libraries and install dirs use major.minor as a version
38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
39 dnl we override it here for release candidates for a new series
40 GST_MAJORMINOR=0.10
41 AC_SUBST(GST_MAJORMINOR)
42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
43   [library major.minor version])
45 dnl CURRENT, REVISION, AGE
46 dnl - library source changed -> increment REVISION
47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
48 dnl - interfaces added -> increment AGE
49 dnl - interfaces removed -> AGE = 0
50 dnl sets GST_LT_LDFLAGS
51 AS_LIBTOOL(GST, 30, 0, 30)
53 dnl FIXME: this macro doesn't actually work;
54 dnl the generated libtool script has no support for the listed tags.
55 dnl So this needs to be fixed first if we want to use this
56 dnl AS_LIBTOOL_TAGS
58 AC_LIBTOOL_WIN32_DLL
59 AM_PROG_LIBTOOL
61 dnl *** autotools stuff ****
63 dnl allow for different autotools
64 AS_AUTOTOOLS_ALTERNATE
66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
69 dnl set up gettext
70 dnl the version check needs to stay here because autopoint greps for it
71 AM_GNU_GETTEXT_VERSION([0.17])
72 AM_GNU_GETTEXT([external])
73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
75 dnl *** check for arguments to configure ***
77 dnl subsystems - can influence other decisions so needs to be high up
78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
81 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
82 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
83 dnl define a substitution to use in docs/gst/gstreamer.types
84 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
85 then
86   GST_LOADSAVE_DOC_TYPES="%"
87 else
88   GST_LOADSAVE_DOC_TYPES=
89 fi
90 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
93 if test "x$GST_DISABLE_PARSE" = xyes; then
94   AC_DEFINE(GST_DISABLE_PARSE, 1,
95     [Define if pipeline parsing code is disabled])
96 fi
97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
101     [Define if option parsing is disabled])
102 fi
103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
109 dnl define a substitution to use in docs/gst/gstreamer.types
110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
111 then
112   GST_REGISTRY_DOC_TYPES="%"
113 else
114   GST_REGISTRY_DOC_TYPES=
115 fi
116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
122 AG_GST_ARG_DEBUG
123 AG_GST_ARG_PROFILING
124 AG_GST_ARG_VALGRIND
125 AG_GST_ARG_GCOV
127 AG_GST_ARG_EXAMPLES
129 AG_GST_ARG_WITH_PKG_CONFIG_PATH
130 AG_GST_ARG_WITH_PACKAGE_NAME
131 AG_GST_ARG_WITH_PACKAGE_ORIGIN
133 AG_GST_PKG_CONFIG_PATH
135 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
136   ["${srcdir}/gstreamer.doap"],
137   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
139 dnl building of tests
140 AC_ARG_ENABLE(tests,
141   AC_HELP_STRING([--disable-tests], [disable building test apps]),
142   [
143     case "${enableval}" in
144       yes) BUILD_TESTS=yes ;;
145       no)  BUILD_TESTS=no ;;
146       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
147     esac
148   ],
149 [BUILD_TESTS=yes]) dnl Default value
150 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
152 dnl tests known to fail
153 AC_ARG_ENABLE(failing-tests,
154   AC_HELP_STRING([--disable-failing-tests],
155     [disable building tests known to fail]),
156   [
157     case "${enableval}" in
158       yes) BUILD_FAILING_TESTS=yes ;;
159       no)  BUILD_FAILING_TESTS=no ;;
160       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
161     esac
162   ],
163   [BUILD_FAILING_TESTS=no]) dnl Default value
164 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
165 if test x$BUILD_FAILING_TESTS = xyes; then
166   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
167 else
168   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
169 fi
171 dnl poison destroyed objects
172 AC_ARG_ENABLE(poisoning,
173   AC_HELP_STRING([--enable-poisoning],
174     [enable poisoning of deallocated objects]),
175   [
176     case "${enableval}" in
177       yes) USE_POISONING=yes ;;
178       no)  USE_POISONING=no ;;
179       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
180     esac
181   ],
182   [USE_POISONING=no]) dnl Default value
183 if test "x$USE_POISONING" = xyes; then
184   AC_DEFINE(USE_POISONING, 1,
185     [Define if we should poison deallocated memory])
186 fi
188 dnl *** checks for platform ***
190 dnl * hardware/architecture *
192 dnl common/m4/gst-arch.m4
193 dnl check CPU type
194 AG_GST_ARCH
195 dnl substitution for win32/common/config.h
196 HOST_CPU=$host_cpu
197 AC_SUBST(HOST_CPU)
199 dnl common/m4/gst-arch.m4
200 dnl check for unaligned access
201 AG_GST_UNALIGNED_ACCESS
202 dnl create a configure variable for gst/gstconfig.h
203 if test x${as_cv_unaligned_access} = xyes ; then
204   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
205 else
206   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
207 fi
208 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
210 dnl check for platform specific settings
211 AG_GST_PLATFORM
213 dnl * software *
215 dnl check for large file support
216 dnl affected plugins must include config.h
217 AC_SYS_LARGEFILE
219 dnl *** checks for programs ***
221 dnl find a compiler
222 AC_PROG_CC
223 AC_PROG_CC_STDC
225 dnl check if the compiler supports '-c' and '-o' options
226 AM_PROG_CC_C_O
228 dnl find an assembler
229 AM_PROG_AS
231 dnl determine if c++ is available on this system
232 AC_PROG_CXX
233 dnl CXX may be set to some default even if no c++ compiler is available
234 dnl (thanks autotools!), so just try to compile some c++ code to make sure
235 AC_LANG_PUSH([C++])
236 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
237 AC_LANG_POP([C++])
238 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
239 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
241 dnl Perl is used in building documentation and in the version checks
242 AC_PATH_PROG(PERL_PATH, perl, no)
243 if test x$PERL_PATH = xno; then
244   AC_MSG_ERROR(Could not find perl)
245 fi
247 dnl we require flex and bison for building the parser
248 if test "x$GST_DISABLE_PARSE" != xyes; then
249   AG_GST_BISON_CHECK
250   AG_GST_FLEX_CHECK
251 fi
253 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
254 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
256 dnl check for gobject-introspection
257 GOBJECT_INTROSPECTION_CHECK([0.6.8])
259 dnl check for documentation tools
260 AG_GST_DOCBOOK_CHECK
261 GTK_DOC_CHECK([1.3])
262 AS_PATH_PYTHON([2.1])
263 AG_GST_PLUGIN_DOCS([1.3],[2.1])
265 dnl *** checks for libraries ***
267 dnl check for libm, for sin()
268 AC_CHECK_LIBM
269 AC_SUBST(LIBM)
271 dnl *** checks for header files ***
273 dnl check if we have ANSI C header files
274 AC_HEADER_STDC
276 dnl Check for ucontext.h
277 AC_CHECK_HEADERS([ucontext.h])
279 dnl Check for sys/socket.h
280 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
281 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
283 dnl check for sys/times.h for tests/examples/adapter/
284 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
285 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
286 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
288 dnl Check for process.h for getpid() on win32
289 AC_CHECK_HEADERS([process.h])
291 dnl Check for sys/utsname.h for uname
292 AC_CHECK_HEADERS([sys/utsname.h])
294 dnl Check for stdio_ext.f for __fbufsize
295 AC_CHECK_HEADERS([stdio_ext.h])
297 dnl check for pthreads
298 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
299 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
301 dnl check for sys/prctl for setting thread name on Linux
302 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
304 dnl Check for valgrind.h
305 dnl separate from HAVE_VALGRIND because you can have the program, but not
306 dnl the dev package
307 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
309 dnl used in gst/gstpoll.c
310 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
311 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
312 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
313   WIN32_LIBS="-lws2_32"
314   AC_SUBST(WIN32_LIBS)
315 fi
317 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
318 if test "x$BUILD_TESTS" = "xyes"; then
319   AG_GST_CHECK_LIBHEADER(GMP, gmp,
320                          __gmpz_init_set_d, ,
321                          gmp.h,
322                          GMP_LIBS="-lgmp"
323                          AC_SUBST(GMP_LIBS)
324                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
325   AG_GST_CHECK_LIBHEADER(GSL, gsl,
326                          gsl_rng_uniform_int, -lgslcblas,
327                          gsl/gsl_rng.h,
328                          GSL_LIBS="-lgsl -lgslcblas"
329                          AC_SUBST(GSL_LIBS)
330                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
331 fi
333 dnl *** checks for types/defines ***
335 dnl *** checks for structures ***
337 dnl *** checks for compiler characteristics ***
339 dnl check if the compiler supports __uint128_t (gcc)
340 dnl Actually check for 128-bit division, since that's what we use
341 dnl uint128_t for.
342 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
343     AC_TRY_LINK([ ], [
344       static __uint128_t v1 = 100;
345       static __uint128_t v2 = 10;
346       static __uint128_t u;
347       u = v1 / v2;
348     ], [
349       gst_cv_uint128_t=yes
350     ], [
351       gst_cv_uint128_t=no
352     ])
354 if test x$gst_cv_uint128_t = xyes; then
355   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
356 fi
358 dnl *** checking for tm_gmtoff ***
359 AC_MSG_CHECKING([for tm_gmtoff])
360 AC_RUN_IFELSE([AC_LANG_SOURCE([[
361         #include <time.h>
362         int main(void) {
363           struct tm t;
364           t.tm_gmtoff = 0;
365           exit(0);
366         }]])],
367   [have_tm_gmtoff=yes
368    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
369   [have_tm_gmtoff=no],
370   [have_tm_gmtoff="no (cross compiling)"])
371 AC_MSG_RESULT($have_tm_gmtoff)
374 dnl *** checks for library functions ***
376 AC_CHECK_FUNCS([gmtime_r])
377 AC_CHECK_FUNCS([localtime_r])
378 AC_CHECK_FUNCS([sigaction])
380 dnl check for fseeko()
381 AC_FUNC_FSEEKO
382 dnl check for ftello()
383 AC_CHECK_FUNCS([ftello])
385 AC_CHECK_FUNCS([fgetpos])
386 AC_CHECK_FUNCS([fsetpos])
388 dnl check for poll(), ppoll() and pselect()
389 AC_CHECK_FUNCS([poll])
390 AC_CHECK_FUNCS([ppoll])
391 AC_CHECK_FUNCS([pselect])
393 AC_CHECK_HEADERS([sys/poll.h])
395 dnl ****************************************
396 dnl *** GLib POLL* compatibility defines ***
397 dnl ****************************************
399 AC_MSG_CHECKING([for broken poll])
400 AC_RUN_IFELSE([AC_LANG_SOURCE([[
401         #include <stdlib.h>
402         #include <fcntl.h>
403         #include <poll.h>
404         #ifdef HAVE_SYS_POLL_H
405         #include <sys/poll.h>
406         #endif
407         int main(void) {
408           struct pollfd fds[1];
409           int fd;
410           fd = open("/dev/null", 1);
411           fds[0].fd = fd;
412           fds[0].events = POLLIN;
413           fds[0].revents = 0;
414           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
415                 exit(1);  /* Does not work for devices -- fail */
416           }
417           exit(0);
418         }]])],
419   [broken_poll=no],
420   [broken_poll=yes
421    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
422   [broken_poll="no (cross compiling)"])
423 AC_MSG_RESULT($broken_poll)
425 dnl check for mmap()
426 AC_FUNC_MMAP
427 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
429 dnl check for posix_memalign(), getpagesize()
430 AC_CHECK_FUNCS([posix_memalign])
431 AC_CHECK_FUNCS([getpagesize])
433 dnl Check for POSIX timers
434 AC_CHECK_FUNCS(clock_gettime, [], [
435   AC_CHECK_LIB(rt, clock_gettime, [
436     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
437     LIBS="$LIBS -lrt"
438   ])
439 ])
441 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
442     AC_TRY_COMPILE([
443 #include <time.h>
444 #ifdef HAVE_UNISTD_H
445 #include <unistd.h>
446 #endif
447     ], [
448 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
449 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
450 #endif
451     ], [
452       gst_cv_posix_timers=yes
453     ], [
454       gst_cv_posix_timers=no
455     ])
458 if test "$gst_cv_posix_timers" = "yes"; then
459   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
460   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
461 else
462   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
463 fi
464 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
465 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
467 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
468     AC_TRY_COMPILE([
469 #include <time.h>
470 #ifdef HAVE_UNISTD_H
471 #include <unistd.h>
472 #endif
473     ], [
474 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
475 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
476 #endif
477     ], [
478       gst_cv_monotonic_clock=yes
479     ], [
480       gst_cv_monotonic_clock=no
481     ])
484 if test "$gst_cv_monotonic_clock" = "yes"; then
485   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
486   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
487 else
488   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
489 fi
490 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
491 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
493 dnl Check for a way to display the function name in debug output
494 AG_GST_CHECK_FUNCTION
496 dnl test for register_printf_specifier or register_printf_function
497 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
498     [HAVE_PRINTF_EXTENSION=yes])
500 if test "$HAVE_PRINTF_EXTENSION" = yes; then
501   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
502   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
503   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
504   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
505       [Defined if we have printf specifier extensions available])
506 else
507     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
508     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
509     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
510 fi
511 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
512 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
513 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
515 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
516 save_cflags="$CFLAGS"
517 CFLAGS="$CFLAGS -D_GNU_SOURCE"
518 AC_CHECK_LIB(dl, dladdr,
519    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
520    LIBS="$LIBS -ldl")
521 CFLAGS="$save_cflags"
523 dnl *** checks for socket and nsl libraries ***
524 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
525 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
527 dnl check for inet_aton()
528 save_libs="$LIBS"
529 AC_CHECK_FUNC(inet_aton, ,
530    AC_CHECK_LIB(nsl, inet_aton, ,
531       AC_CHECK_LIB(socket, inet_aton, ,
532          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
533 INET_ATON_LIBS=$LIBS
534 AC_SUBST(INET_ATON_LIBS)
535 LIBS="$save_libs"
537 dnl *** checks for dependency libraries ***
539 dnl GLib
540 GLIB_REQ=2.24
542 AG_GST_GLIB_CHECK([$GLIB_REQ])
544 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
545 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
546 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
548 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
549 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
551 dnl Check for documentation xrefs
552 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
553 AC_SUBST(GLIB_PREFIX)
555 dnl libxml2 is only needed for xml loading/saving of pipelines these days
556 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
557 then
558   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
559   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
560 else
561   dnl check for libxml2 with minimum req version
562   AG_GST_LIBXML2_CHECK(2.4.9)
563   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
564 fi
565 AC_SUBST(GST_DISABLE_XML_DEFINE)
567 dnl building of unit test libraries
568 AC_ARG_ENABLE(check,
569   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
570   [
571     case "${enableval}" in
572       yes) BUILD_CHECK=yes ;;
573       no)  BUILD_CHECK=no ;;
574       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
575     esac
576   ], [
577     dnl Default value
578     case $host_os in
579       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
580       *) BUILD_CHECK=yes ;;
581     esac
582 ])
583 dnl bit of a misnomer, but keep the conditional named like this so we don't
584 dnl have to change too much elsewhere
585 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
587 dnl configure the desired buffer alignment
588 AC_ARG_WITH([buffer-alignment],
589   AS_HELP_STRING([--with-buffer-alignment],[8,N,malloc,pagesize (default is 32)]),
590   [
591     if test "x$withval" = "xyes"
592     then
593       AC_DEFINE(BUFFER_ALIGNMENT, 32, [Buffer alignment to use])
594     else
595       case "${withval}" in
596         malloc) AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default]) ;;
597         pagesize)  AC_DEFINE(BUFFER_ALIGNMENT_PAGESIZE, 1, [Buffer alignment by pagesize]) ;;
598         *)   AC_DEFINE_UNQUOTED(BUFFER_ALIGNMENT, ${withval}, [Buffer alignment to use]) ;;
599       esac
600     fi
601   ], [
602     AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default]) 
603   ]
606 dnl Check for -Bsymbolic-functions linker flag used to avoid
607 dnl intra-library PLT jumps, if available.
608 AC_ARG_ENABLE(Bsymbolic,
609               [AC_HELP_STRING([--disable-Bsymbolic],
610                               [avoid linking with -Bsymbolic])],,
611               [SAVED_LDFLAGS="${LDFLAGS}"
612                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
613                LDFLAGS=-Wl,-Bsymbolic-functions
614                AC_TRY_LINK([], [int main (void) { return 0; }],
615                            AC_MSG_RESULT(yes)
616                            enable_Bsymbolic=yes,
617                            AC_MSG_RESULT(no)
618                            enable_Bsymbolic=no)
619                LDFLAGS="${SAVED_LDFLAGS}"])
622 dnl *** set variables based on configure arguments
624 dnl set license and copyright notice
625 GST_LICENSE="LGPL"
626 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
627 AC_SUBST(GST_LICENSE)
629 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
630 AS_AC_EXPAND(LIBDIR, $libdir)
631 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
632 AS_AC_EXPAND(DATADIR, $datadir)
633 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
635 dnl set location of plugin directory
636 AG_GST_SET_PLUGINDIR
638 dnl FIXME: add LIBXML_PKG here if we use it
639 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
640 AC_SUBST(GST_PKG_DEPS)
642 dnl make sure it doesn't complain about unused variables if debugging is disabled
643 NO_WARNINGS=""
644 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
645   NO_WARNINGS="-Wno-unused"
646 fi
648 dnl define an ERROR_CFLAGS Makefile variable
649 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
651 dnl define correct level for debugging messages
652 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
654 dnl *** finalize CFLAGS, LDFLAGS, LIBS
656 dnl Overview:
657 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
658 dnl GST_ALL_*:          vars shared by all built objects
659 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
660 dnl GST_OBJ_*:          additional vars to link to the core library
661 dnl                     include GST_ALL_*
662 dnl GST_LT_LDFLAGS:     library versioning of our libraries
663 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
665 dnl GST_OPTION_CFLAGS
666 if test "x$USE_DEBUG" = xyes; then
667    PROFILE_CFLAGS="-g"
668 fi
669 AC_SUBST(PROFILE_CFLAGS)
671 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
672 # functionality from the API that gstreamer uses
673 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
674 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
675   dnl Define _only_ when compiling from git (not for pre-releases or releases)
676   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
677 else
678   DEPRECATED_CFLAGS=""
679 fi
680 AC_SUBST(DEPRECATED_CFLAGS)
682 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
683 dnl make DEPRECATED_CFLAGS=''
684 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
685 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
686 AC_SUBST(GST_OPTION_CFLAGS)
687 AC_SUBST(GST_OPTION_CXXFLAGS)
689 dnl GST_ALL_*
690 dnl vars common to for all internal objects (core libs, elements, applications)
691 dnl CFLAGS:
692 dnl - XML needs to be added because xmlPtr is used in core
693 dnl - src and build dirs need to be added because every piece that gets built
694 dnl   will need the GStreamer source and generated headers
695 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
696 dnl       from LibXML except for in the core library
697 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
698 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
700 dnl FIXME: check if LTLIBINTL is needed everywhere
701 dnl I presume it is given that it contains the symbols that _() stuff maps to
702 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
704 dnl LDFLAGS really should only contain flags, not libs - they get added before
705 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
706 GST_ALL_LDFLAGS="-no-undefined"
707 if test "x${enable_Bsymbolic}" = "xyes"; then
708   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
709 fi
711 AC_SUBST(GST_ALL_CFLAGS)
712 AC_SUBST(GST_ALL_CXXFLAGS)
713 AC_SUBST(GST_ALL_LIBS)
714 AC_SUBST(GST_ALL_LDFLAGS)
716 dnl GST_LIB_LDFLAGS
717 dnl linker flags shared by all libraries
718 dnl LDFLAGS modifier defining exported symbols from built libraries
719 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
720 AC_SUBST(GST_LIB_LDFLAGS)
722 dnl GST_OBJ_*
723 dnl default vars for all internal objects built on libgstreamer
724 dnl includes GST_ALL_*
725 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
726 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
727 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
728 AC_SUBST(GST_OBJ_CFLAGS)
729 AC_SUBST(GST_OBJ_CXXFLAGS)
730 AC_SUBST(GST_OBJ_LIBS)
732 dnl GST_PLUGIN_LDFLAGS
733 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
734 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
735 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
737 dnl plugin scanner locations
738 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
739 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
740     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
741 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
743 dnl things for our internal libcheck (must be called even if building
744 dnl libcheck is disabled because it defines conditionals)
745 AG_GST_CHECK_CHECKS()
747 AC_CONFIG_FILES(
748 Makefile
749 gst/Makefile
750 gst/gstconfig.h
751 gst/gstversion.h
752 gst/parse/Makefile
753 libs/Makefile
754 libs/gst/Makefile
755 libs/gst/base/Makefile
756 libs/gst/check/Makefile
757 libs/gst/check/libcheck/Makefile
758 libs/gst/check/libcheck/check.h
759 libs/gst/controller/Makefile
760 libs/gst/dataprotocol/Makefile
761 libs/gst/helpers/Makefile
762 libs/gst/net/Makefile
763 plugins/Makefile
764 plugins/indexers/Makefile
765 plugins/elements/Makefile
766 po/Makefile.in
767 tests/Makefile
768 tests/benchmarks/Makefile
769 tests/check/Makefile
770 tests/misc/Makefile
771 tests/examples/Makefile
772 tests/examples/adapter/Makefile
773 tests/examples/controller/Makefile
774 tests/examples/stepping/Makefile
775 tests/examples/helloworld/Makefile
776 tests/examples/launch/Makefile
777 tests/examples/manual/Makefile
778 tests/examples/metadata/Makefile
779 tests/examples/queue/Makefile
780 tests/examples/streams/Makefile
781 tests/examples/typefind/Makefile
782 tools/Makefile
783 common/Makefile
784 common/m4/Makefile
785 docs/Makefile
786 docs/design/Makefile
787 docs/faq/Makefile
788 docs/gst/Makefile
789 docs/gst/gstreamer.types
790 docs/libs/Makefile
791 docs/plugins/Makefile
792 docs/manual/Makefile
793 docs/pwg/Makefile
794 docs/slides/Makefile
795 docs/xsl/Makefile
796 docs/version.entities
797 m4/Makefile
798 pkgconfig/Makefile
799 stamp.h
800 pkgconfig/gstreamer.pc
801 pkgconfig/gstreamer-uninstalled.pc
802 pkgconfig/gstreamer-base.pc
803 pkgconfig/gstreamer-base-uninstalled.pc
804 pkgconfig/gstreamer-check.pc
805 pkgconfig/gstreamer-check-uninstalled.pc
806 pkgconfig/gstreamer-controller.pc
807 pkgconfig/gstreamer-controller-uninstalled.pc
808 pkgconfig/gstreamer-dataprotocol.pc
809 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
810 pkgconfig/gstreamer-net.pc
811 pkgconfig/gstreamer-net-uninstalled.pc
812 gst-element-check.m4
813 gstreamer.spec
816 dnl Create the config.h file for Visual Studio builds
817 dnl Beware of spaces and /'s in some of the shell variable contents.
818 sed \
819     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
820     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
821     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
822     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
823     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
824     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
825     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
826     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
827     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
828     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
829     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
830     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
831     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
832     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
833     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
834     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
835     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
836     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
837     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
838     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
839     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
840     -e 's/.* BUFFER_ALIGNMENT_MALLOC/#define BUFFER_ALIGNMENT_MALLOC 1/' \
841     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
842     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
843     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
844     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
845     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
846     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
847     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
848     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
849     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
850     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
851     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
852     config.h.in >win32/common/config.h-new
854 AC_OUTPUT
856 dnl negate for output
857 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
858 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
859 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
860 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
861 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
862 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
863 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
864 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
865 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
867 echo "
869 Configuration
870         Version                    : ${VERSION}
871         Source code location       : ${srcdir}
872         Prefix                     : ${prefix}
873         Compiler                   : ${CC}
874         Package name               : ${GST_PACKAGE_NAME}
875         Package origin             : ${GST_PACKAGE_ORIGIN}
877         Documentation (manuals)    : ${enable_docbook}
878         Documentation (API)        : ${enable_gtk_doc}
880         Debug Logging              : ${enable_gst_debug}
881         Pipeline XML load/save     : ${enable_loadsave}
882         Command-line parser        : ${enable_parse}
883         Option parsing in gst_init : ${enable_option_parsing}
884         Tracing subsystem          : ${enable_trace}
885         Allocation tracing         : ${enable_alloc_trace}
886         Plugin registry            : ${enable_registry}
887         Plugin support             : ${enable_plugin}
888         Network support            : ${enable_net}
889         Unit testing support       : ${BUILD_CHECK}
891         Debug                      : ${USE_DEBUG}
892         Profiling                  : ${USE_PROFILING}
894         Building examples          : ${BUILD_EXAMPLES}
895         Building test apps         : ${BUILD_TESTS}
896         Building tests that fail   : ${BUILD_FAILING_TESTS}