radeon: fix unused-function warning
[glsdk/libdrm.git] / configure.ac
1 #  Copyright 2005 Adam Jackson.
2 #
3 #  Permission is hereby granted, free of charge, to any person obtaining a
4 #  copy of this software and associated documentation files (the "Software"),
5 #  to deal in the Software without restriction, including without limitation
6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
7 #  license, and/or sell copies of the Software, and to permit persons to whom
8 #  the Software is furnished to do so, subject to the following conditions:
9 #
10 #  The above copyright notice and this permission notice (including the next
11 #  paragraph) shall be included in all copies or substantial portions of the
12 #  Software.
13 #
14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ([2.63])
22 AC_INIT([libdrm],
23         [2.4.39],
24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
25         [libdrm])
27 AC_CONFIG_HEADERS([config.h])
28 AC_CONFIG_SRCDIR([Makefile.am])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_AUX_DIR([build-aux])
32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
33 AM_MAINTAINER_MODE([enable])
35 # Enable quiet compiles on automake 1.11.
36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
38 if test x$LIB_MAN_SUFFIX = x    ; then
39     LIB_MAN_SUFFIX=3
40 fi
41 if test x$LIB_MAN_DIR = x    ; then
42     LIB_MAN_DIR='$(mandir)/man$(LIB_MAN_SUFFIX)'
43 fi
44 AC_SUBST([LIB_MAN_SUFFIX])
45 AC_SUBST([LIB_MAN_DIR])
47 MAN_SUBSTS="\
48         -e 's|__vendorversion__|\"\$(PACKAGE_STRING)\" |' \
49         -e 's|__projectroot__|\$(prefix)|g' \
50         -e 's|__apploaddir__|\$(appdefaultdir)|g' \
51         -e 's|__appmansuffix__|\$(APP_MAN_SUFFIX)|g' \
52         -e 's|__drivermansuffix__|\$(DRIVER_MAN_SUFFIX)|g' \
53         -e 's|__adminmansuffix__|\$(ADMIN_MAN_SUFFIX)|g' \
54         -e 's|__libmansuffix__|\$(LIB_MAN_SUFFIX)|g' \
55         -e 's|__miscmansuffix__|\$(MISC_MAN_SUFFIX)|g' \
56         -e 's|__filemansuffix__|\$(FILE_MAN_SUFFIX)|g'"
57 AC_SUBST([MAN_SUBSTS])
59 # Check for programs
60 AC_PROG_CC
62 AC_USE_SYSTEM_EXTENSIONS
63 AC_SYS_LARGEFILE
64 AC_FUNC_ALLOCA
66 # Initialize libtool
67 LT_PREREQ([2.2])
68 LT_INIT([disable-static])
71 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
72 AC_SUBST(PTHREADSTUBS_CFLAGS)
73 AC_SUBST(PTHREADSTUBS_LIBS)
75 pkgconfigdir=${libdir}/pkgconfig
76 AC_SUBST(pkgconfigdir)
77 AC_ARG_ENABLE([udev],
78               [AS_HELP_STRING([--enable-udev],
79                               [Enable support for using udev instead of mknod (default: disabled)])],
80               [UDEV=$enableval], [UDEV=no])
82 AC_ARG_ENABLE(libkms,
83               AS_HELP_STRING([--disable-libkms],
84               [Disable KMS mm abstraction library (default: auto)]),
85               [LIBKMS=$enableval], [LIBKMS=auto])
87 AC_ARG_ENABLE(intel,
88               AS_HELP_STRING([--disable-intel],
89               [Enable support for intel's KMS API (default: auto)]),
90               [INTEL=$enableval], [INTEL=auto])
92 AC_ARG_ENABLE(radeon,
93               AS_HELP_STRING([--disable-radeon],
94               [Enable support for radeon's KMS API (default: auto)]),
95               [RADEON=$enableval], [RADEON=auto])
97 AC_ARG_ENABLE(nouveau,
98               AS_HELP_STRING([--disable-nouveau],
99               [Enable support for nouveau's KMS API (default: auto)]),
100               [NOUVEAU=$enableval], [NOUVEAU=auto])
102 AC_ARG_ENABLE(vmwgfx,
103               AS_HELP_STRING([--disable-vmwgfx],
104               [Enable support for vmwgfx's KMS API (default: yes)]),
105               [VMWGFX=$enableval], [VMWGFX=yes])
107 AC_ARG_ENABLE(omap-experimental-api,
108               AS_HELP_STRING([--enable-omap-experimental-api],
109               [Enable support for OMAP's experimental API (default: disabled)]),
110               [OMAP=$enableval], [OMAP=no])
112 AC_ARG_ENABLE(exynos-experimental-api,
113               AS_HELP_STRING([--enable-exynos-experimental-api],
114               [Enable support for EXYNOS's experimental API (default: disabled)]),
115               [EXYNOS=$enableval], [EXYNOS=no])
117 dnl ===========================================================================
118 dnl check compiler flags
119 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
120   AC_MSG_CHECKING([whether $CC supports $1])
122   libdrm_save_CFLAGS="$CFLAGS"
123   CFLAGS="$CFLAGS $1"
125   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
126   CFLAGS="$libdrm_save_CFLAGS"
128   if test "x$libdrm_cc_flag" = "xyes"; then
129     ifelse([$2], , :, [$2])
130   else
131     ifelse([$3], , :, [$3])
132   fi
133   AC_MSG_RESULT([$libdrm_cc_flag])
134 ])
136 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
138 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
139                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
140                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
141 AC_SUBST([CLOCK_LIB])
143 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
145 dnl Use lots of warning flags with with gcc and compatible compilers
147 dnl Note: if you change the following variable, the cache is automatically
148 dnl skipped and all flags rechecked.  So there's no need to do anything
149 dnl else.  If for any reason you need to force a recheck, just change
150 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
152 MAYBE_WARN="-Wall -Wextra \
153 -Wsign-compare -Werror-implicit-function-declaration \
154 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
155 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
156 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
157 -Wstrict-aliasing=2 -Winit-self \
158 -Wdeclaration-after-statement -Wold-style-definition \
159 -Wno-missing-field-initializers -Wno-unused-parameter \
160 -Wno-attributes -Wno-long-long -Winline"
162 # invalidate cached value if MAYBE_WARN has changed
163 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
164         unset libdrm_cv_warn_cflags
165 fi
166 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
167         echo
168         WARN_CFLAGS=""
170         # Some warning options are not supported by all versions of
171         # gcc, so test all desired options against the current
172         # compiler.
173         #
174         # Note that there are some order dependencies
175         # here. Specifically, an option that disables a warning will
176         # have no net effect if a later option then enables that
177         # warnings, (perhaps implicitly). So we put some grouped
178         # options (-Wall and -Wextra) up front and the -Wno options
179         # last.
181         for W in $MAYBE_WARN; do
182                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
183         done
185         libdrm_cv_warn_cflags=$WARN_CFLAGS
186         libdrm_cv_warn_maybe=$MAYBE_WARN
188         AC_MSG_CHECKING([which warning flags were supported])])
189 WARN_CFLAGS="$libdrm_cv_warn_cflags"
191 if test "x$UDEV" = xyes; then
192         AC_DEFINE(UDEV, 1, [Have UDEV support])
193 fi
195 AC_CANONICAL_HOST
196 if test "x$LIBKMS" = xauto ; then
197         case $host_os in
198                 linux*)         LIBKMS="yes" ;;
199                 *)              LIBKMS="no" ;;
200         esac
201 fi
203 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
205 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
206 if test "x$VMWGFX" = xyes; then
207         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
208 fi
210 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
211 if test "x$NOUVEAU" = xyes; then
212         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
213 fi
215 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
216 if test "x$OMAP" = xyes; then
217         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
218 fi
220 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
221 if test "x$EXYNOS" = xyes; then
222         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
223 fi
225 AC_ARG_ENABLE([cairo-tests],
226               [AS_HELP_STRING([--enable-cairo-tests],
227                               [Enable support for Cairo rendering in tests (default: auto)])],
228               [CAIRO=$enableval], [CAIRO=auto])
229 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
230 AC_MSG_CHECKING([whether to enable Cairo tests])
231 if test "x$CAIRO" = xauto; then
232         CAIRO="$HAVE_CAIRO"
233 fi
234 if test "x$CAIRO" = xyes; then
235         if ! test "x$HAVE_CAIRO" = xyes; then
236                 AC_MSG_ERROR([Cairo support required but not present])
237         fi
238         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
239 fi
240 AC_MSG_RESULT([$CAIRO])
241 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
243 # For enumerating devices in test case
244 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
245 if test "x$HAVE_LIBUDEV" = xyes; then
246         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
247 fi
248 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
250 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno" -o "x$NOUVEAU" != "xno" -o "x$OMAP" != "xno"; then
251     # Check for atomic intrinsics
252     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
253     [
254             drm_cv_atomic_primitives="none"
256             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
257     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
258     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
259                                             ]],[[]])],
260                            [drm_cv_atomic_primitives="Intel"],[])
262             if test "x$drm_cv_atomic_primitives" = "xnone"; then
263                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
264             fi
266             # atomic functions defined in <atomic.h> & libc on Solaris
267             if test "x$drm_cv_atomic_primitives" = "xnone"; then
268                     AC_CHECK_FUNC([atomic_cas_uint],
269                                   drm_cv_atomic_primitives="Solaris")
270             fi
272     ])
273     if test "x$drm_cv_atomic_primitives" = xIntel; then
274             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
275                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
276     fi
277     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
278             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
279     fi
281     if test "x$drm_cv_atomic_primitives" = "xnone"; then
282            if test "x$INTEL" != "xauto"; then
283                    if test "x$INTEL" != "xno"; then
284                         AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
285                    fi
286            else
287                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
288                    INTEL=no
289            fi
290            if test "x$RADEON" != "xauto"; then
291                    if test "x$RADEON" != "xno"; then
292                         AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
293                    fi
294            else
295                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
296                    RADEON=no
297            fi
298            if test "x$NOUVEAU" != "xauto"; then
299                    if test "x$NOUVEAU" != "xno"; then
300                         AC_MSG_ERROR([libdrm_nouveau depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA GPUs by passing --disable-nouveau to ./configure])
301                    fi
302            else
303                    AC_MSG_WARN([Disabling libdrm_nouveau. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
304                    NOUVEAU=no
305            fi
306     else
307            if test "x$INTEL" != "xno"; then
308                    case $host_cpu in
309                            i?86|x86_64) INTEL=yes ;;
310                            *) INTEL=no ;;
311                    esac
312            fi
313            if test "x$RADEON" != "xno"; then
314                    RADEON=yes
315            fi
316            if test "x$NOUVEAU" != "xno"; then
317                    NOUVEAU=yes
318            fi
319     fi
320 fi
322 if test "x$INTEL" != "xno"; then
323         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
324 fi
325 AC_SUBST(PCIACCESS_CFLAGS)
326 AC_SUBST(PCIACCESS_LIBS)
328 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
329 if test "x$have_valgrind" = "xyes"; then
330         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
331 fi
333 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
334 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
335 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" != "xno"])
336 if test "x$RADEON" = xyes; then
337         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
338 fi
340 AC_ARG_WITH([kernel-source],
341             [AS_HELP_STRING([--with-kernel-source],
342               [specify path to linux kernel source])],
343             [kernel_source="$with_kernel_source"])
344 AC_SUBST(kernel_source)
346 AC_SUBST(WARN_CFLAGS)
347 AC_CONFIG_FILES([
348         Makefile
349         libkms/Makefile
350         libkms/libkms.pc
351         intel/Makefile
352         intel/libdrm_intel.pc
353         radeon/Makefile
354         radeon/libdrm_radeon.pc
355         nouveau/Makefile
356         nouveau/libdrm_nouveau.pc
357         omap/Makefile
358         omap/libdrm_omap.pc
359         exynos/Makefile
360         exynos/libdrm_exynos.pc
361         tests/Makefile
362         tests/modeprint/Makefile
363         tests/modetest/Makefile
364         tests/kmstest/Makefile
365         tests/radeon/Makefile
366         tests/vbltest/Makefile
367         include/Makefile
368         include/drm/Makefile
369         man/Makefile
370         libdrm.pc])
371 AC_OUTPUT
373 echo ""
374 echo "$PACKAGE_STRING will be compiled with:"
375 echo ""
376 echo "  libkms         $LIBKMS"
377 echo "  Intel API      $INTEL"
378 echo "  vmwgfx API     $VMWGFX"
379 echo "  Radeon API     $RADEON"
380 echo "  Nouveau API    $NOUVEAU"
381 echo "  OMAP API       $OMAP"
382 echo "  EXYNOS API     $EXYNOS"
383 echo ""