configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.24.3,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 22, 0, 22)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4 -I .")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.17])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 113 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 dnl building of tests
 129 AC_ARG_ENABLE(tests,
 130   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 131   [
 132     case "${enableval}" in
 133       yes) BUILD_TESTS=yes ;;
 134       no)  BUILD_TESTS=no ;;
 135       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 136     esac
 137   ],
 138 [BUILD_TESTS=yes]) dnl Default value
 139 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 140
 141 dnl tests known to fail
 142 AC_ARG_ENABLE(failing-tests,
 143   AC_HELP_STRING([--disable-failing-tests],
 144     [disable building tests known to fail]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_FAILING_TESTS=yes ;;
 148       no)  BUILD_FAILING_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 150     esac
 151   ],
 152   [BUILD_FAILING_TESTS=no]) dnl Default value
 153 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 154 if test x$BUILD_FAILING_TESTS = xyes; then
 155   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 156 else
 157   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 158 fi
 159
 160 dnl poison destroyed objects
 161 AC_ARG_ENABLE(poisoning,
 162   AC_HELP_STRING([--enable-poisoning],
 163     [enable poisoning of deallocated objects]),
 164   [
 165     case "${enableval}" in
 166       yes) USE_POISONING=yes ;;
 167       no)  USE_POISONING=no ;;
 168       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 169     esac
 170   ],
 171   [USE_POISONING=no]) dnl Default value
 172 if test "x$USE_POISONING" = xyes; then
 173   AC_DEFINE(USE_POISONING, 1,
 174     [Define if we should poison deallocated memory])
 175 fi
 176
 177 dnl *** checks for platform ***
 178
 179 dnl * hardware/architecture *
 180
 181 dnl common/m4/gst-arch.m4
 182 dnl check CPU type
 183 AG_GST_ARCH
 184 dnl substitution for win32/common/config.h
 185 HOST_CPU=$host_cpu
 186 AC_SUBST(HOST_CPU)
 187
 188 dnl common/m4/gst-arch.m4
 189 dnl check for unaligned access
 190 AG_GST_UNALIGNED_ACCESS
 191 dnl create a configure variable for gst/gstconfig.h
 192 if test x${as_cv_unaligned_access} = xyes ; then
 193   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 194 else
 195   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 196 fi
 197 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 198
 199 dnl check for platform specific settings
 200 case $host_os in
 201      rhapsody*)
 202         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 203         ;;
 204      darwin*)
 205         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 206         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 207         AC_DEFINE_UNQUOTED(HAVE_OSX, 1, [Defined if compiling for OSX])
 208         ;;
 209      cygwin*)
 210         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 211         ;;
 212      mingw* | msvc* | mks*)
 213         dnl HAVE_WIN32 currently means "disable POSIXisms".
 214         AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 215
 216         dnl define __MSVCRT_VERSION__ version if not set already by the
 217         dnl compiler (ie. mostly for mingw). This is needed for things like
 218         dnl __stat64 to be available. If set by the compiler, ensure it's
 219         dnl new enough - we need at least WinXP SP2.
 220         AC_TRY_COMPILE([ ], [ return __MSVCRT_VERSION__; ], [
 221             AC_TRY_COMPILE([ ], [
 222               #if __MSVCRT_VERSION__ < 0x0601
 223               #error "MSVCRT too old"
 224               #endif
 225             ], [
 226               AC_MSG_NOTICE([MSVCRT version looks ok])
 227             ], [
 228               AC_MSG_ERROR([MSVCRT version too old, need at least WinXP SP2])
 229             ])
 230         ], [
 231           AC_MSG_NOTICE([Setting MSVCRT version to 0x0601])
 232           AC_DEFINE_UNQUOTED(__MSVCRT_VERSION__, 0x0601, [We need at least WinXP SP2 for __stat64])
 233         ])
 234         ;;
 235      *)
 236         ;;
 237 esac
 238
 239 dnl * software *
 240
 241 dnl check for large file support
 242 dnl affected plugins must include config.h
 243 AC_SYS_LARGEFILE
 244
 245 dnl *** checks for programs ***
 246
 247 dnl find a compiler
 248 AC_PROG_CC
 249
 250 dnl check if the compiler supports '-c' and '-o' options
 251 AM_PROG_CC_C_O
 252
 253 dnl find an assembler
 254 AM_PROG_AS
 255
 256 dnl Perl is used in building documentation and in the version checks
 257 AC_PATH_PROG(PERL_PATH, perl, no)
 258 if test x$PERL_PATH = xno; then
 259   AC_MSG_ERROR(Could not find perl)
 260 fi
 261
 262 dnl we require flex and bison for building the parser
 263 if test "x$GST_DISABLE_PARSE" != xyes; then
 264   AG_GST_BISON_CHECK
 265   AG_GST_FLEX_CHECK
 266 fi
 267
 268 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 269 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 270
 271 dnl check for gobject-introspection
 272 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 273
 274 dnl check for documentation tools
 275 AG_GST_DOCBOOK_CHECK
 276 GTK_DOC_CHECK([1.3])
 277 AS_PATH_PYTHON([2.1])
 278 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 279
 280 dnl *** checks for libraries ***
 281
 282 dnl check for libm, for sin()
 283 AC_CHECK_LIBM
 284 AC_SUBST(LIBM)
 285
 286 dnl *** checks for header files ***
 287
 288 dnl check if we have ANSI C header files
 289 AC_HEADER_STDC
 290
 291 dnl Check for ucontext.h
 292 AC_CHECK_HEADERS([ucontext.h])
 293
 294 dnl Check for sys/socket.h
 295 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 296 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 297
 298 dnl check for sys/times.h for tests/examples/adapter/
 299 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 300 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 301 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 302
 303 dnl Check for process.h for getpid() on win32
 304 AC_CHECK_HEADERS([process.h])
 305
 306 dnl Check for sys/utsname.h for uname
 307 AC_CHECK_HEADERS([sys/utsname.h])
 308
 309 dnl Check for stdio_ext.f for __fbufsize
 310 AC_CHECK_HEADERS([stdio_ext.h])
 311
 312 dnl check for pthreads
 313 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 314 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 315
 316 dnl Check for valgrind.h
 317 dnl separate from HAVE_VALGRIND because you can have the program, but not
 318 dnl the dev package
 319 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 320
 321 dnl used in gst/gstpoll.c
 322 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 323 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 324 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 325   WIN32_LIBS="-lws2_32"
 326   AC_SUBST(WIN32_LIBS)
 327 fi
 328
 329 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 330 AG_GST_CHECK_LIBHEADER(GMP, gmp,
 331                         __gmpz_init_set_d, ,
 332                         gmp.h,
 333                         GMP_LIBS="-lgmp"
 334                         AC_SUBST(GMP_LIBS)
 335                         AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 336 AG_GST_CHECK_LIBHEADER(GSL, gsl,
 337                         gsl_rng_uniform_int, -lgslcblas,
 338                         gsl/gsl_rng.h,
 339                         GSL_LIBS="-lgsl -lgslcblas"
 340                         AC_SUBST(GSL_LIBS)
 341                         AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 342
 343 dnl *** checks for types/defines ***
 344
 345 dnl *** checks for structures ***
 346
 347 dnl *** checks for compiler characteristics ***
 348
 349 dnl check if the compiler supports __uint128_t (gcc)
 350 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 351     AC_TRY_COMPILE([ ], [
 352       __uint128_t u = 0;
 353
 354       return 0;
 355     ], [
 356       gst_cv_uint128_t=yes
 357     ], [
 358       gst_cv_uint128_t=no
 359     ])
 360 )
 361 if test x$gst_cv_uint128_t = xyes; then
 362   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 363 fi
 364
 365 OPT_CFLAGS=
 366 dnl Check for some compiler flags that optimize our code.
 367 if test "x$GCC" = xyes; then
 368   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 369 fi
 370
 371 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 372 dnl flag
 373 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 374 dnl symbolic register names in inline asm
 375 if test x$HAVE_CPU_PPC = xyes ; then
 376   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 377     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 378 fi
 379
 380 dnl *** checks for library functions ***
 381
 382 AC_CHECK_FUNCS([sigaction])
 383
 384 dnl we use fork in the registry code
 385 AC_CHECK_FUNCS([fork])
 386
 387 dnl check for fseeko()
 388 AC_FUNC_FSEEKO
 389 dnl check for ftello()
 390 AC_CHECK_FUNCS([ftello])
 391
 392 AC_CHECK_FUNCS([fgetpos])
 393 AC_CHECK_FUNCS([fsetpos])
 394
 395 dnl check for poll(), ppoll() and pselect()
 396 AC_CHECK_FUNCS([poll])
 397 AC_CHECK_FUNCS([ppoll])
 398 AC_CHECK_FUNCS([pselect])
 399
 400 dnl check for mmap()
 401 AC_FUNC_MMAP
 402 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 403
 404 dnl Check for POSIX timers
 405 AC_CHECK_FUNCS(clock_gettime, [], [
 406   AC_CHECK_LIB(rt, clock_gettime, [
 407     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 408     LIBS="$LIBS -lrt"
 409   ])
 410 ])
 411
 412 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 413     AC_TRY_COMPILE([
 414 #include <time.h>
 415 #ifdef HAVE_UNISTD_H
 416 #include <unistd.h>
 417 #endif
 418     ], [
 419 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 420 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 421 #endif
 422       return 0;
 423     ], [
 424       gst_cv_posix_timers=yes
 425     ], [
 426       gst_cv_posix_timers=no
 427     ])
 428 )
 429
 430 if test "$gst_cv_posix_timers" = "yes"; then
 431   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 432   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 433 else
 434   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 435 fi
 436 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 437 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 438
 439 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 440     AC_TRY_COMPILE([
 441 #include <time.h>
 442 #ifdef HAVE_UNISTD_H
 443 #include <unistd.h>
 444 #endif
 445     ], [
 446 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 447 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 448 #endif
 449       return 0;
 450     ], [
 451       gst_cv_monotonic_clock=yes
 452     ], [
 453       gst_cv_monotonic_clock=no
 454     ])
 455 )
 456
 457 if test "$gst_cv_monotonic_clock" = "yes"; then
 458   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 459   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 460 else
 461   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 462 fi
 463 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 464 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 465
 466 dnl Check for a way to display the function name in debug output
 467 AG_GST_CHECK_FUNCTION
 468
 469 dnl test for register_printf_specifier or register_printf_function
 470 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 471     [HAVE_PRINTF_EXTENSION=yes])
 472
 473 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 474   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 475   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 476   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 477   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 478       [Defined if we have printf specifier extensions available])
 479 else
 480     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 481     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 482     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 483 fi
 484 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 485 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 486 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 487
 488 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 489 save_cflags="$CFLAGS"
 490 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 491 AC_CHECK_LIB(dl, dladdr,
 492    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 493    LIBS="$LIBS -ldl")
 494 CFLAGS="$save_cflags"
 495
 496 dnl *** checks for socket and nsl libraries ***
 497 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 498 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 499
 500 dnl check for inet_aton()
 501 save_libs="$LIBS"
 502 AC_CHECK_FUNC(inet_aton, ,
 503    AC_CHECK_LIB(nsl, inet_aton, ,
 504       AC_CHECK_LIB(socket, inet_aton, ,
 505          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 506 INET_ATON_LIBS=$LIBS
 507 AC_SUBST(INET_ATON_LIBS)
 508 LIBS="$save_libs"
 509
 510 dnl *** checks for dependency libraries ***
 511
 512 dnl GLib
 513 GLIB_REQ=2.16
 514
 515 AG_GST_GLIB_CHECK([$GLIB_REQ])
 516
 517 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 518 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 519 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 520
 521 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 522 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 523
 524 dnl Check for documentation xrefs
 525 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 526 AC_SUBST(GLIB_PREFIX)
 527
 528 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 529 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 530 then
 531   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 532   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 533 else
 534   dnl check for libxml2 with minimum req version
 535   AG_GST_LIBXML2_CHECK(2.4.9)
 536   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 537 fi
 538 AC_SUBST(GST_DISABLE_XML_DEFINE)
 539
 540 dnl building of unit test libraries
 541 AC_ARG_ENABLE(check,
 542   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 543   [
 544     case "${enableval}" in
 545       yes) BUILD_CHECK=yes ;;
 546       no)  BUILD_CHECK=no ;;
 547       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 548     esac
 549   ], [
 550     dnl Default value
 551     case $host_os in
 552       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 553       *) BUILD_CHECK=yes ;;
 554     esac
 555 ])
 556 dnl bit of a misnomer, but keep the conditional named like this so we don't
 557 dnl have to change too much elsewhere
 558 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 559
 560
 561 dnl *** set variables based on configure arguments
 562
 563 dnl set license and copyright notice
 564 GST_LICENSE="LGPL"
 565 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 566 AC_SUBST(GST_LICENSE)
 567
 568 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 569 AS_AC_EXPAND(LIBDIR, $libdir)
 570 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 571 AS_AC_EXPAND(DATADIR, $datadir)
 572 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 573
 574 dnl set location of plugin directory
 575 AG_GST_SET_PLUGINDIR
 576
 577 dnl FIXME: add LIBXML_PKG here if we use it
 578 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 579 AC_SUBST(GST_PKG_DEPS)
 580
 581 dnl define an ERROR_CFLAGS Makefile variable
 582 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 583
 584 dnl define correct level for debugging messages
 585 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 586
 587 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 588
 589 dnl Overview:
 590 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 591 dnl GST_ALL_*:          vars shared by all built objects
 592 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 593 dnl GST_OBJ_*:          additional vars to link to the core library
 594 dnl                     include GST_ALL_*
 595 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 596 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 597
 598 dnl GST_OPTION_CFLAGS
 599 if test "x$USE_DEBUG" = xyes; then
 600    PROFILE_CFLAGS="-g"
 601 fi
 602 AC_SUBST(PROFILE_CFLAGS)
 603
 604 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 605 # functionality from the API that gstreamer uses
 606 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 607 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 608   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 609   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 610 else
 611   DEPRECATED_CFLAGS=""
 612 fi
 613 AC_SUBST(DEPRECATED_CFLAGS)
 614
 615 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 616 dnl make DEPRECATED_CFLAGS=''
 617 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 618 AC_SUBST(GST_OPTION_CFLAGS)
 619
 620 dnl GST_ALL_*
 621 dnl vars common to for all internal objects (core libs, elements, applications)
 622 dnl CFLAGS:
 623 dnl - XML needs to be added because xmlPtr is used in core
 624 dnl - src and build dirs need to be added because every piece that gets built
 625 dnl   will need the GStreamer source and generated headers
 626 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 627 dnl       from LibXML except for in the core library
 628 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 629
 630 dnl FIXME: check if LTLIBINTL is needed everywhere
 631 dnl I presume it is given that it contains the symbols that _() stuff maps to
 632 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 633
 634 dnl LDFLAGS really should only contain flags, not libs - they get added before
 635 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 636 GST_ALL_LDFLAGS="-no-undefined"
 637
 638 AC_SUBST(GST_ALL_CFLAGS)
 639 AC_SUBST(GST_ALL_LIBS)
 640 AC_SUBST(GST_ALL_LDFLAGS)
 641
 642 dnl GST_LIB_LDFLAGS
 643 dnl linker flags shared by all libraries
 644 dnl LDFLAGS modifier defining exported symbols from built libraries
 645 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 646 AC_SUBST(GST_LIB_LDFLAGS)
 647
 648 dnl GST_OBJ_*
 649 dnl default vars for all internal objects built on libgstreamer
 650 dnl includes GST_ALL_*
 651 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 652 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 653 AC_SUBST(GST_OBJ_CFLAGS)
 654 AC_SUBST(GST_OBJ_LIBS)
 655
 656 dnl GST_PLUGIN_LDFLAGS
 657 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 658 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 659 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 660
 661 SHAVE_INIT([common],[enable])
 662
 663 dnl things for our internal libcheck
 664 if test "x$BUILD_CHECK" = "xyes"; then
 665   AG_GST_CHECK_CHECKS()
 666 fi
 667
 668 AC_CONFIG_FILES(
 669 Makefile
 670 common/shave
 671 common/shave-libtool
 672 gst/Makefile
 673 gst/gstconfig.h
 674 gst/gstversion.h
 675 gst/parse/Makefile
 676 libs/Makefile
 677 libs/gst/Makefile
 678 libs/gst/base/Makefile
 679 libs/gst/check/Makefile
 680 libs/gst/check/libcheck/Makefile
 681 libs/gst/check/libcheck/check.h
 682 libs/gst/controller/Makefile
 683 libs/gst/dataprotocol/Makefile
 684 libs/gst/net/Makefile
 685 plugins/Makefile
 686 plugins/indexers/Makefile
 687 plugins/elements/Makefile
 688 po/Makefile.in
 689 tests/Makefile
 690 tests/benchmarks/Makefile
 691 tests/check/Makefile
 692 tests/misc/Makefile
 693 tests/examples/Makefile
 694 tests/examples/adapter/Makefile
 695 tests/examples/controller/Makefile
 696 tests/examples/stepping/Makefile
 697 tests/examples/helloworld/Makefile
 698 tests/examples/launch/Makefile
 699 tests/examples/manual/Makefile
 700 tests/examples/metadata/Makefile
 701 tests/examples/queue/Makefile
 702 tests/examples/streams/Makefile
 703 tests/examples/typefind/Makefile
 704 tests/examples/xml/Makefile
 705 tools/Makefile
 706 common/Makefile
 707 common/m4/Makefile
 708 docs/Makefile
 709 docs/design/Makefile
 710 docs/faq/Makefile
 711 docs/gst/Makefile
 712 docs/gst/gstreamer.types
 713 docs/libs/Makefile
 714 docs/plugins/Makefile
 715 docs/manual/Makefile
 716 docs/pwg/Makefile
 717 docs/slides/Makefile
 718 docs/xsl/Makefile
 719 docs/version.entities
 720 pkgconfig/Makefile
 721 stamp.h
 722 pkgconfig/gstreamer.pc
 723 pkgconfig/gstreamer-uninstalled.pc
 724 pkgconfig/gstreamer-base.pc
 725 pkgconfig/gstreamer-base-uninstalled.pc
 726 pkgconfig/gstreamer-check.pc
 727 pkgconfig/gstreamer-check-uninstalled.pc
 728 pkgconfig/gstreamer-controller.pc
 729 pkgconfig/gstreamer-controller-uninstalled.pc
 730 pkgconfig/gstreamer-dataprotocol.pc
 731 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 732 pkgconfig/gstreamer-net.pc
 733 pkgconfig/gstreamer-net-uninstalled.pc
 734 gst-element-check.m4
 735 gstreamer.spec
 736 )
 737
 738 dnl Create the config.h file for Visual Studio builds
 739 dnl Beware of spaces and /'s in some of the shell variable contents.
 740 sed \
 741     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 742     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 743     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 744     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 745     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 746     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 747     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 748     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 749     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 750     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 751     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 752     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 753     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 754     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 755     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 756     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 757     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 758     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 759     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 760     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 761     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 762     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 763     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 764     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 765     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 766     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 767     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 768     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 769     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 770     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 771     config.h.in >win32/common/config.h-new
 772
 773 AC_OUTPUT
 774
 775 dnl negate for output
 776 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 777 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 778 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 779 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 780 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 781 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 782 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 783 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 784 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 785
 786 echo "
 787
 788 Configuration
 789         Version                    : ${VERSION}
 790         Source code location       : ${srcdir}
 791         Prefix                     : ${prefix}
 792         Compiler                   : ${SHAVE_SAVED_CC}
 793         Package name               : ${GST_PACKAGE_NAME}
 794         Package origin             : ${GST_PACKAGE_ORIGIN}
 795
 796         Documentation (manuals)    : ${enable_docbook}
 797         Documentation (API)        : ${enable_gtk_doc}
 798
 799         Debug Logging              : ${enable_gst_debug}
 800         Pipeline XML load/save     : ${enable_loadsave}
 801         Command-line parser        : ${enable_parse}
 802         Option parsing in gst_init : ${enable_option_parsing}
 803         Tracing subsystem          : ${enable_trace}
 804         Allocation tracing         : ${enable_alloc_trace}
 805         Plugin registry            : ${enable_registry}
 806         Plugin support             : ${enable_plugin}
 807         Network support            : ${enable_net}
 808         Unit testing support       : ${BUILD_CHECK}
 809
 810         Debug                      : ${USE_DEBUG}
 811         Profiling                  : ${USE_PROFILING}
 812
 813         Building examples          : ${BUILD_EXAMPLES}
 814         Building test apps         : ${BUILD_TESTS}
 815         Building tests that fail   : ${BUILD_FAILING_TESTS}
 816 "