1 # Copyright 2005 Adam Jackson.
2 #
3 # Permission is hereby granted, free of charge, to any person obtaining a
4 # copy of this software and associated documentation files (the "Software"),
5 # to deal in the Software without restriction, including without limitation
6 # on the rights to use, copy, modify, merge, publish, distribute, sub
7 # license, and/or sell copies of the Software, and to permit persons to whom
8 # the Software is furnished to do so, subject to the following conditions:
9 #
10 # The above copyright notice and this permission notice (including the next
11 # paragraph) shall be included in all copies or substantial portions of the
12 # Software.
13 #
14 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16 # FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT. IN NO EVENT SHALL
17 # ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18 # IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19 # CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
21 AC_PREREQ(2.60)
22 AC_INIT([libdrm], 2.4.20, [dri-devel@lists.sourceforge.net], libdrm)
23 AC_USE_SYSTEM_EXTENSIONS
24 AC_CONFIG_SRCDIR([Makefile.am])
25 AM_INIT_AUTOMAKE([dist-bzip2])
27 AM_CONFIG_HEADER([config.h])
29 AC_DISABLE_STATIC
30 AC_PROG_LIBTOOL
31 AC_PROG_CC
33 AC_HEADER_STDC
34 AC_SYS_LARGEFILE
35 AC_FUNC_ALLOCA
37 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
38 AC_SUBST(PTHREADSTUBS_CFLAGS)
39 AC_SUBST(PTHREADSTUBS_LIBS)
41 pkgconfigdir=${libdir}/pkgconfig
42 AC_SUBST(pkgconfigdir)
43 AC_ARG_ENABLE(udev, AS_HELP_STRING([--enable-udev],
44 [Enable support for using udev instead of mknod (default: disabled)]),
45 [UDEV=$enableval], [UDEV=no])
47 AC_ARG_ENABLE(libkms,
48 AS_HELP_STRING([--disable-libkms],
49 [Disable KMS mm abstraction library (default: auto)]),
50 [LIBKMS=$enableval], [LIBKMS=auto])
52 AC_ARG_ENABLE(intel,
53 AS_HELP_STRING([--disable-intel],
54 [Enable support for intel's KMS API (default: auto)]),
55 [INTEL=$enableval], [INTEL=auto])
57 AC_ARG_ENABLE(radeon,
58 AS_HELP_STRING([--disable-radeon],
59 [Enable support for radeon's KMS API (default: auto)]),
60 [RADEON=$enableval], [RADEON=auto])
62 AC_ARG_ENABLE(vmwgfx-experimental-api,
63 AS_HELP_STRING([--enable-vmwgfx-experimental-api],
64 [Install vmwgfx's experimental kernel API header (default: disabled)]),
65 [VMWGFX=$enableval], [VMWGFX=no])
67 AC_ARG_ENABLE(nouveau-experimental-api,
68 AS_HELP_STRING([--enable-nouveau-experimental-api],
69 [Enable support for nouveau's experimental API (default: disabled)]),
70 [NOUVEAU=$enableval], [NOUVEAU=no])
73 dnl ===========================================================================
74 dnl check compiler flags
75 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
76 AC_MSG_CHECKING([whether $CC supports $1])
78 libdrm_save_CFLAGS="$CFLAGS"
79 CFLAGS="$CFLAGS $1"
81 AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
82 CFLAGS="$libdrm_save_CFLAGS"
84 if test "x$libdrm_cc_flag" = "xyes"; then
85 ifelse([$2], , :, [$2])
86 else
87 ifelse([$3], , :, [$3])
88 fi
89 AC_MSG_RESULT([$libdrm_cc_flag])
90 ])
92 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
94 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
95 [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
96 [AC_MSG_ERROR([Couldn't find clock_gettime])])])
97 AC_SUBST([CLOCK_LIB])
99 dnl Use lots of warning flags with with gcc and compatible compilers
101 dnl Note: if you change the following variable, the cache is automatically
102 dnl skipped and all flags rechecked. So there's no need to do anything
103 dnl else. If for any reason you need to force a recheck, just change
104 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
106 MAYBE_WARN="-Wall -Wextra \
107 -Wsign-compare -Werror-implicit-function-declaration \
108 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
109 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
110 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
111 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
112 -Wdeclaration-after-statement -Wold-style-definition \
113 -Wno-missing-field-initializers -Wno-unused-parameter \
114 -Wno-attributes -Wno-long-long -Winline"
116 # invalidate cached value if MAYBE_WARN has changed
117 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
118 unset libdrm_cv_warn_cflags
119 fi
120 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
121 echo
122 WARN_CFLAGS=""
124 # Some warning options are not supported by all versions of
125 # gcc, so test all desired options against the current
126 # compiler.
127 #
128 # Note that there are some order dependencies
129 # here. Specifically, an option that disables a warning will
130 # have no net effect if a later option then enables that
131 # warnings, (perhaps implicitly). So we put some grouped
132 # options (-Wall and -Wextra) up front and the -Wno options
133 # last.
135 for W in $MAYBE_WARN; do
136 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
137 done
139 libdrm_cv_warn_cflags=$WARN_CFLAGS
140 libdrm_cv_warn_maybe=$MAYBE_WARN
142 AC_MSG_CHECKING([which warning flags were supported])])
143 WARN_CFLAGS="$libdrm_cv_warn_cflags"
145 if test "x$UDEV" = xyes; then
146 AC_DEFINE(UDEV, 1, [Have UDEV support])
147 fi
149 AC_CANONICAL_HOST
150 if test "x$LIBKMS" = xauto ; then
151 case $host_os in
152 linux*) LIBKMS="yes" ;;
153 *) LIBKMS="no" ;;
154 esac
155 fi
157 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
159 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
160 if test "x$VMWGFX" = xyes; then
161 AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
162 fi
164 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
165 if test "x$NOUVEAU" = xyes; then
166 AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
167 fi
169 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
170 if test "x$HAVE_CAIRO" = xyes; then
171 AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
172 fi
173 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
175 # For enumerating devices in test case
176 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
177 if test "x$HAVE_LIBUDEV" = xyes; then
178 AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
179 fi
180 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
182 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno"; then
183 # Check for atomic intrinsics
184 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
185 [
186 drm_cv_atomic_primitives="none"
188 AC_TRY_LINK([
189 int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
190 int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
191 ], [],
192 drm_cv_atomic_primitives="Intel"
193 )
195 if test "x$drm_cv_atomic_primitives" = "xnone"; then
196 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
197 fi
199 # atomic functions defined in <atomic.h> & libc on Solaris
200 if test "x$drm_cv_atomic_primitives" = "xnone"; then
201 AC_CHECK_FUNC([atomic_cas_uint],
202 drm_cv_atomic_primitives="Solaris")
203 fi
205 ])
206 if test "x$drm_cv_atomic_primitives" = xIntel; then
207 AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
208 [Enable if your compiler supports the Intel __sync_* atomic primitives])
209 fi
210 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
211 AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
212 fi
214 if test "x$drm_cv_atomic_primitives" = "xnone"; then
215 if test "x$INTEL" != "xauto"; then
216 if test "x$INTEL" != "xno"; then
217 AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
218 fi
219 else
220 AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
221 INTEL=no
222 fi
223 if test "x$RADEON" != "xauto"; then
224 if test "x$RADEON" != "xno"; then
225 AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
226 fi
227 else
228 AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
229 RADEON=no
230 fi
232 else
233 if test "x$INTEL" != "xno"; then
234 INTEL=yes
235 fi
236 if test "x$RADEON" != "xno"; then
237 RADEON=yes
238 fi
239 fi
240 fi
242 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
243 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
245 AC_ARG_WITH([kernel-source],
246 [AS_HELP_STRING([--with-kernel-source],
247 [specify path to linux kernel source])],
248 [kernel_source="$with_kernel_source"])
249 AC_SUBST(kernel_source)
251 AC_SUBST(WARN_CFLAGS)
252 AC_OUTPUT([
253 Makefile
254 libkms/Makefile
255 libkms/libkms.pc
256 intel/Makefile
257 intel/libdrm_intel.pc
258 radeon/Makefile
259 radeon/libdrm_radeon.pc
260 nouveau/Makefile
261 nouveau/libdrm_nouveau.pc
262 tests/Makefile
263 tests/modeprint/Makefile
264 tests/modetest/Makefile
265 tests/kmstest/Makefile
266 tests/vbltest/Makefile
267 include/Makefile
268 include/drm/Makefile
269 libdrm.pc])
271 echo ""
272 echo "$PACKAGE_STRING will be compiled with:"
273 echo ""
274 echo " libkms $LIBKMS"
275 echo " Intel API $INTEL"
276 echo " vmwgfx API $VMWGFX"
277 echo " Radeon API $RADEON"
278 echo " Nouveau API $NOUVEAU"
279 echo ""