recipes-bsp/powervr-drivers/omap3-sgx-modules_4.08.00.01.bb

   1 DESCRIPTION = "Kernel drivers for the PowerVR SGX chipset found in the omap3 SoCs"
   2 LICENSE = "GPLv2"
   3 LIC_FILES_CHKSUM = "file://COPYING;md5=ea5743acf520dd81ca172e69f818a3d4"
   4
   5 TI_BIN_UNPK_CMDS="Y: qY:workdir:Y"
   6 require ../../recipes-ti/includes/ti-eula-unpack.inc
   7
   8 SGXPV = "4_08_00_01"
   9 IMGPV = "1.9.2139099"
  10 BINFILE = "Graphics_SDK_setuplinux_${SGXPV}.bin"
  11
  12 inherit module
  13
  14 MACHINE_KERNEL_PR_append = "a"
  15 PR = "${MACHINE_KERNEL_PR}"
  16
  17 DEFAULT_PREFERENCE = "-1"
  18
  19 SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/gfxsdk/${SGXPV}/exports/${BINFILE}"
  20
  21 SRC_URI[md5sum] = "dd0d994a48ecc4293f272a1fddddf159"
  22 SRC_URI[sha256sum] = "fd721288c95314e0d676dd89462e1dec994e185cb608bcb8ac4a4b5809f9693a"
  23
  24 TI_BIN_UNPK_WDEXT="/Graphics_SDK_${SGXPV}"
  25 S = "${WORKDIR}${TI_BIN_UNPK_WDEXT}/GFX_Linux_KM"
  26
  27 PVRBUILD = "release"
  28 export KERNELDIR = "${STAGING_KERNEL_DIR}"
  29
  30 INHIBIT_PACKAGE_STRIP = "1"
  31
  32 TI_PLATFORM_omap3 = "omap3630"
  33 TI_PLATFORM_ti814x = "ti81xx"
  34 TI_PLATFORM_ti816x = "ti81xx"
  35 TI_PLATFORM_ti33x = "ti335x"
  36
  37 MODULESLOCATION_omap3 = "dc_omapfb3_linux"
  38 MODULESLOCATION_ti814x = "dc_ti81xx_linux"
  39 MODULESLOCATION_ti816x = "dc_ti81xx_linux"
  40 MODULESLOCATION_ti33x = "dc_ti335x_linux"
  41
  42 export SUPPORT_XORG ?= "${@base_contains('DISTRO_FEATURES', 'x11', '1', '0', d)}"
  43
  44 MAKE_TARGETS = " BUILD=${PVRBUILD} TI_PLATFORM=${TI_PLATFORM} SUPPORT_XORG=${SUPPORT_XORG}"
  45
  46 do_install() {
  47     mkdir -p ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/gpu/pvr
  48     cp  ${S}/pvrsrvkm.ko \
  49         ${S}/services4/3rdparty/${MODULESLOCATION}/omaplfb.ko  \
  50         ${S}/services4/3rdparty/bufferclass_ti/bufferclass_ti.ko \
  51         ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/gpu/pvr
  52
  53     if [ "${SUPPORT_XORG}" = "1" ]; then
  54         cp ${S}/services4/3rdparty/linux_drm/drm.ko ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/gpu/pvr
  55     fi
  56 }