recipes-bsp/ti/am33x-cm3_git.bb

   1 DESCRIPTION = "Cortex-M3 binary blob for suspend-resume"
   2
   3 LICENSE = "TI-BSD"
   4 LIC_FILES_CHKSUM = "file://License.txt;md5=858099c817e47ea63559fc6b67ae8d91"
   5
   6 PV = "04.06.00.10"
   7 PR = "r3"
   8
   9 # SRCREV corresponds to tag "AM335xPSP_04.06.00.10-rc1"
  10 SRCREV = "27ca4643e422245a95723de1df0247a00eada45b"
  11 BRANCH ?= "master"
  12
  13 INITSCRIPT_NAME = "am335x-pm-firmware-load"
  14 INITSCRIPT_PARAMS = "defaults 96"
  15
  16 inherit update-rc.d
  17
  18 UPDATERCPN = "${PN}-initscript"
  19
  20 RDEPENDS_${PN}-initscript = "am33x-cm3"
  21
  22 SRC_URI = "git://arago-project.org/git/projects/am33x-cm3.git;protocol=git;branch=${BRANCH} \
  23            file://init-am33x-cm3 \
  24           "
  25
  26 S = "${WORKDIR}/git"
  27
  28 do_compile() {
  29         make CC="${TARGET_CC}" CROSS_COMPILE="${TARGET_PREFIX}"
  30 }
  31
  32 do_install() {
  33         install -d ${D}${base_libdir}/firmware
  34         install -m 0644 bin/am335x-pm-firmware.bin ${D}${base_libdir}/firmware/
  35
  36         # Install the init script to load the PM firmware at boot
  37         install -d ${D}${sysconfdir}/init.d
  38         install -m 0755 ${WORKDIR}/init-am33x-cm3 ${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}
  39 }
  40
  41 PACKAGES =+ "${PN}-initscript"
  42
  43 FILES_${PN} += "${base_libdir}/firmware"
  44
  45 FILES_${PN}-initscript = "${sysconfdir}/*"