recipes-bsp/powervr-drivers/omap3-sgx-modules_4.05.00.03.bb

   1 DESCRIPTION = "Kernel drivers for the PowerVR SGX chipset found in the omap3 SoCs"
   2 LICENSE = "GPLv2"
   3 LIC_FILES_CHKSUM = "file://COPYING;md5=21228a42e27d1d104b31a83f7c9da935"
   4
   5 TI_BIN_UNPK_CMDS="Y: qY:workdir:Y"
   6 require ../../recipes-ti/includes/ti-eula-unpack.inc
   7
   8 SGXPV = "4_05_00_03"
   9 BINFILE := "Graphics_SDK_setuplinux_${SGXPV}.bin"
  10
  11 inherit module
  12
  13 MACHINE_KERNEL_PR_append = "b"
  14 PR = "${MACHINE_KERNEL_PR}"
  15
  16 SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/gfxsdk/${SGXPV}/exports/Graphics_SDK_setuplinux_${SGXPV}.bin \
  17           "
  18 SRC_URI[md5sum] = "0e651eaa92bb91760f0b40a17697a7dc"
  19 SRC_URI[sha256sum] = "bfe764a8959556195545d6fff76f63a489642f345c105bbbc309a3f243c2dd0e"
  20 TI_BIN_UNPK_WDEXT="/Graphics_SDK_${SGXPV}"
  21 S = "${WORKDIR}${TI_BIN_UNPK_WDEXT}/GFX_Linux_KM"
  22
  23 PVRBUILD = "release"
  24 export KERNELDIR = "${STAGING_KERNEL_DIR}"
  25
  26 PACKAGE_STRIP = "no"
  27
  28 TI_PLATFORM_omap3 = "omap3630"
  29 TI_PLATFORM_ti814x = "ti81xx"
  30 TI_PLATFORM_ti816x = "ti81xx"
  31 TI_PLATFORM_ti33x = "ti335x"
  32
  33 MODULESLOCATION_omap3 = "dc_omapfb3_linux"
  34 MODULESLOCATION_ti814x = "dc_ti81xx_linux"
  35 MODULESLOCATION_ti816x = "dc_ti81xx_linux"
  36 MODULESLOCATION_ti33x = "dc_ti335x_linux"
  37
  38 MAKE_TARGETS = " BUILD=${PVRBUILD} TI_PLATFORM=${TI_PLATFORM}"
  39
  40 do_install() {
  41         mkdir -p ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/gpu/pvr
  42         cp ${S}/pvrsrvkm.ko \
  43            ${S}/services4/3rdparty/${MODULESLOCATION}/omaplfb.ko  \
  44            ${S}/services4/3rdparty/bufferclass_ti/bufferclass_ti.ko \
  45            ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/gpu/pvr
  46 }