intel: Fix build of Intel DRM on x86 systems
[glsdk/libdrm.git] / configure.ac
1 #  Copyright 2005 Adam Jackson.
2 #
3 #  Permission is hereby granted, free of charge, to any person obtaining a
4 #  copy of this software and associated documentation files (the "Software"),
5 #  to deal in the Software without restriction, including without limitation
6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
7 #  license, and/or sell copies of the Software, and to permit persons to whom
8 #  the Software is furnished to do so, subject to the following conditions:
9 #
10 #  The above copyright notice and this permission notice (including the next
11 #  paragraph) shall be included in all copies or substantial portions of the
12 #  Software.
13 #
14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ([2.63])
22 AC_INIT([libdrm],
23         [2.4.30],
24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
25         [libdrm])
27 AC_CONFIG_HEADERS([config.h])
28 AC_CONFIG_SRCDIR([Makefile.am])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_AUX_DIR([build-aux])
32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
33 AM_MAINTAINER_MODE([enable])
35 # Enable quiet compiles on automake 1.11.
36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
38 # Check for programs
39 AC_PROG_CC
41 AC_USE_SYSTEM_EXTENSIONS
42 AC_SYS_LARGEFILE
43 AC_FUNC_ALLOCA
45 # Initialize libtool
46 LT_PREREQ([2.2])
47 LT_INIT([disable-static])
50 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
51 AC_SUBST(PTHREADSTUBS_CFLAGS)
52 AC_SUBST(PTHREADSTUBS_LIBS)
54 PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
55 AC_SUBST(PCIACCESS_CFLAGS)
56 AC_SUBST(PCIACCESS_LIBS)
58 pkgconfigdir=${libdir}/pkgconfig
59 AC_SUBST(pkgconfigdir)
60 AC_ARG_ENABLE([udev],
61               [AS_HELP_STRING([--enable-udev],
62                               [Enable support for using udev instead of mknod (default: disabled)])],
63               [UDEV=$enableval], [UDEV=no])
65 AC_ARG_ENABLE(libkms,
66               AS_HELP_STRING([--disable-libkms],
67               [Disable KMS mm abstraction library (default: auto)]),
68               [LIBKMS=$enableval], [LIBKMS=auto])
70 AC_ARG_ENABLE(intel,
71               AS_HELP_STRING([--disable-intel],
72               [Enable support for intel's KMS API (default: auto)]),
73               [INTEL=$enableval], [INTEL=auto])
75 AC_ARG_ENABLE(radeon,
76               AS_HELP_STRING([--disable-radeon],
77               [Enable support for radeon's KMS API (default: auto)]),
78               [RADEON=$enableval], [RADEON=auto])
80 AC_ARG_ENABLE(vmwgfx-experimental-api,
81               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
82               [Install vmwgfx's experimental kernel API header (default: disabled)]),
83               [VMWGFX=$enableval], [VMWGFX=no])
85 AC_ARG_ENABLE(nouveau-experimental-api,
86               AS_HELP_STRING([--enable-nouveau-experimental-api],
87               [Enable support for nouveau's experimental API (default: disabled)]),
88               [NOUVEAU=$enableval], [NOUVEAU=no])
91 dnl ===========================================================================
92 dnl check compiler flags
93 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
94   AC_MSG_CHECKING([whether $CC supports $1])
96   libdrm_save_CFLAGS="$CFLAGS"
97   CFLAGS="$CFLAGS $1"
99   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
100   CFLAGS="$libdrm_save_CFLAGS"
102   if test "x$libdrm_cc_flag" = "xyes"; then
103     ifelse([$2], , :, [$2])
104   else
105     ifelse([$3], , :, [$3])
106   fi
107   AC_MSG_RESULT([$libdrm_cc_flag])
108 ])
110 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
112 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
113                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
114                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
115 AC_SUBST([CLOCK_LIB])
117 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
119 dnl Use lots of warning flags with with gcc and compatible compilers
121 dnl Note: if you change the following variable, the cache is automatically
122 dnl skipped and all flags rechecked.  So there's no need to do anything
123 dnl else.  If for any reason you need to force a recheck, just change
124 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
126 MAYBE_WARN="-Wall -Wextra \
127 -Wsign-compare -Werror-implicit-function-declaration \
128 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
129 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
130 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
131 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
132 -Wdeclaration-after-statement -Wold-style-definition \
133 -Wno-missing-field-initializers -Wno-unused-parameter \
134 -Wno-attributes -Wno-long-long -Winline"
136 # invalidate cached value if MAYBE_WARN has changed
137 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
138         unset libdrm_cv_warn_cflags
139 fi
140 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
141         echo
142         WARN_CFLAGS=""
144         # Some warning options are not supported by all versions of
145         # gcc, so test all desired options against the current
146         # compiler.
147         #
148         # Note that there are some order dependencies
149         # here. Specifically, an option that disables a warning will
150         # have no net effect if a later option then enables that
151         # warnings, (perhaps implicitly). So we put some grouped
152         # options (-Wall and -Wextra) up front and the -Wno options
153         # last.
155         for W in $MAYBE_WARN; do
156                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
157         done
159         libdrm_cv_warn_cflags=$WARN_CFLAGS
160         libdrm_cv_warn_maybe=$MAYBE_WARN
162         AC_MSG_CHECKING([which warning flags were supported])])
163 WARN_CFLAGS="$libdrm_cv_warn_cflags"
165 if test "x$UDEV" = xyes; then
166         AC_DEFINE(UDEV, 1, [Have UDEV support])
167 fi
169 AC_CANONICAL_HOST
170 if test "x$LIBKMS" = xauto ; then
171         case $host_os in
172                 linux*)         LIBKMS="yes" ;;
173                 *)              LIBKMS="no" ;;
174         esac
175 fi
177 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
179 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
180 if test "x$VMWGFX" = xyes; then
181         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
182 fi
184 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
185 if test "x$NOUVEAU" = xyes; then
186         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
187 fi
189 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
190 if test "x$HAVE_CAIRO" = xyes; then
191         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
192 fi
193 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
195 # For enumerating devices in test case
196 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
197 if test "x$HAVE_LIBUDEV" = xyes; then
198         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
199 fi
200 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
202 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno"; then
203     # Check for atomic intrinsics
204     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
205     [
206             drm_cv_atomic_primitives="none"
208             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
209     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
210     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
211                                             ]],[[]])],
212                            [drm_cv_atomic_primitives="Intel"],[])
214             if test "x$drm_cv_atomic_primitives" = "xnone"; then
215                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
216             fi
218             # atomic functions defined in <atomic.h> & libc on Solaris
219             if test "x$drm_cv_atomic_primitives" = "xnone"; then
220                     AC_CHECK_FUNC([atomic_cas_uint],
221                                   drm_cv_atomic_primitives="Solaris")
222             fi
224     ])
225     if test "x$drm_cv_atomic_primitives" = xIntel; then
226             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
227                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
228     fi
229     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
230             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
231     fi
233     if test "x$drm_cv_atomic_primitives" = "xnone"; then
234            if test "x$INTEL" != "xauto"; then
235                    if test "x$INTEL" != "xno"; then
236                         AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
237                    fi
238            else
239                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
240                    INTEL=no
241            fi
242            if test "x$RADEON" != "xauto"; then
243                    if test "x$RADEON" != "xno"; then
244                         AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
245                    fi
246            else
247                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
248                    RADEON=no
249            fi
251     else
252            if test "x$INTEL" != "xno"; then
253                    case $host_cpu in
254                            i?86|x86_64) INTEL=yes ;;
255                            *) INTEL=no ;;
256                    esac
257            fi
258            if test "x$RADEON" != "xno"; then
259                    RADEON=yes
260            fi
261     fi
262 fi
264 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
265 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
266 if test "x$RADEON" = xyes; then
267         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
268 fi
270 AC_ARG_WITH([kernel-source],
271             [AS_HELP_STRING([--with-kernel-source],
272               [specify path to linux kernel source])],
273             [kernel_source="$with_kernel_source"])
274 AC_SUBST(kernel_source)
276 AC_SUBST(WARN_CFLAGS)
277 AC_CONFIG_FILES([
278         Makefile
279         libkms/Makefile
280         libkms/libkms.pc
281         intel/Makefile
282         intel/libdrm_intel.pc
283         radeon/Makefile
284         radeon/libdrm_radeon.pc
285         nouveau/Makefile
286         nouveau/libdrm_nouveau.pc
287         tests/Makefile
288         tests/modeprint/Makefile
289         tests/modetest/Makefile
290         tests/kmstest/Makefile
291         tests/radeon/Makefile
292         tests/vbltest/Makefile
293         include/Makefile
294         include/drm/Makefile
295         libdrm.pc])
296 AC_OUTPUT
298 echo ""
299 echo "$PACKAGE_STRING will be compiled with:"
300 echo ""
301 echo "  libkms         $LIBKMS"
302 echo "  Intel API      $INTEL"
303 echo "  vmwgfx API     $VMWGFX"
304 echo "  Radeon API     $RADEON"
305 echo "  Nouveau API    $NOUVEAU"
306 echo ""