1 # Copyright 2005 Adam Jackson.
2 #
3 # Permission is hereby granted, free of charge, to any person obtaining a
4 # copy of this software and associated documentation files (the "Software"),
5 # to deal in the Software without restriction, including without limitation
6 # on the rights to use, copy, modify, merge, publish, distribute, sub
7 # license, and/or sell copies of the Software, and to permit persons to whom
8 # the Software is furnished to do so, subject to the following conditions:
9 #
10 # The above copyright notice and this permission notice (including the next
11 # paragraph) shall be included in all copies or substantial portions of the
12 # Software.
13 #
14 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 # FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT. IN NO EVENT SHALL
17 # ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 # IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 # CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ([2.63])
22 AC_INIT([libdrm],
23 [2.4.41],
24 [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
25 [libdrm])
27 AC_CONFIG_HEADERS([config.h])
28 AC_CONFIG_SRCDIR([Makefile.am])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_AUX_DIR([build-aux])
32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
33 AM_MAINTAINER_MODE([enable])
35 # Enable quiet compiles on automake 1.11.
36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
38 # Check for programs
39 AC_PROG_CC
41 AC_USE_SYSTEM_EXTENSIONS
42 AC_SYS_LARGEFILE
43 AC_FUNC_ALLOCA
45 # Initialize libtool
46 LT_PREREQ([2.2])
47 LT_INIT([disable-static])
50 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
51 AC_SUBST(PTHREADSTUBS_CFLAGS)
52 AC_SUBST(PTHREADSTUBS_LIBS)
54 pkgconfigdir=${libdir}/pkgconfig
55 AC_SUBST(pkgconfigdir)
56 AC_ARG_ENABLE([udev],
57 [AS_HELP_STRING([--enable-udev],
58 [Enable support for using udev instead of mknod (default: disabled)])],
59 [UDEV=$enableval], [UDEV=no])
61 AC_ARG_ENABLE(libkms,
62 AS_HELP_STRING([--disable-libkms],
63 [Disable KMS mm abstraction library (default: auto)]),
64 [LIBKMS=$enableval], [LIBKMS=auto])
66 AC_ARG_ENABLE(intel,
67 AS_HELP_STRING([--disable-intel],
68 [Enable support for intel's KMS API (default: auto)]),
69 [INTEL=$enableval], [INTEL=auto])
71 AC_ARG_ENABLE(radeon,
72 AS_HELP_STRING([--disable-radeon],
73 [Enable support for radeon's KMS API (default: auto)]),
74 [RADEON=$enableval], [RADEON=auto])
76 AC_ARG_ENABLE(nouveau,
77 AS_HELP_STRING([--disable-nouveau],
78 [Enable support for nouveau's KMS API (default: auto)]),
79 [NOUVEAU=$enableval], [NOUVEAU=auto])
81 AC_ARG_ENABLE(vmwgfx,
82 AS_HELP_STRING([--disable-vmwgfx],
83 [Enable support for vmwgfx's KMS API (default: yes)]),
84 [VMWGFX=$enableval], [VMWGFX=yes])
86 AC_ARG_ENABLE(omap-experimental-api,
87 AS_HELP_STRING([--enable-omap-experimental-api],
88 [Enable support for OMAP's experimental API (default: disabled)]),
89 [OMAP=$enableval], [OMAP=no])
91 AC_ARG_ENABLE(exynos-experimental-api,
92 AS_HELP_STRING([--enable-exynos-experimental-api],
93 [Enable support for EXYNOS's experimental API (default: disabled)]),
94 [EXYNOS=$enableval], [EXYNOS=no])
96 dnl ===========================================================================
97 dnl check compiler flags
98 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
99 AC_MSG_CHECKING([whether $CC supports $1])
101 libdrm_save_CFLAGS="$CFLAGS"
102 CFLAGS="$CFLAGS $1"
104 AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
105 CFLAGS="$libdrm_save_CFLAGS"
107 if test "x$libdrm_cc_flag" = "xyes"; then
108 ifelse([$2], , :, [$2])
109 else
110 ifelse([$3], , :, [$3])
111 fi
112 AC_MSG_RESULT([$libdrm_cc_flag])
113 ])
115 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
117 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
118 [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
119 [AC_MSG_ERROR([Couldn't find clock_gettime])])])
120 AC_SUBST([CLOCK_LIB])
122 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
124 dnl Use lots of warning flags with with gcc and compatible compilers
126 dnl Note: if you change the following variable, the cache is automatically
127 dnl skipped and all flags rechecked. So there's no need to do anything
128 dnl else. If for any reason you need to force a recheck, just change
129 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
131 MAYBE_WARN="-Wall -Wextra \
132 -Wsign-compare -Werror-implicit-function-declaration \
133 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
134 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
135 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
136 -Wstrict-aliasing=2 -Winit-self \
137 -Wdeclaration-after-statement -Wold-style-definition \
138 -Wno-missing-field-initializers -Wno-unused-parameter \
139 -Wno-attributes -Wno-long-long -Winline"
141 # invalidate cached value if MAYBE_WARN has changed
142 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
143 unset libdrm_cv_warn_cflags
144 fi
145 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
146 echo
147 WARN_CFLAGS=""
149 # Some warning options are not supported by all versions of
150 # gcc, so test all desired options against the current
151 # compiler.
152 #
153 # Note that there are some order dependencies
154 # here. Specifically, an option that disables a warning will
155 # have no net effect if a later option then enables that
156 # warnings, (perhaps implicitly). So we put some grouped
157 # options (-Wall and -Wextra) up front and the -Wno options
158 # last.
160 for W in $MAYBE_WARN; do
161 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
162 done
164 libdrm_cv_warn_cflags=$WARN_CFLAGS
165 libdrm_cv_warn_maybe=$MAYBE_WARN
167 AC_MSG_CHECKING([which warning flags were supported])])
168 WARN_CFLAGS="$libdrm_cv_warn_cflags"
170 if test "x$UDEV" = xyes; then
171 AC_DEFINE(UDEV, 1, [Have UDEV support])
172 fi
174 AC_CANONICAL_HOST
175 if test "x$LIBKMS" = xauto ; then
176 case $host_os in
177 linux*) LIBKMS="yes" ;;
178 *) LIBKMS="no" ;;
179 esac
180 fi
182 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
184 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
185 if test "x$VMWGFX" = xyes; then
186 AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
187 fi
189 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
190 if test "x$NOUVEAU" = xyes; then
191 AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
192 fi
194 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
195 if test "x$OMAP" = xyes; then
196 AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
197 fi
199 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
200 if test "x$EXYNOS" = xyes; then
201 AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
202 fi
204 AC_ARG_ENABLE([cairo-tests],
205 [AS_HELP_STRING([--enable-cairo-tests],
206 [Enable support for Cairo rendering in tests (default: auto)])],
207 [CAIRO=$enableval], [CAIRO=auto])
208 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
209 AC_MSG_CHECKING([whether to enable Cairo tests])
210 if test "x$CAIRO" = xauto; then
211 CAIRO="$HAVE_CAIRO"
212 fi
213 if test "x$CAIRO" = xyes; then
214 if ! test "x$HAVE_CAIRO" = xyes; then
215 AC_MSG_ERROR([Cairo support required but not present])
216 fi
217 AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
218 fi
219 AC_MSG_RESULT([$CAIRO])
220 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
222 # For enumerating devices in test case
223 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
224 if test "x$HAVE_LIBUDEV" = xyes; then
225 AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
226 fi
227 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
229 AC_PATH_PROG(XSLTPROC, xsltproc)
230 AM_CONDITIONAL([HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
232 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno" -o "x$NOUVEAU" != "xno" -o "x$OMAP" != "xno"; then
233 # Check for atomic intrinsics
234 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
235 [
236 drm_cv_atomic_primitives="none"
238 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
239 int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
240 int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
241 ]],[[]])],
242 [drm_cv_atomic_primitives="Intel"],[])
244 if test "x$drm_cv_atomic_primitives" = "xnone"; then
245 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
246 fi
248 # atomic functions defined in <atomic.h> & libc on Solaris
249 if test "x$drm_cv_atomic_primitives" = "xnone"; then
250 AC_CHECK_FUNC([atomic_cas_uint],
251 drm_cv_atomic_primitives="Solaris")
252 fi
254 ])
255 if test "x$drm_cv_atomic_primitives" = xIntel; then
256 AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
257 [Enable if your compiler supports the Intel __sync_* atomic primitives])
258 fi
259 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
260 AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
261 fi
263 if test "x$drm_cv_atomic_primitives" = "xnone"; then
264 if test "x$INTEL" != "xauto"; then
265 if test "x$INTEL" != "xno"; then
266 AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
267 fi
268 else
269 AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
270 INTEL=no
271 fi
272 if test "x$RADEON" != "xauto"; then
273 if test "x$RADEON" != "xno"; then
274 AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
275 fi
276 else
277 AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
278 RADEON=no
279 fi
280 if test "x$NOUVEAU" != "xauto"; then
281 if test "x$NOUVEAU" != "xno"; then
282 AC_MSG_ERROR([libdrm_nouveau depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for NVIDIA GPUs by passing --disable-nouveau to ./configure])
283 fi
284 else
285 AC_MSG_WARN([Disabling libdrm_nouveau. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
286 NOUVEAU=no
287 fi
288 else
289 if test "x$INTEL" != "xno"; then
290 case $host_cpu in
291 i?86|x86_64) INTEL=yes ;;
292 *) INTEL=no ;;
293 esac
294 fi
295 if test "x$RADEON" != "xno"; then
296 RADEON=yes
297 fi
298 if test "x$NOUVEAU" != "xno"; then
299 NOUVEAU=yes
300 fi
301 fi
302 fi
304 if test "x$INTEL" != "xno"; then
305 PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
306 fi
307 AC_SUBST(PCIACCESS_CFLAGS)
308 AC_SUBST(PCIACCESS_LIBS)
310 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
311 if test "x$have_valgrind" = "xyes"; then
312 AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
313 fi
315 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
316 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
317 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" != "xno"])
318 if test "x$RADEON" = xyes; then
319 AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
320 fi
322 AC_ARG_WITH([kernel-source],
323 [AS_HELP_STRING([--with-kernel-source],
324 [specify path to linux kernel source])],
325 [kernel_source="$with_kernel_source"])
326 AC_SUBST(kernel_source)
328 AC_SUBST(WARN_CFLAGS)
329 AC_CONFIG_FILES([
330 Makefile
331 libkms/Makefile
332 libkms/libkms.pc
333 intel/Makefile
334 intel/libdrm_intel.pc
335 radeon/Makefile
336 radeon/libdrm_radeon.pc
337 nouveau-1/Makefile
338 nouveau-1/libdrm_nouveau1.pc
339 nouveau/Makefile
340 nouveau/libdrm_nouveau.pc
341 omap/Makefile
342 omap/libdrm_omap.pc
343 exynos/Makefile
344 exynos/libdrm_exynos.pc
345 tests/Makefile
346 tests/modeprint/Makefile
347 tests/modetest/Makefile
348 tests/kmstest/Makefile
349 tests/radeon/Makefile
350 tests/vbltest/Makefile
351 include/Makefile
352 include/drm/Makefile
353 man/Makefile
354 libdrm.pc])
355 AC_OUTPUT
357 echo ""
358 echo "$PACKAGE_STRING will be compiled with:"
359 echo ""
360 echo " libkms $LIBKMS"
361 echo " Intel API $INTEL"
362 echo " vmwgfx API $VMWGFX"
363 echo " Radeon API $RADEON"
364 echo " Nouveau API $NOUVEAU"
365 echo " OMAP API $OMAP"
366 echo " EXYNOS API $EXYNOS"
367 echo ""