Merge branch 'master' into libkms-master
[glsdk/libdrm.git] / configure.ac
1 #  Copyright 2005 Adam Jackson.
2 #
3 #  Permission is hereby granted, free of charge, to any person obtaining a
4 #  copy of this software and associated documentation files (the "Software"),
5 #  to deal in the Software without restriction, including without limitation
6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
7 #  license, and/or sell copies of the Software, and to permit persons to whom
8 #  the Software is furnished to do so, subject to the following conditions:
9 #
10 #  The above copyright notice and this permission notice (including the next
11 #  paragraph) shall be included in all copies or substantial portions of the
12 #  Software.
13 #
14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ(2.60)
22 AC_INIT([libdrm], 2.4.17, [dri-devel@lists.sourceforge.net], libdrm)
23 AC_USE_SYSTEM_EXTENSIONS
24 AC_CONFIG_SRCDIR([Makefile.am])
25 AM_INIT_AUTOMAKE([dist-bzip2])
27 AM_CONFIG_HEADER([config.h])
29 AC_DISABLE_STATIC
30 AC_PROG_LIBTOOL
31 AC_PROG_CC
33 AC_HEADER_STDC
34 AC_SYS_LARGEFILE
36 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
37 AC_SUBST(PTHREADSTUBS_CFLAGS)
38 AC_SUBST(PTHREADSTUBS_LIBS)
40 pkgconfigdir=${libdir}/pkgconfig
41 AC_SUBST(pkgconfigdir)
42 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
43                                 [Enable support for using udev instead of mknod (default: disabled)]),
44                                 [UDEV=$enableval], [UDEV=no])
46 AC_ARG_ENABLE(libkms,
47               AS_HELP_STRING([--enable-libkms],
48               [Enable KMS mm abstraction library (default: disabled)]),
49               [LIBKMS=$enableval], [LIBKMS=no])
51 AC_ARG_ENABLE(intel,
52               AS_HELP_STRING([--disable-intel],
53               [Enable support for intel's KMS API (default: auto)]),
54               [INTEL=$enableval], [INTEL=auto])
56 AC_ARG_ENABLE(vmwgfx-experimental-api,
57               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
58               [Install vmwgfx's experimental kernel API header (default: disabled)]),
59               [VMWGFX=$enableval], [VMWGFX=no])
61 AC_ARG_ENABLE(nouveau-experimental-api,
62               AS_HELP_STRING([--enable-nouveau-experimental-api],
63               [Enable support for nouveau's experimental API (default: disabled)]),
64               [NOUVEAU=$enableval], [NOUVEAU=no])
66 AC_ARG_ENABLE(radeon-experimental-api,
67               AS_HELP_STRING([--enable-radeon-experimental-api],
68               [Enable support for radeon's KMS API (default: disabled)]),
69               [RADEON=$enableval], [RADEON=no])
71 dnl ===========================================================================
72 dnl check compiler flags
73 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
74   AC_MSG_CHECKING([whether $CC supports $1])
76   libdrm_save_CFLAGS="$CFLAGS"
77   CFLAGS="$CFLAGS $1"
79   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
80   CFLAGS="$libdrm_save_CFLAGS"
82   if test "x$libdrm_cc_flag" = "xyes"; then
83     ifelse([$2], , :, [$2])
84   else
85     ifelse([$3], , :, [$3])
86   fi
87   AC_MSG_RESULT([$libdrm_cc_flag])
88 ])
90 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
92 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
93                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
94                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
95 AC_SUBST([CLOCK_LIB])
97 dnl Use lots of warning flags with with gcc and compatible compilers
99 dnl Note: if you change the following variable, the cache is automatically
100 dnl skipped and all flags rechecked.  So there's no need to do anything
101 dnl else.  If for any reason you need to force a recheck, just change
102 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
104 MAYBE_WARN="-Wall -Wextra \
105 -Wsign-compare -Werror-implicit-function-declaration \
106 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
107 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
108 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
109 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
110 -Wdeclaration-after-statement -Wold-style-definition \
111 -Wno-missing-field-initializers -Wno-unused-parameter \
112 -Wno-attributes -Wno-long-long -Winline"
114 # invalidate cached value if MAYBE_WARN has changed
115 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
116         unset libdrm_cv_warn_cflags
117 fi
118 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
119         echo
120         WARN_CFLAGS=""
122         # Some warning options are not supported by all versions of
123         # gcc, so test all desired options against the current
124         # compiler.
125         #
126         # Note that there are some order dependencies
127         # here. Specifically, an option that disables a warning will
128         # have no net effect if a later option then enables that
129         # warnings, (perhaps implicitly). So we put some grouped
130         # options (-Wall and -Wextra) up front and the -Wno options
131         # last.
133         for W in $MAYBE_WARN; do
134                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
135         done
137         libdrm_cv_warn_cflags=$WARN_CFLAGS
138         libdrm_cv_warn_maybe=$MAYBE_WARN
140         AC_MSG_CHECKING([which warning flags were supported])])
141 WARN_CFLAGS="$libdrm_cv_warn_cflags"
143 if test "x$UDEV" = xyes; then
144         AC_DEFINE(UDEV, 1, [Have UDEV support])
145 fi
147 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
149 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
151 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
153 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
155 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
156 if test "x$HAVE_CAIRO" = xyes; then
157         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
158 fi
159 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
161 # For enumerating devices in test case
162 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
163 if test "x$HAVE_LIBUDEV" = xyes; then
164         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
165 fi
166 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
168 if test "x$INTEL" != "xno"; then
169     # Check for atomic intrinsics
170     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
171     [
172             drm_cv_atomic_primitives="none"
174             AC_TRY_LINK([
175     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
176     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
177     ], [],
178               drm_cv_atomic_primitives="Intel"
179               )
181             if test "x$drm_cv_atomic_primitives" = "xnone"; then
182                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
183             fi
185     ])
186     if test "x$drm_cv_atomic_primitives" = xIntel; then
187             AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1,
188                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
189     fi
190     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
191             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
192     fi
194     if test "x$drm_cv_atomic_primitives" = "xnone"; then
195             if test "x$INTEL" != "xauto"; then
196                     AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
197            else
198                     INTEL=no
199            fi
200     else
201            INTEL=yes
202     fi
203 fi
205 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
207 AC_ARG_WITH([kernel-source],
208             [AS_HELP_STRING([--with-kernel-source],
209               [specify path to linux kernel source])],
210             [kernel_source="$with_kernel_source"])
211 AC_SUBST(kernel_source)
213 AC_SUBST(WARN_CFLAGS)
214 AC_OUTPUT([
215         Makefile
216         libkms/Makefile
217         libkms/libkms.pc
218         intel/Makefile
219         intel/libdrm_intel.pc
220         radeon/Makefile
221         radeon/libdrm_radeon.pc
222         nouveau/Makefile
223         nouveau/libdrm_nouveau.pc
224         tests/Makefile
225         tests/modeprint/Makefile
226         tests/modetest/Makefile
227         include/Makefile
228         include/drm/Makefile
229         libdrm.pc])
231 echo ""
232 echo "$PACKAGE_STRING will be compiled with:"
233 echo ""
234 echo "  libkms         $LIBKMS"
235 echo "  Intel API      $INTEL"
236 echo "  vmwgfx API     $VMWGFX"
237 echo "  Radeon API     $RADEON"
238 echo "  Nouveau API    $NOUVEAU"
239 echo ""