libdrm_radeon: Optimize cs_gem_reloc to do less looping.
[glsdk/libdrm.git] / configure.ac
1 #  Copyright 2005 Adam Jackson.
2 #
3 #  Permission is hereby granted, free of charge, to any person obtaining a
4 #  copy of this software and associated documentation files (the "Software"),
5 #  to deal in the Software without restriction, including without limitation
6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
7 #  license, and/or sell copies of the Software, and to permit persons to whom
8 #  the Software is furnished to do so, subject to the following conditions:
9 #
10 #  The above copyright notice and this permission notice (including the next
11 #  paragraph) shall be included in all copies or substantial portions of the
12 #  Software.
13 #
14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ(2.60)
22 AC_INIT([libdrm], 2.4.19, [dri-devel@lists.sourceforge.net], libdrm)
23 AC_USE_SYSTEM_EXTENSIONS
24 AC_CONFIG_SRCDIR([Makefile.am])
25 AM_INIT_AUTOMAKE([dist-bzip2])
27 AM_CONFIG_HEADER([config.h])
29 AC_DISABLE_STATIC
30 AC_PROG_LIBTOOL
31 AC_PROG_CC
33 AC_HEADER_STDC
34 AC_SYS_LARGEFILE
35 AC_FUNC_ALLOCA
37 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
38 AC_SUBST(PTHREADSTUBS_CFLAGS)
39 AC_SUBST(PTHREADSTUBS_LIBS)
41 pkgconfigdir=${libdir}/pkgconfig
42 AC_SUBST(pkgconfigdir)
43 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
44                                 [Enable support for using udev instead of mknod (default: disabled)]),
45                                 [UDEV=$enableval], [UDEV=no])
47 AC_ARG_ENABLE(libkms,
48               AS_HELP_STRING([--disable-libkms],
49               [Disable KMS mm abstraction library (default: enabled)]),
50               [LIBKMS=$enableval], [LIBKMS=yes])
52 AC_ARG_ENABLE(intel,
53               AS_HELP_STRING([--disable-intel],
54               [Enable support for intel's KMS API (default: auto)]),
55               [INTEL=$enableval], [INTEL=auto])
57 AC_ARG_ENABLE(radeon,
58               AS_HELP_STRING([--disable-radeon],
59               [Enable support for radeon's KMS API (default: auto)]),
60               [RADEON=$enableval], [RADEON=auto])
62 AC_ARG_ENABLE(vmwgfx-experimental-api,
63               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
64               [Install vmwgfx's experimental kernel API header (default: disabled)]),
65               [VMWGFX=$enableval], [VMWGFX=no])
67 AC_ARG_ENABLE(nouveau-experimental-api,
68               AS_HELP_STRING([--enable-nouveau-experimental-api],
69               [Enable support for nouveau's experimental API (default: disabled)]),
70               [NOUVEAU=$enableval], [NOUVEAU=no])
73 dnl ===========================================================================
74 dnl check compiler flags
75 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
76   AC_MSG_CHECKING([whether $CC supports $1])
78   libdrm_save_CFLAGS="$CFLAGS"
79   CFLAGS="$CFLAGS $1"
81   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
82   CFLAGS="$libdrm_save_CFLAGS"
84   if test "x$libdrm_cc_flag" = "xyes"; then
85     ifelse([$2], , :, [$2])
86   else
87     ifelse([$3], , :, [$3])
88   fi
89   AC_MSG_RESULT([$libdrm_cc_flag])
90 ])
92 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
94 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
95                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
96                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
97 AC_SUBST([CLOCK_LIB])
99 dnl Use lots of warning flags with with gcc and compatible compilers
101 dnl Note: if you change the following variable, the cache is automatically
102 dnl skipped and all flags rechecked.  So there's no need to do anything
103 dnl else.  If for any reason you need to force a recheck, just change
104 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
106 MAYBE_WARN="-Wall -Wextra \
107 -Wsign-compare -Werror-implicit-function-declaration \
108 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
109 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
110 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
111 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
112 -Wdeclaration-after-statement -Wold-style-definition \
113 -Wno-missing-field-initializers -Wno-unused-parameter \
114 -Wno-attributes -Wno-long-long -Winline"
116 # invalidate cached value if MAYBE_WARN has changed
117 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
118         unset libdrm_cv_warn_cflags
119 fi
120 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
121         echo
122         WARN_CFLAGS=""
124         # Some warning options are not supported by all versions of
125         # gcc, so test all desired options against the current
126         # compiler.
127         #
128         # Note that there are some order dependencies
129         # here. Specifically, an option that disables a warning will
130         # have no net effect if a later option then enables that
131         # warnings, (perhaps implicitly). So we put some grouped
132         # options (-Wall and -Wextra) up front and the -Wno options
133         # last.
135         for W in $MAYBE_WARN; do
136                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
137         done
139         libdrm_cv_warn_cflags=$WARN_CFLAGS
140         libdrm_cv_warn_maybe=$MAYBE_WARN
142         AC_MSG_CHECKING([which warning flags were supported])])
143 WARN_CFLAGS="$libdrm_cv_warn_cflags"
145 if test "x$UDEV" = xyes; then
146         AC_DEFINE(UDEV, 1, [Have UDEV support])
147 fi
149 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
151 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
152 if test "x$VMWGFX" = xyes; then
153         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
154 fi
156 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
157 if test "x$NOUVEAU" = xyes; then
158         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
159 fi
161 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
163 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
164 if test "x$HAVE_CAIRO" = xyes; then
165         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
166 fi
167 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
169 # For enumerating devices in test case
170 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
171 if test "x$HAVE_LIBUDEV" = xyes; then
172         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
173 fi
174 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
176 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno"; then
177     # Check for atomic intrinsics
178     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
179     [
180             drm_cv_atomic_primitives="none"
182             AC_TRY_LINK([
183     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
184     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
185     ], [],
186               drm_cv_atomic_primitives="Intel"
187               )
189             if test "x$drm_cv_atomic_primitives" = "xnone"; then
190                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
191             fi
193             # atomic functions defined in <atomic.h> & libc on Solaris
194             if test "x$drm_cv_atomic_primitives" = "xnone"; then
195                     AC_CHECK_FUNC([atomic_cas_uint],
196                                   drm_cv_atomic_primitives="Solaris")
197             fi
199     ])
200     if test "x$drm_cv_atomic_primitives" = xIntel; then
201             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
202                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
203     fi
204     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
205             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
206     fi
208     if test "x$drm_cv_atomic_primitives" = "xnone"; then
209            if test "x$INTEL" != "xauto"; then
210                    AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
211            else
212                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
213                    INTEL=no
214            fi
215            if test "x$RADEON" != "xauto"; then
216                    AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
217            else
218                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
219                    RADEON=no
220            fi
222     else
223            if test "x$INTEL" != "xno"; then
224                    INTEL=yes
225            fi
226            if test "x$RADEON" != "xno"; then
227                    RADEON=yes
228            fi
229     fi
230 fi
232 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
234 AC_ARG_WITH([kernel-source],
235             [AS_HELP_STRING([--with-kernel-source],
236               [specify path to linux kernel source])],
237             [kernel_source="$with_kernel_source"])
238 AC_SUBST(kernel_source)
240 AC_SUBST(WARN_CFLAGS)
241 AC_OUTPUT([
242         Makefile
243         libkms/Makefile
244         libkms/libkms.pc
245         intel/Makefile
246         intel/libdrm_intel.pc
247         radeon/Makefile
248         radeon/libdrm_radeon.pc
249         nouveau/Makefile
250         nouveau/libdrm_nouveau.pc
251         tests/Makefile
252         tests/modeprint/Makefile
253         tests/modetest/Makefile
254         tests/kmstest/Makefile
255         include/Makefile
256         include/drm/Makefile
257         libdrm.pc])
259 echo ""
260 echo "$PACKAGE_STRING will be compiled with:"
261 echo ""
262 echo "  libkms         $LIBKMS"
263 echo "  Intel API      $INTEL"
264 echo "  vmwgfx API     $VMWGFX"
265 echo "  Radeon API     $RADEON"
266 echo "  Nouveau API    $NOUVEAU"
267 echo ""