configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ(2.57)
  22 AC_INIT([libdrm], 2.4.3, [dri-devel@lists.sourceforge.net], libdrm)
  23 AC_CONFIG_SRCDIR([Makefile.am])
  24 AM_INIT_AUTOMAKE([dist-bzip2])
  25
  26 AM_CONFIG_HEADER([libdrm/config.h])
  27
  28 AC_DISABLE_STATIC
  29 AC_PROG_LIBTOOL
  30 AC_PROG_CC
  31
  32 AC_HEADER_STDC
  33 AC_SYS_LARGEFILE
  34
  35 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  36 AC_SUBST(PTHREADSTUBS_CFLAGS)
  37 AC_SUBST(PTHREADSTUBS_LIBS)
  38
  39 pkgconfigdir=${libdir}/pkgconfig
  40 AC_SUBST(pkgconfigdir)
  41 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
  42                                 [Enable support for using udev instead of mknod (default: disabled)]),
  43                                 [UDEV=$enableval], [UDEV=no])
  44
  45
  46 dnl ===========================================================================
  47 dnl check compiler flags
  48 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  49   AC_MSG_CHECKING([whether $CC supports $1])
  50
  51   libdrm_save_CFLAGS="$CFLAGS"
  52   CFLAGS="$CFLAGS $1"
  53
  54   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  55   CFLAGS="$libdrm_save_CFLAGS"
  56
  57   if test "x$libdrm_cc_flag" = "xyes"; then
  58     ifelse([$2], , :, [$2])
  59   else
  60     ifelse([$3], , :, [$3])
  61   fi
  62   AC_MSG_RESULT([$libdrm_cc_flag])
  63 ])
  64
  65 dnl Use lots of warning flags with with gcc and compatible compilers
  66
  67 dnl Note: if you change the following variable, the cache is automatically
  68 dnl skipped and all flags rechecked.  So there's no need to do anything
  69 dnl else.  If for any reason you need to force a recheck, just change
  70 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
  71
  72 MAYBE_WARN="-Wall -Wextra \
  73 -Wsign-compare -Werror-implicit-function-declaration \
  74 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
  75 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
  76 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
  77 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
  78 -Wdeclaration-after-statement -Wold-style-definition \
  79 -Wno-missing-field-initializers -Wno-unused-parameter \
  80 -Wno-attributes -Wno-long-long -Winline"
  81
  82 # invalidate cached value if MAYBE_WARN has changed
  83 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
  84         unset libdrm_cv_warn_cflags
  85 fi
  86 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
  87         echo
  88         WARN_CFLAGS=""
  89
  90         # Some warning options are not supported by all versions of
  91         # gcc, so test all desired options against the current
  92         # compiler.
  93         #
  94         # Note that there are some order dependencies
  95         # here. Specifically, an option that disables a warning will
  96         # have no net effect if a later option then enables that
  97         # warnings, (perhaps implicitly). So we put some grouped
  98         # options (-Wall and -Wextra) up front and the -Wno options
  99         # last.
 100
 101         for W in $MAYBE_WARN; do
 102                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 103         done
 104
 105         libdrm_cv_warn_cflags=$WARN_CFLAGS
 106         libdrm_cv_warn_maybe=$MAYBE_WARN
 107
 108         AC_MSG_CHECKING([which warning flags were supported])])
 109 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 110
 111 if test "x$UDEV" = xyes; then
 112         AC_DEFINE(UDEV, 1, [Have UDEV support])
 113 fi
 114
 115 AC_SUBST(WARN_CFLAGS)
 116 AC_OUTPUT([
 117         Makefile
 118         libdrm/Makefile
 119         libdrm/intel/Makefile
 120         libdrm/radeon/Makefile
 121         shared-core/Makefile
 122         tests/Makefile
 123         libdrm.pc])