configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.25.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 22, 0, 22)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4 -I .")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.17])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 113 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 dnl building of tests
 129 AC_ARG_ENABLE(tests,
 130   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 131   [
 132     case "${enableval}" in
 133       yes) BUILD_TESTS=yes ;;
 134       no)  BUILD_TESTS=no ;;
 135       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 136     esac
 137   ],
 138 [BUILD_TESTS=yes]) dnl Default value
 139 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 140
 141 dnl tests known to fail
 142 AC_ARG_ENABLE(failing-tests,
 143   AC_HELP_STRING([--disable-failing-tests],
 144     [disable building tests known to fail]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_FAILING_TESTS=yes ;;
 148       no)  BUILD_FAILING_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 150     esac
 151   ],
 152   [BUILD_FAILING_TESTS=no]) dnl Default value
 153 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 154 if test x$BUILD_FAILING_TESTS = xyes; then
 155   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 156 else
 157   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 158 fi
 159
 160 dnl poison destroyed objects
 161 AC_ARG_ENABLE(poisoning,
 162   AC_HELP_STRING([--enable-poisoning],
 163     [enable poisoning of deallocated objects]),
 164   [
 165     case "${enableval}" in
 166       yes) USE_POISONING=yes ;;
 167       no)  USE_POISONING=no ;;
 168       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 169     esac
 170   ],
 171   [USE_POISONING=no]) dnl Default value
 172 if test "x$USE_POISONING" = xyes; then
 173   AC_DEFINE(USE_POISONING, 1,
 174     [Define if we should poison deallocated memory])
 175 fi
 176
 177 dnl *** checks for platform ***
 178
 179 dnl * hardware/architecture *
 180
 181 dnl common/m4/gst-arch.m4
 182 dnl check CPU type
 183 AG_GST_ARCH
 184 dnl substitution for win32/common/config.h
 185 HOST_CPU=$host_cpu
 186 AC_SUBST(HOST_CPU)
 187
 188 dnl common/m4/gst-arch.m4
 189 dnl check for unaligned access
 190 AG_GST_UNALIGNED_ACCESS
 191 dnl create a configure variable for gst/gstconfig.h
 192 if test x${as_cv_unaligned_access} = xyes ; then
 193   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 194 else
 195   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 196 fi
 197 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 198
 199 dnl check for platform specific settings
 200 case $host_os in
 201      rhapsody*)
 202         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 203         ;;
 204      darwin*)
 205         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 206         AC_DEFINE_UNQUOTED(HAVE_OSX, 1, [Defined if compiling for OSX])
 207         ;;
 208      cygwin*)
 209         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 210         ;;
 211      mingw* | msvc* | mks*)
 212         dnl HAVE_WIN32 currently means "disable POSIXisms".
 213         AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 214
 215         dnl define __MSVCRT_VERSION__ version if not set already by the
 216         dnl compiler (ie. mostly for mingw). This is needed for things like
 217         dnl __stat64 to be available. If set by the compiler, ensure it's
 218         dnl new enough - we need at least WinXP SP2.
 219         AC_TRY_COMPILE([ ], [ return __MSVCRT_VERSION__; ], [
 220             AC_TRY_COMPILE([ ], [
 221               #if __MSVCRT_VERSION__ < 0x0601
 222               #error "MSVCRT too old"
 223               #endif
 224             ], [
 225               AC_MSG_NOTICE([MSVCRT version looks ok])
 226             ], [
 227               AC_MSG_ERROR([MSVCRT version too old, need at least WinXP SP2])
 228             ])
 229         ], [
 230           AC_MSG_NOTICE([Setting MSVCRT version to 0x0601])
 231           AC_DEFINE_UNQUOTED(__MSVCRT_VERSION__, 0x0601, [We need at least WinXP SP2 for __stat64])
 232         ])
 233         ;;
 234      *)
 235         ;;
 236 esac
 237
 238 dnl * software *
 239
 240 dnl check for large file support
 241 dnl affected plugins must include config.h
 242 AC_SYS_LARGEFILE
 243
 244 dnl *** checks for programs ***
 245
 246 dnl find a compiler
 247 AC_PROG_CC
 248
 249 dnl check if the compiler supports '-c' and '-o' options
 250 AM_PROG_CC_C_O
 251
 252 dnl find an assembler
 253 AM_PROG_AS
 254
 255 dnl Perl is used in building documentation and in the version checks
 256 AC_PATH_PROG(PERL_PATH, perl, no)
 257 if test x$PERL_PATH = xno; then
 258   AC_MSG_ERROR(Could not find perl)
 259 fi
 260
 261 dnl we require flex and bison for building the parser
 262 if test "x$GST_DISABLE_PARSE" != xyes; then
 263   AG_GST_BISON_CHECK
 264   AG_GST_FLEX_CHECK
 265 fi
 266
 267 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 268 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 269
 270 dnl check for gobject-introspection
 271 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 272
 273 dnl check for documentation tools
 274 AG_GST_DOCBOOK_CHECK
 275 GTK_DOC_CHECK([1.3])
 276 AS_PATH_PYTHON([2.1])
 277 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 278
 279 dnl *** checks for libraries ***
 280
 281 dnl check for libm, for sin()
 282 AC_CHECK_LIBM
 283 AC_SUBST(LIBM)
 284
 285 dnl *** checks for header files ***
 286
 287 dnl check if we have ANSI C header files
 288 AC_HEADER_STDC
 289
 290 dnl Check for ucontext.h
 291 AC_CHECK_HEADERS([ucontext.h])
 292
 293 dnl Check for sys/socket.h
 294 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 295 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 296
 297 dnl check for sys/times.h for tests/examples/adapter/
 298 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 299 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 300 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 301
 302 dnl Check for process.h for getpid() on win32
 303 AC_CHECK_HEADERS([process.h])
 304
 305 dnl Check for sys/utsname.h for uname
 306 AC_CHECK_HEADERS([sys/utsname.h])
 307
 308 dnl Check for stdio_ext.f for __fbufsize
 309 AC_CHECK_HEADERS([stdio_ext.h])
 310
 311 dnl check for pthreads
 312 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 313 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 314
 315 dnl Check for valgrind.h
 316 dnl separate from HAVE_VALGRIND because you can have the program, but not
 317 dnl the dev package
 318 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 319
 320 dnl used in gst/gstpoll.c
 321 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 322 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 323 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 324   WIN32_LIBS="-lws2_32"
 325   AC_SUBST(WIN32_LIBS)
 326 fi
 327
 328 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 329 AG_GST_CHECK_LIBHEADER(GMP, gmp,
 330                         __gmpz_init_set_d, ,
 331                         gmp.h,
 332                         GMP_LIBS="-lgmp"
 333                         AC_SUBST(GMP_LIBS)
 334                         AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 335 AG_GST_CHECK_LIBHEADER(GSL, gsl,
 336                         gsl_rng_uniform_int, -lgslcblas,
 337                         gsl/gsl_rng.h,
 338                         GSL_LIBS="-lgsl -lgslcblas"
 339                         AC_SUBST(GSL_LIBS)
 340                         AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 341
 342 dnl *** checks for types/defines ***
 343
 344 dnl *** checks for structures ***
 345
 346 dnl *** checks for compiler characteristics ***
 347
 348 dnl check if the compiler supports __uint128_t (gcc)
 349 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 350     AC_TRY_COMPILE([ ], [
 351       unsigned long long v1 = 1024ULL;
 352       unsigned long long v2 = 0x8000000000000000ULL;
 353       __uint128_t u = ((__uint128_t)v1)*((__uint128_t)v2);
 354
 355       return 0;
 356     ], [
 357       gst_cv_uint128_t=yes
 358     ], [
 359       gst_cv_uint128_t=no
 360     ])
 361 )
 362 if test x$gst_cv_uint128_t = xyes; then
 363   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 364 fi
 365
 366 OPT_CFLAGS=
 367 dnl Check for some compiler flags that optimize our code.
 368 if test "x$GCC" = xyes; then
 369   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 370 fi
 371
 372 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 373 dnl flag
 374 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 375 dnl symbolic register names in inline asm
 376 if test x$HAVE_CPU_PPC = xyes ; then
 377   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 378     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 379 fi
 380
 381 dnl *** checks for library functions ***
 382
 383 AC_CHECK_FUNCS([sigaction])
 384
 385 dnl check for fseeko()
 386 AC_FUNC_FSEEKO
 387 dnl check for ftello()
 388 AC_CHECK_FUNCS([ftello])
 389
 390 AC_CHECK_FUNCS([fgetpos])
 391 AC_CHECK_FUNCS([fsetpos])
 392
 393 dnl check for poll(), ppoll() and pselect()
 394 AC_CHECK_FUNCS([poll])
 395 AC_CHECK_FUNCS([ppoll])
 396 AC_CHECK_FUNCS([pselect])
 397
 398 dnl ****************************************
 399 dnl *** GLib POLL* compatibility defines ***
 400 dnl ****************************************
 401
 402 AC_MSG_CHECKING([for broken poll])
 403 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 404         #include <stdlib.h>
 405         #include <fcntl.h>
 406         #include <poll.h>
 407         #ifdef HAVE_SYS_POLL_H
 408         #include <sys/poll.h>
 409         #endif
 410         int main(void) {
 411           struct pollfd fds[1];
 412           int fd;
 413           fd = open("/dev/null", 1);
 414           fds[0].fd = fd;
 415           fds[0].events = POLLIN;
 416           fds[0].revents = 0;
 417           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 418                 exit(1);  /* Does not work for devices -- fail */
 419           }
 420           exit(0);
 421         }]])],
 422   [broken_poll=no],
 423   [broken_poll=yes
 424    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 425   [broken_poll="no (cross compiling)"])
 426 AC_MSG_RESULT($broken_poll)
 427
 428 dnl check for mmap()
 429 AC_FUNC_MMAP
 430 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 431
 432 dnl Check for POSIX timers
 433 AC_CHECK_FUNCS(clock_gettime, [], [
 434   AC_CHECK_LIB(rt, clock_gettime, [
 435     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 436     LIBS="$LIBS -lrt"
 437   ])
 438 ])
 439
 440 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 441     AC_TRY_COMPILE([
 442 #include <time.h>
 443 #ifdef HAVE_UNISTD_H
 444 #include <unistd.h>
 445 #endif
 446     ], [
 447 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 448 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 449 #endif
 450       return 0;
 451     ], [
 452       gst_cv_posix_timers=yes
 453     ], [
 454       gst_cv_posix_timers=no
 455     ])
 456 )
 457
 458 if test "$gst_cv_posix_timers" = "yes"; then
 459   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 460   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 461 else
 462   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 463 fi
 464 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 465 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 466
 467 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 468     AC_TRY_COMPILE([
 469 #include <time.h>
 470 #ifdef HAVE_UNISTD_H
 471 #include <unistd.h>
 472 #endif
 473     ], [
 474 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 475 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 476 #endif
 477       return 0;
 478     ], [
 479       gst_cv_monotonic_clock=yes
 480     ], [
 481       gst_cv_monotonic_clock=no
 482     ])
 483 )
 484
 485 if test "$gst_cv_monotonic_clock" = "yes"; then
 486   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 487   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 488 else
 489   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 490 fi
 491 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 492 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 493
 494 dnl Check for a way to display the function name in debug output
 495 AG_GST_CHECK_FUNCTION
 496
 497 dnl test for register_printf_specifier or register_printf_function
 498 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 499     [HAVE_PRINTF_EXTENSION=yes])
 500
 501 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 502   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 503   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 504   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 505   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 506       [Defined if we have printf specifier extensions available])
 507 else
 508     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 509     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 510     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 511 fi
 512 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 513 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 514 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 515
 516 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 517 save_cflags="$CFLAGS"
 518 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 519 AC_CHECK_LIB(dl, dladdr,
 520    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 521    LIBS="$LIBS -ldl")
 522 CFLAGS="$save_cflags"
 523
 524 dnl *** checks for socket and nsl libraries ***
 525 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 526 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 527
 528 dnl check for inet_aton()
 529 save_libs="$LIBS"
 530 AC_CHECK_FUNC(inet_aton, ,
 531    AC_CHECK_LIB(nsl, inet_aton, ,
 532       AC_CHECK_LIB(socket, inet_aton, ,
 533          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 534 INET_ATON_LIBS=$LIBS
 535 AC_SUBST(INET_ATON_LIBS)
 536 LIBS="$save_libs"
 537
 538 dnl *** checks for dependency libraries ***
 539
 540 dnl GLib
 541 GLIB_REQ=2.18
 542
 543 AG_GST_GLIB_CHECK([$GLIB_REQ])
 544
 545 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 546 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 547 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 548
 549 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 550 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 551
 552 dnl Check for documentation xrefs
 553 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 554 AC_SUBST(GLIB_PREFIX)
 555
 556 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 557 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 558 then
 559   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 560   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 561 else
 562   dnl check for libxml2 with minimum req version
 563   AG_GST_LIBXML2_CHECK(2.4.9)
 564   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 565 fi
 566 AC_SUBST(GST_DISABLE_XML_DEFINE)
 567
 568 dnl building of unit test libraries
 569 AC_ARG_ENABLE(check,
 570   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 571   [
 572     case "${enableval}" in
 573       yes) BUILD_CHECK=yes ;;
 574       no)  BUILD_CHECK=no ;;
 575       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 576     esac
 577   ], [
 578     dnl Default value
 579     case $host_os in
 580       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 581       *) BUILD_CHECK=yes ;;
 582     esac
 583 ])
 584 dnl bit of a misnomer, but keep the conditional named like this so we don't
 585 dnl have to change too much elsewhere
 586 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 587
 588
 589 dnl *** set variables based on configure arguments
 590
 591 dnl set license and copyright notice
 592 GST_LICENSE="LGPL"
 593 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 594 AC_SUBST(GST_LICENSE)
 595
 596 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 597 AS_AC_EXPAND(LIBDIR, $libdir)
 598 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 599 AS_AC_EXPAND(DATADIR, $datadir)
 600 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 601
 602 dnl set location of plugin directory
 603 AG_GST_SET_PLUGINDIR
 604
 605 dnl FIXME: add LIBXML_PKG here if we use it
 606 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 607 AC_SUBST(GST_PKG_DEPS)
 608
 609 dnl define an ERROR_CFLAGS Makefile variable
 610 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 611
 612 dnl define correct level for debugging messages
 613 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 614
 615 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 616
 617 dnl Overview:
 618 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 619 dnl GST_ALL_*:          vars shared by all built objects
 620 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 621 dnl GST_OBJ_*:          additional vars to link to the core library
 622 dnl                     include GST_ALL_*
 623 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 624 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 625
 626 dnl GST_OPTION_CFLAGS
 627 if test "x$USE_DEBUG" = xyes; then
 628    PROFILE_CFLAGS="-g"
 629 fi
 630 AC_SUBST(PROFILE_CFLAGS)
 631
 632 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 633 # functionality from the API that gstreamer uses
 634 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 635 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 636   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 637   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 638 else
 639   DEPRECATED_CFLAGS=""
 640 fi
 641 AC_SUBST(DEPRECATED_CFLAGS)
 642
 643 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 644 dnl make DEPRECATED_CFLAGS=''
 645 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 646 AC_SUBST(GST_OPTION_CFLAGS)
 647
 648 dnl GST_ALL_*
 649 dnl vars common to for all internal objects (core libs, elements, applications)
 650 dnl CFLAGS:
 651 dnl - XML needs to be added because xmlPtr is used in core
 652 dnl - src and build dirs need to be added because every piece that gets built
 653 dnl   will need the GStreamer source and generated headers
 654 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 655 dnl       from LibXML except for in the core library
 656 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 657
 658 dnl FIXME: check if LTLIBINTL is needed everywhere
 659 dnl I presume it is given that it contains the symbols that _() stuff maps to
 660 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 661
 662 dnl LDFLAGS really should only contain flags, not libs - they get added before
 663 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 664 GST_ALL_LDFLAGS="-no-undefined"
 665
 666 AC_SUBST(GST_ALL_CFLAGS)
 667 AC_SUBST(GST_ALL_LIBS)
 668 AC_SUBST(GST_ALL_LDFLAGS)
 669
 670 dnl GST_LIB_LDFLAGS
 671 dnl linker flags shared by all libraries
 672 dnl LDFLAGS modifier defining exported symbols from built libraries
 673 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 674 AC_SUBST(GST_LIB_LDFLAGS)
 675
 676 dnl GST_OBJ_*
 677 dnl default vars for all internal objects built on libgstreamer
 678 dnl includes GST_ALL_*
 679 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 680 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 681 AC_SUBST(GST_OBJ_CFLAGS)
 682 AC_SUBST(GST_OBJ_LIBS)
 683
 684 dnl GST_PLUGIN_LDFLAGS
 685 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 686 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 687 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 688
 689 dnl plugin scanner locations
 690 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/plugin-scanner)
 691 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 692     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed plugin-scanner])
 693
 694 SHAVE_INIT([common],[enable])
 695
 696 dnl things for our internal libcheck
 697 if test "x$BUILD_CHECK" = "xyes"; then
 698   AG_GST_CHECK_CHECKS()
 699 fi
 700
 701 AC_CONFIG_FILES(
 702 Makefile
 703 common/shave
 704 common/shave-libtool
 705 gst/Makefile
 706 gst/gstconfig.h
 707 gst/gstversion.h
 708 gst/parse/Makefile
 709 libs/Makefile
 710 libs/gst/Makefile
 711 libs/gst/base/Makefile
 712 libs/gst/check/Makefile
 713 libs/gst/check/libcheck/Makefile
 714 libs/gst/check/libcheck/check.h
 715 libs/gst/controller/Makefile
 716 libs/gst/dataprotocol/Makefile
 717 libs/gst/helpers/Makefile
 718 libs/gst/net/Makefile
 719 plugins/Makefile
 720 plugins/indexers/Makefile
 721 plugins/elements/Makefile
 722 po/Makefile.in
 723 tests/Makefile
 724 tests/benchmarks/Makefile
 725 tests/check/Makefile
 726 tests/misc/Makefile
 727 tests/examples/Makefile
 728 tests/examples/adapter/Makefile
 729 tests/examples/controller/Makefile
 730 tests/examples/stepping/Makefile
 731 tests/examples/helloworld/Makefile
 732 tests/examples/launch/Makefile
 733 tests/examples/manual/Makefile
 734 tests/examples/metadata/Makefile
 735 tests/examples/queue/Makefile
 736 tests/examples/streams/Makefile
 737 tests/examples/typefind/Makefile
 738 tests/examples/xml/Makefile
 739 tools/Makefile
 740 common/Makefile
 741 common/m4/Makefile
 742 docs/Makefile
 743 docs/design/Makefile
 744 docs/faq/Makefile
 745 docs/gst/Makefile
 746 docs/gst/gstreamer.types
 747 docs/libs/Makefile
 748 docs/plugins/Makefile
 749 docs/manual/Makefile
 750 docs/pwg/Makefile
 751 docs/slides/Makefile
 752 docs/xsl/Makefile
 753 docs/version.entities
 754 pkgconfig/Makefile
 755 stamp.h
 756 pkgconfig/gstreamer.pc
 757 pkgconfig/gstreamer-uninstalled.pc
 758 pkgconfig/gstreamer-base.pc
 759 pkgconfig/gstreamer-base-uninstalled.pc
 760 pkgconfig/gstreamer-check.pc
 761 pkgconfig/gstreamer-check-uninstalled.pc
 762 pkgconfig/gstreamer-controller.pc
 763 pkgconfig/gstreamer-controller-uninstalled.pc
 764 pkgconfig/gstreamer-dataprotocol.pc
 765 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 766 pkgconfig/gstreamer-net.pc
 767 pkgconfig/gstreamer-net-uninstalled.pc
 768 gst-element-check.m4
 769 gstreamer.spec
 770 )
 771
 772 dnl Create the config.h file for Visual Studio builds
 773 dnl Beware of spaces and /'s in some of the shell variable contents.
 774 sed \
 775     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 776     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 777     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 778     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 779     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 780     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 781     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 782     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 783     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 784     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 785     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 786     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 787     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 788     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 789     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 790     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 791     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 792     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 793     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 794     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 795     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 796     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 797     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 798     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 799     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 800     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 801     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 802     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 803     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 804     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 805     config.h.in >win32/common/config.h-new
 806
 807 AC_OUTPUT
 808
 809 dnl negate for output
 810 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 811 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 812 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 813 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 814 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 815 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 816 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 817 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 818 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 819
 820 echo "
 821
 822 Configuration
 823         Version                    : ${VERSION}
 824         Source code location       : ${srcdir}
 825         Prefix                     : ${prefix}
 826         Compiler                   : ${SHAVE_SAVED_CC}
 827         Package name               : ${GST_PACKAGE_NAME}
 828         Package origin             : ${GST_PACKAGE_ORIGIN}
 829
 830         Documentation (manuals)    : ${enable_docbook}
 831         Documentation (API)        : ${enable_gtk_doc}
 832
 833         Debug Logging              : ${enable_gst_debug}
 834         Pipeline XML load/save     : ${enable_loadsave}
 835         Command-line parser        : ${enable_parse}
 836         Option parsing in gst_init : ${enable_option_parsing}
 837         Tracing subsystem          : ${enable_trace}
 838         Allocation tracing         : ${enable_alloc_trace}
 839         Plugin registry            : ${enable_registry}
 840         Plugin support             : ${enable_plugin}
 841         Network support            : ${enable_net}
 842         Unit testing support       : ${BUILD_CHECK}
 843
 844         Debug                      : ${USE_DEBUG}
 845         Profiling                  : ${USE_PROFILING}
 846
 847         Building examples          : ${BUILD_EXAMPLES}
 848         Building test apps         : ${BUILD_TESTS}
 849         Building tests that fail   : ${BUILD_FAILING_TESTS}
 850 "