vmwgfx: Add experimental vmwgfx kernel header
[glsdk/libdrm.git] / configure.ac
1 #  Copyright 2005 Adam Jackson.
2 #
3 #  Permission is hereby granted, free of charge, to any person obtaining a
4 #  copy of this software and associated documentation files (the "Software"),
5 #  to deal in the Software without restriction, including without limitation
6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
7 #  license, and/or sell copies of the Software, and to permit persons to whom
8 #  the Software is furnished to do so, subject to the following conditions:
9 #
10 #  The above copyright notice and this permission notice (including the next
11 #  paragraph) shall be included in all copies or substantial portions of the
12 #  Software.
13 #
14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ(2.60)
22 AC_INIT([libdrm], 2.4.17, [dri-devel@lists.sourceforge.net], libdrm)
23 AC_USE_SYSTEM_EXTENSIONS
24 AC_CONFIG_SRCDIR([Makefile.am])
25 AM_INIT_AUTOMAKE([dist-bzip2])
27 AM_CONFIG_HEADER([config.h])
29 AC_DISABLE_STATIC
30 AC_PROG_LIBTOOL
31 AC_PROG_CC
33 AC_HEADER_STDC
34 AC_SYS_LARGEFILE
36 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
37 AC_SUBST(PTHREADSTUBS_CFLAGS)
38 AC_SUBST(PTHREADSTUBS_LIBS)
40 pkgconfigdir=${libdir}/pkgconfig
41 AC_SUBST(pkgconfigdir)
42 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
43                                 [Enable support for using udev instead of mknod (default: disabled)]),
44                                 [UDEV=$enableval], [UDEV=no])
46 AC_ARG_ENABLE(intel,
47               AS_HELP_STRING([--disable-intel],
48               [Enable support for intel's KMS API (default: auto)]),
49               [INTEL=$enableval], [INTEL=auto])
51 AC_ARG_ENABLE(vmwgfx-experimental-api,
52               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
53               [Install vmwgfx's experimental kernel API header (default: disabled)]),
54               [VMWGFX=$enableval], [VMWGFX=no])
56 AC_ARG_ENABLE(nouveau-experimental-api,
57               AS_HELP_STRING([--enable-nouveau-experimental-api],
58               [Enable support for nouveau's experimental API (default: disabled)]),
59               [NOUVEAU=$enableval], [NOUVEAU=no])
61 AC_ARG_ENABLE(radeon-experimental-api,
62               AS_HELP_STRING([--enable-radeon-experimental-api],
63               [Enable support for radeon's KMS API (default: disabled)]),
64               [RADEON=$enableval], [RADEON=no])
66 dnl ===========================================================================
67 dnl check compiler flags
68 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
69   AC_MSG_CHECKING([whether $CC supports $1])
71   libdrm_save_CFLAGS="$CFLAGS"
72   CFLAGS="$CFLAGS $1"
74   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
75   CFLAGS="$libdrm_save_CFLAGS"
77   if test "x$libdrm_cc_flag" = "xyes"; then
78     ifelse([$2], , :, [$2])
79   else
80     ifelse([$3], , :, [$3])
81   fi
82   AC_MSG_RESULT([$libdrm_cc_flag])
83 ])
85 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
87 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
88                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
89                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
90 AC_SUBST([CLOCK_LIB])
92 dnl Use lots of warning flags with with gcc and compatible compilers
94 dnl Note: if you change the following variable, the cache is automatically
95 dnl skipped and all flags rechecked.  So there's no need to do anything
96 dnl else.  If for any reason you need to force a recheck, just change
97 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
99 MAYBE_WARN="-Wall -Wextra \
100 -Wsign-compare -Werror-implicit-function-declaration \
101 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
102 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
103 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
104 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
105 -Wdeclaration-after-statement -Wold-style-definition \
106 -Wno-missing-field-initializers -Wno-unused-parameter \
107 -Wno-attributes -Wno-long-long -Winline"
109 # invalidate cached value if MAYBE_WARN has changed
110 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
111         unset libdrm_cv_warn_cflags
112 fi
113 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
114         echo
115         WARN_CFLAGS=""
117         # Some warning options are not supported by all versions of
118         # gcc, so test all desired options against the current
119         # compiler.
120         #
121         # Note that there are some order dependencies
122         # here. Specifically, an option that disables a warning will
123         # have no net effect if a later option then enables that
124         # warnings, (perhaps implicitly). So we put some grouped
125         # options (-Wall and -Wextra) up front and the -Wno options
126         # last.
128         for W in $MAYBE_WARN; do
129                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
130         done
132         libdrm_cv_warn_cflags=$WARN_CFLAGS
133         libdrm_cv_warn_maybe=$MAYBE_WARN
135         AC_MSG_CHECKING([which warning flags were supported])])
136 WARN_CFLAGS="$libdrm_cv_warn_cflags"
138 if test "x$UDEV" = xyes; then
139         AC_DEFINE(UDEV, 1, [Have UDEV support])
140 fi
142 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
144 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
146 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
148 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
149 if test "x$HAVE_CAIRO" = xyes; then
150         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
151 fi
152 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
154 # For enumerating devices in test case
155 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
156 if test "x$HAVE_LIBUDEV" = xyes; then
157         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
158 fi
159 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
161 if test "x$INTEL" != "xno"; then
162     # Check for atomic intrinsics
163     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
164     [
165             drm_cv_atomic_primitives="none"
167             AC_TRY_LINK([
168     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
169     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
170     ], [],
171               drm_cv_atomic_primitives="Intel"
172               )
174             if test "x$drm_cv_atomic_primitives" = "xnone"; then
175                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
176             fi
178     ])
179     if test "x$drm_cv_atomic_primitives" = xIntel; then
180             AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1,
181                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
182     fi
183     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
184             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
185     fi
187     if test "x$drm_cv_atomic_primitives" = "xnone"; then
188             if test "x$INTEL" != "xauto"; then
189                     AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
190            else
191                     INTEL=no
192            fi
193     else
194            INTEL=yes
195     fi
196 fi
198 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
200 AC_ARG_WITH([kernel-source],
201             [AS_HELP_STRING([--with-kernel-source],
202               [specify path to linux kernel source])],
203             [kernel_source="$with_kernel_source"])
204 AC_SUBST(kernel_source)
206 AC_SUBST(WARN_CFLAGS)
207 AC_OUTPUT([
208         Makefile
209         intel/Makefile
210         intel/libdrm_intel.pc
211         radeon/Makefile
212         radeon/libdrm_radeon.pc
213         nouveau/Makefile
214         nouveau/libdrm_nouveau.pc
215         tests/Makefile
216         tests/modeprint/Makefile
217         tests/modetest/Makefile
218         include/Makefile
219         include/drm/Makefile
220         libdrm.pc])
222 echo ""
223 echo "$PACKAGE_STRING will be compiled with:"
224 echo ""
225 echo "  Intel API      $INTEL"
226 echo "  vmwgfx API     $VMWGFX"
227 echo "  Radeon API     $RADEON"
228 echo "  Nouveau API    $NOUVEAU"
229 echo ""