1 # Copyright 2005 Adam Jackson.
2 #
3 # Permission is hereby granted, free of charge, to any person obtaining a
4 # copy of this software and associated documentation files (the "Software"),
5 # to deal in the Software without restriction, including without limitation
6 # on the rights to use, copy, modify, merge, publish, distribute, sub
7 # license, and/or sell copies of the Software, and to permit persons to whom
8 # the Software is furnished to do so, subject to the following conditions:
9 #
10 # The above copyright notice and this permission notice (including the next
11 # paragraph) shall be included in all copies or substantial portions of the
12 # Software.
13 #
14 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 # FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT. IN NO EVENT SHALL
17 # ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 # IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 # CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ([2.63])
22 AC_INIT([libdrm],
23 [2.4.33],
24 [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
25 [libdrm])
27 AC_CONFIG_HEADERS([config.h])
28 AC_CONFIG_SRCDIR([Makefile.am])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_AUX_DIR([build-aux])
32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
33 AM_MAINTAINER_MODE([enable])
35 # Enable quiet compiles on automake 1.11.
36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
38 # Check for programs
39 AC_PROG_CC
41 AC_USE_SYSTEM_EXTENSIONS
42 AC_SYS_LARGEFILE
43 AC_FUNC_ALLOCA
45 # Initialize libtool
46 LT_PREREQ([2.2])
47 LT_INIT([disable-static])
50 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
51 AC_SUBST(PTHREADSTUBS_CFLAGS)
52 AC_SUBST(PTHREADSTUBS_LIBS)
54 pkgconfigdir=${libdir}/pkgconfig
55 AC_SUBST(pkgconfigdir)
56 AC_ARG_ENABLE([udev],
57 [AS_HELP_STRING([--enable-udev],
58 [Enable support for using udev instead of mknod (default: disabled)])],
59 [UDEV=$enableval], [UDEV=no])
61 AC_ARG_ENABLE(libkms,
62 AS_HELP_STRING([--disable-libkms],
63 [Disable KMS mm abstraction library (default: auto)]),
64 [LIBKMS=$enableval], [LIBKMS=auto])
66 AC_ARG_ENABLE(intel,
67 AS_HELP_STRING([--disable-intel],
68 [Enable support for intel's KMS API (default: auto)]),
69 [INTEL=$enableval], [INTEL=auto])
71 AC_ARG_ENABLE(radeon,
72 AS_HELP_STRING([--disable-radeon],
73 [Enable support for radeon's KMS API (default: auto)]),
74 [RADEON=$enableval], [RADEON=auto])
76 AC_ARG_ENABLE(nouveau,
77 AS_HELP_STRING([--disable-nouveau],
78 [Enable support for nouveau's KMS API (default: auto)]),
79 [NOUVEAU=$enableval], [NOUVEAU=auto])
81 AC_ARG_ENABLE(vmwgfx-experimental-api,
82 AS_HELP_STRING([--enable-vmwgfx-experimental-api],
83 [Install vmwgfx's experimental kernel API header (default: disabled)]),
84 [VMWGFX=$enableval], [VMWGFX=no])
86 AC_ARG_ENABLE(omap-experimental-api,
87 AS_HELP_STRING([--enable-omap-experimental-api],
88 [Enable support for OMAP's experimental API (default: disabled)]),
89 [OMAP=$enableval], [OMAP=no])
91 dnl ===========================================================================
92 dnl check compiler flags
93 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
94 AC_MSG_CHECKING([whether $CC supports $1])
96 libdrm_save_CFLAGS="$CFLAGS"
97 CFLAGS="$CFLAGS $1"
99 AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
100 CFLAGS="$libdrm_save_CFLAGS"
102 if test "x$libdrm_cc_flag" = "xyes"; then
103 ifelse([$2], , :, [$2])
104 else
105 ifelse([$3], , :, [$3])
106 fi
107 AC_MSG_RESULT([$libdrm_cc_flag])
108 ])
110 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
112 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
113 [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
114 [AC_MSG_ERROR([Couldn't find clock_gettime])])])
115 AC_SUBST([CLOCK_LIB])
117 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
119 dnl Use lots of warning flags with with gcc and compatible compilers
121 dnl Note: if you change the following variable, the cache is automatically
122 dnl skipped and all flags rechecked. So there's no need to do anything
123 dnl else. If for any reason you need to force a recheck, just change
124 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
126 MAYBE_WARN="-Wall -Wextra \
127 -Wsign-compare -Werror-implicit-function-declaration \
128 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
129 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
130 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
131 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
132 -Wdeclaration-after-statement -Wold-style-definition \
133 -Wno-missing-field-initializers -Wno-unused-parameter \
134 -Wno-attributes -Wno-long-long -Winline"
136 # invalidate cached value if MAYBE_WARN has changed
137 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
138 unset libdrm_cv_warn_cflags
139 fi
140 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
141 echo
142 WARN_CFLAGS=""
144 # Some warning options are not supported by all versions of
145 # gcc, so test all desired options against the current
146 # compiler.
147 #
148 # Note that there are some order dependencies
149 # here. Specifically, an option that disables a warning will
150 # have no net effect if a later option then enables that
151 # warnings, (perhaps implicitly). So we put some grouped
152 # options (-Wall and -Wextra) up front and the -Wno options
153 # last.
155 for W in $MAYBE_WARN; do
156 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
157 done
159 libdrm_cv_warn_cflags=$WARN_CFLAGS
160 libdrm_cv_warn_maybe=$MAYBE_WARN
162 AC_MSG_CHECKING([which warning flags were supported])])
163 WARN_CFLAGS="$libdrm_cv_warn_cflags"
165 if test "x$UDEV" = xyes; then
166 AC_DEFINE(UDEV, 1, [Have UDEV support])
167 fi
169 AC_CANONICAL_HOST
170 if test "x$LIBKMS" = xauto ; then
171 case $host_os in
172 linux*) LIBKMS="yes" ;;
173 *) LIBKMS="no" ;;
174 esac
175 fi
177 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
179 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
180 if test "x$VMWGFX" = xyes; then
181 AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
182 fi
184 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
185 if test "x$NOUVEAU" = xyes; then
186 AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
187 fi
189 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
190 if test "x$OMAP" = xyes; then
191 AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
192 fi
194 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
195 if test "x$HAVE_CAIRO" = xyes; then
196 AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
197 fi
198 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
200 # For enumerating devices in test case
201 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
202 if test "x$HAVE_LIBUDEV" = xyes; then
203 AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
204 fi
205 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
207 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno" -o "x$NOUVEAU" != "xno"; then
208 # Check for atomic intrinsics
209 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
210 [
211 drm_cv_atomic_primitives="none"
213 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
214 int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
215 int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
216 ]],[[]])],
217 [drm_cv_atomic_primitives="Intel"],[])
219 if test "x$drm_cv_atomic_primitives" = "xnone"; then
220 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
221 fi
223 # atomic functions defined in <atomic.h> & libc on Solaris
224 if test "x$drm_cv_atomic_primitives" = "xnone"; then
225 AC_CHECK_FUNC([atomic_cas_uint],
226 drm_cv_atomic_primitives="Solaris")
227 fi
229 ])
230 if test "x$drm_cv_atomic_primitives" = xIntel; then
231 AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
232 [Enable if your compiler supports the Intel __sync_* atomic primitives])
233 fi
234 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
235 AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
236 fi
238 if test "x$drm_cv_atomic_primitives" = "xnone"; then
239 if test "x$INTEL" != "xauto"; then
240 if test "x$INTEL" != "xno"; then
241 AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
242 fi
243 else
244 AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
245 INTEL=no
246 fi
247 if test "x$RADEON" != "xauto"; then
248 if test "x$RADEON" != "xno"; then
249 AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
250 fi
251 else
252 AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
253 RADEON=no
254 fi
255 if test "x$NOUVEAU" != "xauto"; then
256 if test "x$NOUVEAU" != "xno"; then
257 AC_MSG_ERROR([libdrm_nouveau depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA GPUs by passing --disable-nouveau to ./configure])
258 fi
259 else
260 AC_MSG_WARN([Disabling libdrm_nouveau. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
261 NOUVEAU=no
262 fi
263 else
264 if test "x$INTEL" != "xno"; then
265 case $host_cpu in
266 i?86|x86_64) INTEL=yes ;;
267 *) INTEL=no ;;
268 esac
269 fi
270 if test "x$RADEON" != "xno"; then
271 RADEON=yes
272 fi
273 if test "x$NOUVEAU" != "xno"; then
274 NOUVEAU=yes
275 fi
276 fi
277 fi
279 if test "x$INTEL" != "xno"; then
280 PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
281 fi
282 AC_SUBST(PCIACCESS_CFLAGS)
283 AC_SUBST(PCIACCESS_LIBS)
285 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
286 if test "x$have_valgrind" = "xyes"; then
287 AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
288 fi
290 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
291 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
292 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" != "xno"])
293 if test "x$RADEON" = xyes; then
294 AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
295 fi
297 AC_ARG_WITH([kernel-source],
298 [AS_HELP_STRING([--with-kernel-source],
299 [specify path to linux kernel source])],
300 [kernel_source="$with_kernel_source"])
301 AC_SUBST(kernel_source)
303 AC_SUBST(WARN_CFLAGS)
304 AC_CONFIG_FILES([
305 Makefile
306 libkms/Makefile
307 libkms/libkms.pc
308 intel/Makefile
309 intel/libdrm_intel.pc
310 radeon/Makefile
311 radeon/libdrm_radeon.pc
312 nouveau/Makefile
313 nouveau/libdrm_nouveau.pc
314 omap/Makefile
315 omap/libdrm_omap.pc
316 tests/Makefile
317 tests/modeprint/Makefile
318 tests/modetest/Makefile
319 tests/kmstest/Makefile
320 tests/radeon/Makefile
321 tests/vbltest/Makefile
322 include/Makefile
323 include/drm/Makefile
324 libdrm.pc])
325 AC_OUTPUT
327 echo ""
328 echo "$PACKAGE_STRING will be compiled with:"
329 echo ""
330 echo " libkms $LIBKMS"
331 echo " Intel API $INTEL"
332 echo " vmwgfx API $VMWGFX"
333 echo " Radeon API $RADEON"
334 echo " Nouveau API $NOUVEAU"
335 echo " OMAP API $OMAP"
336 echo ""