intel: Silence a trivial compiler warning
[glsdk/libdrm.git] / configure.ac
1 #  Copyright 2005 Adam Jackson.
2 #
3 #  Permission is hereby granted, free of charge, to any person obtaining a
4 #  copy of this software and associated documentation files (the "Software"),
5 #  to deal in the Software without restriction, including without limitation
6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
7 #  license, and/or sell copies of the Software, and to permit persons to whom
8 #  the Software is furnished to do so, subject to the following conditions:
9 #
10 #  The above copyright notice and this permission notice (including the next
11 #  paragraph) shall be included in all copies or substantial portions of the
12 #  Software.
13 #
14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ([2.63])
22 AC_INIT([libdrm],
23         [2.4.39],
24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
25         [libdrm])
27 AC_CONFIG_HEADERS([config.h])
28 AC_CONFIG_SRCDIR([Makefile.am])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_AUX_DIR([build-aux])
32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
33 AM_MAINTAINER_MODE([enable])
35 # Enable quiet compiles on automake 1.11.
36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
38 if test x$LIB_MAN_SUFFIX = x    ; then
39     LIB_MAN_SUFFIX=3
40 fi
41 if test x$LIB_MAN_DIR = x    ; then
42     LIB_MAN_DIR='$(mandir)/man$(LIB_MAN_SUFFIX)'
43 fi
44 AC_SUBST([LIB_MAN_SUFFIX])
45 AC_SUBST([LIB_MAN_DIR])
47 MAN_SUBSTS="\
48         -e 's|__vendorversion__|\"\$(PACKAGE_STRING)\" |' \
49         -e 's|__projectroot__|\$(prefix)|g' \
50         -e 's|__apploaddir__|\$(appdefaultdir)|g' \
51         -e 's|__appmansuffix__|\$(APP_MAN_SUFFIX)|g' \
52         -e 's|__drivermansuffix__|\$(DRIVER_MAN_SUFFIX)|g' \
53         -e 's|__adminmansuffix__|\$(ADMIN_MAN_SUFFIX)|g' \
54         -e 's|__libmansuffix__|\$(LIB_MAN_SUFFIX)|g' \
55         -e 's|__miscmansuffix__|\$(MISC_MAN_SUFFIX)|g' \
56         -e 's|__filemansuffix__|\$(FILE_MAN_SUFFIX)|g'"
57 AC_SUBST([MAN_SUBSTS])
59 # Check for programs
60 AC_PROG_CC
62 AC_USE_SYSTEM_EXTENSIONS
63 AC_SYS_LARGEFILE
64 AC_FUNC_ALLOCA
66 # Initialize libtool
67 LT_PREREQ([2.2])
68 LT_INIT([disable-static])
71 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
72 AC_SUBST(PTHREADSTUBS_CFLAGS)
73 AC_SUBST(PTHREADSTUBS_LIBS)
75 pkgconfigdir=${libdir}/pkgconfig
76 AC_SUBST(pkgconfigdir)
77 AC_ARG_ENABLE([udev],
78               [AS_HELP_STRING([--enable-udev],
79                               [Enable support for using udev instead of mknod (default: disabled)])],
80               [UDEV=$enableval], [UDEV=no])
82 AC_ARG_ENABLE(libkms,
83               AS_HELP_STRING([--disable-libkms],
84               [Disable KMS mm abstraction library (default: auto)]),
85               [LIBKMS=$enableval], [LIBKMS=auto])
87 AC_ARG_ENABLE(intel,
88               AS_HELP_STRING([--disable-intel],
89               [Enable support for intel's KMS API (default: auto)]),
90               [INTEL=$enableval], [INTEL=auto])
92 AC_ARG_ENABLE(radeon,
93               AS_HELP_STRING([--disable-radeon],
94               [Enable support for radeon's KMS API (default: auto)]),
95               [RADEON=$enableval], [RADEON=auto])
97 AC_ARG_ENABLE(nouveau,
98               AS_HELP_STRING([--disable-nouveau],
99               [Enable support for nouveau's KMS API (default: auto)]),
100               [NOUVEAU=$enableval], [NOUVEAU=auto])
102 AC_ARG_ENABLE(vmwgfx,
103               AS_HELP_STRING([--disable-vmwgfx],
104               [Enable support for vmwgfx's KMS API (default: yes)]),
105               [VMWGFX=$enableval], [VMWGFX=yes])
107 AC_ARG_ENABLE(omap-experimental-api,
108               AS_HELP_STRING([--enable-omap-experimental-api],
109               [Enable support for OMAP's experimental API (default: disabled)]),
110               [OMAP=$enableval], [OMAP=no])
112 AC_ARG_ENABLE(exynos-experimental-api,
113               AS_HELP_STRING([--enable-exynos-experimental-api],
114               [Enable support for EXYNOS's experimental API (default: disabled)]),
115               [EXYNOS=$enableval], [EXYNOS=no])
117 dnl ===========================================================================
118 dnl check compiler flags
119 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
120   AC_MSG_CHECKING([whether $CC supports $1])
122   libdrm_save_CFLAGS="$CFLAGS"
123   CFLAGS="$CFLAGS $1"
125   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
126   CFLAGS="$libdrm_save_CFLAGS"
128   if test "x$libdrm_cc_flag" = "xyes"; then
129     ifelse([$2], , :, [$2])
130   else
131     ifelse([$3], , :, [$3])
132   fi
133   AC_MSG_RESULT([$libdrm_cc_flag])
134 ])
136 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
138 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
139                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
140                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
141 AC_SUBST([CLOCK_LIB])
143 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
145 dnl Use lots of warning flags with with gcc and compatible compilers
147 dnl Note: if you change the following variable, the cache is automatically
148 dnl skipped and all flags rechecked.  So there's no need to do anything
149 dnl else.  If for any reason you need to force a recheck, just change
150 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
152 MAYBE_WARN="-Wall -Wextra \
153 -Wsign-compare -Werror-implicit-function-declaration \
154 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
155 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
156 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
157 -Wstrict-aliasing=2 -Winit-self \
158 -Wdeclaration-after-statement -Wold-style-definition \
159 -Wno-missing-field-initializers -Wno-unused-parameter \
160 -Wno-attributes -Wno-long-long -Winline"
162 # invalidate cached value if MAYBE_WARN has changed
163 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
164         unset libdrm_cv_warn_cflags
165 fi
166 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
167         echo
168         WARN_CFLAGS=""
170         # Some warning options are not supported by all versions of
171         # gcc, so test all desired options against the current
172         # compiler.
173         #
174         # Note that there are some order dependencies
175         # here. Specifically, an option that disables a warning will
176         # have no net effect if a later option then enables that
177         # warnings, (perhaps implicitly). So we put some grouped
178         # options (-Wall and -Wextra) up front and the -Wno options
179         # last.
181         for W in $MAYBE_WARN; do
182                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
183         done
185         libdrm_cv_warn_cflags=$WARN_CFLAGS
186         libdrm_cv_warn_maybe=$MAYBE_WARN
188         AC_MSG_CHECKING([which warning flags were supported])])
189 WARN_CFLAGS="$libdrm_cv_warn_cflags"
191 if test "x$UDEV" = xyes; then
192         AC_DEFINE(UDEV, 1, [Have UDEV support])
193 fi
195 AC_CANONICAL_HOST
196 if test "x$LIBKMS" = xauto ; then
197         case $host_os in
198                 linux*)         LIBKMS="yes" ;;
199                 *)              LIBKMS="no" ;;
200         esac
201 fi
203 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
205 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
206 if test "x$VMWGFX" = xyes; then
207         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
208 fi
210 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
211 if test "x$NOUVEAU" = xyes; then
212         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
213 fi
215 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
216 if test "x$OMAP" = xyes; then
217         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
218 fi
220 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
221 if test "x$EXYNOS" = xyes; then
222         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
223 fi
225 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
226 if test "x$HAVE_CAIRO" = xyes; then
227         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
228 fi
229 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
231 # For enumerating devices in test case
232 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
233 if test "x$HAVE_LIBUDEV" = xyes; then
234         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
235 fi
236 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
238 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno" -o "x$NOUVEAU" != "xno" -o "x$OMAP" != "xno"; then
239     # Check for atomic intrinsics
240     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
241     [
242             drm_cv_atomic_primitives="none"
244             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
245     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
246     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
247                                             ]],[[]])],
248                            [drm_cv_atomic_primitives="Intel"],[])
250             if test "x$drm_cv_atomic_primitives" = "xnone"; then
251                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
252             fi
254             # atomic functions defined in <atomic.h> & libc on Solaris
255             if test "x$drm_cv_atomic_primitives" = "xnone"; then
256                     AC_CHECK_FUNC([atomic_cas_uint],
257                                   drm_cv_atomic_primitives="Solaris")
258             fi
260     ])
261     if test "x$drm_cv_atomic_primitives" = xIntel; then
262             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
263                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
264     fi
265     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
266             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
267     fi
269     if test "x$drm_cv_atomic_primitives" = "xnone"; then
270            if test "x$INTEL" != "xauto"; then
271                    if test "x$INTEL" != "xno"; then
272                         AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
273                    fi
274            else
275                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
276                    INTEL=no
277            fi
278            if test "x$RADEON" != "xauto"; then
279                    if test "x$RADEON" != "xno"; then
280                         AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
281                    fi
282            else
283                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
284                    RADEON=no
285            fi
286            if test "x$NOUVEAU" != "xauto"; then
287                    if test "x$NOUVEAU" != "xno"; then
288                         AC_MSG_ERROR([libdrm_nouveau depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA GPUs by passing --disable-nouveau to ./configure])
289                    fi
290            else
291                    AC_MSG_WARN([Disabling libdrm_nouveau. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
292                    NOUVEAU=no
293            fi
294     else
295            if test "x$INTEL" != "xno"; then
296                    case $host_cpu in
297                            i?86|x86_64) INTEL=yes ;;
298                            *) INTEL=no ;;
299                    esac
300            fi
301            if test "x$RADEON" != "xno"; then
302                    RADEON=yes
303            fi
304            if test "x$NOUVEAU" != "xno"; then
305                    NOUVEAU=yes
306            fi
307     fi
308 fi
310 if test "x$INTEL" != "xno"; then
311         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
312 fi
313 AC_SUBST(PCIACCESS_CFLAGS)
314 AC_SUBST(PCIACCESS_LIBS)
316 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
317 if test "x$have_valgrind" = "xyes"; then
318         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
319 fi
321 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
322 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
323 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" != "xno"])
324 if test "x$RADEON" = xyes; then
325         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
326 fi
328 AC_ARG_WITH([kernel-source],
329             [AS_HELP_STRING([--with-kernel-source],
330               [specify path to linux kernel source])],
331             [kernel_source="$with_kernel_source"])
332 AC_SUBST(kernel_source)
334 AC_SUBST(WARN_CFLAGS)
335 AC_CONFIG_FILES([
336         Makefile
337         libkms/Makefile
338         libkms/libkms.pc
339         intel/Makefile
340         intel/libdrm_intel.pc
341         radeon/Makefile
342         radeon/libdrm_radeon.pc
343         nouveau/Makefile
344         nouveau/libdrm_nouveau.pc
345         omap/Makefile
346         omap/libdrm_omap.pc
347         exynos/Makefile
348         exynos/libdrm_exynos.pc
349         tests/Makefile
350         tests/modeprint/Makefile
351         tests/modetest/Makefile
352         tests/kmstest/Makefile
353         tests/radeon/Makefile
354         tests/vbltest/Makefile
355         include/Makefile
356         include/drm/Makefile
357         man/Makefile
358         libdrm.pc])
359 AC_OUTPUT
361 echo ""
362 echo "$PACKAGE_STRING will be compiled with:"
363 echo ""
364 echo "  libkms         $LIBKMS"
365 echo "  Intel API      $INTEL"
366 echo "  vmwgfx API     $VMWGFX"
367 echo "  Radeon API     $RADEON"
368 echo "  Nouveau API    $NOUVEAU"
369 echo "  OMAP API       $OMAP"
370 echo "  EXYNOS API     $EXYNOS"
371 echo ""