recipes-graphics/libgles/libgles-omap3.inc

   1 DESCRIPTION = "libGLES for the omap3"
   2 LICENSE = "proprietary-binary"
   3 # 'TSPA.txt' might not be the best file to md5sum
   4 LIC_FILES_CHKSUM = "file://TSPA.txt;md5=c0d5d9c1e38b41677144c4e24d6ddee1"
   5
   6 PR = "r26"
   7
   8 COMPATIBLE_MACHINE = "(omap3|ti816x|ti33x)"
   9
  10 DEPENDS = "virtual/libx11 libxau libxdmcp"
  11
  12 PROVIDES += "virtual/egl"
  13
  14 SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/gfxsdk/${SGXPV}/exports/OMAP35x_Graphics_SDK_setuplinux_${SGXPV}.bin \
  15                    file://cputype \
  16                    file://rc.pvr \
  17                    file://sample.desktop \
  18                    file://99-bufferclass.rules  \
  19 "
  20
  21 S = "${WORKDIR}/OMAP35x_Graphics_SDK_${SGXPV}"
  22
  23 # Logic to unpack installjammer file
  24 TI_BIN_UNPK_CMDS="Y: qY:workdir:Y"
  25 require ../../recipes-ti/includes/ti-eula-unpack.inc
  26
  27 BINLOCATION ?= "${S}/gfx_rel"
  28 ES2LOCATION ?= "${S}/gfx_rel_es2.x"
  29 ES3LOCATION ?= "${S}/gfx_rel_es3.x"
  30 ES5LOCATION ?= "${S}/gfx_rel_es5.x"
  31 ES6LOCATION ?= "${S}/gfx_rel_es6.x"
  32 ES8LOCATION ?= "${S}/gfx_rel_es8.x"
  33
  34 do_configure() {
  35         # Attempt to fix up the worst offenders for file permissions
  36         for i in $(find ${S} -name "*.h") $(find ${S} -name "*.c") $(find ${S} -name "Make*") ; do
  37                 chmod 0644 $i
  38         done
  39
  40         # Attempt to create proper library softlinks
  41         for sofile in $(find ${S} -name "lib*Open*.so") $(find ${S} -name "lib*srv*.so") $(find ${S} -name "lib*gl*.so") $(find ${S} -name "libpvr*.so") $(find ${S} -name "lib*GL*.so"); do
  42                 if [ "$(readlink -n ${sofile})" = "" ] ; then
  43                         mv $sofile ${sofile}.${IMGPV}
  44                         ln -sf $(basename ${sofile}.${IMGPV}) ${sofile}
  45                         ln -sf $(basename ${sofile}.${IMGPV}) ${sofile}$(echo ${IMGPV} | awk -F. '{print "." $1}')
  46                         ln -sf $(basename ${sofile}.${IMGPV}) ${sofile}$(echo ${IMGPV} | awk -F. '{print "." $1 "." $2}')
  47                 fi
  48         done
  49
  50         # Due to recursive make PLAT_* isn't always passed down correctly, so use sed to fix those
  51         for mak in $(find ${S} -name "*.mak") ; do
  52                 sed -i -e s:arm-none-linux-gnueabi-:${TARGET_PREFIX}:g $mak
  53         done
  54
  55         # clear out old stuff
  56         find Binaries/ | xargs rm -f || true
  57 }
  58
  59 # Force in GNU_HASH and paths to libs
  60 TARGET_CC_ARCH += " ${TARGET_LINK_HASH_STYLE} -Wl,-rpath-link,${BINLOCATION} -L${BINLOCATION} \
  61 -L${STAGING_DIR_TARGET}${libdir} -Wl,-rpath-link,${STAGING_DIR_TARGET}${libdir}"
  62 PARALLEL_MAKE = ""
  63
  64 do_compile() {
  65         export X11ROOT="${STAGING_DIR_HOST}/usr"
  66         export TOOLCHAIN="${TOOLCHAIN_PATH}"
  67         export PLATFORM="LinuxOMAP3"
  68
  69         export PLAT_CC="${CC}"
  70         export PLAT_CPP="${CXX}"
  71         export PLAR_AR="${AR}"
  72
  73         mkdir -p ${S}/demos/raw
  74         mkdir -p ${S}/demos/x11
  75
  76         # Rebuild demos for both Raw and X11
  77         for X11BUILD in 0 1 ; do
  78                 for demo in ${S}/GFX_Linux_SDK/OGLES/SDKPackage/Demos/* ; do
  79                         cd $demo/OGLES/Build/LinuxGeneric
  80                         oe_runmake Common=1 PLATFORM=$PLATFORM X11BUILD=$X11BUILD
  81                         rm $demo/OGLES/Build/LinuxOMAP3/Release*/*.o
  82                         install -m 0755 $demo/OGLES/Build/LinuxOMAP3/ReleaseX11/* ${S}/demos/x11 || true
  83                         sed -e s:NAME:$(basename $demo): \
  84                             -e s:EXEC:${bindir}/SGX/demos/X11/$(basename $demo/OGLES/Build/LinuxOMAP3/ReleaseX11/*): \
  85                              ${WORKDIR}/sample.desktop > ${WORKDIR}/$(basename $demo).desktop
  86                         install -m 0755 $demo/OGLES/Build/LinuxOMAP3/ReleaseRaw/* ${S}/demos/raw || true
  87                 done
  88                 for demo in ${S}/GFX_Linux_SDK/OGLES2/SDKPackage/Demos/* ; do
  89                         cd $demo/OGLES2/Build/LinuxGeneric
  90                         oe_runmake Common=1 PLATFORM=$PLATFORM X11BUILD=$X11BUILD
  91                         rm -f $demo/OGLES2/Build/LinuxOMAP3/Release*/*.o
  92                         install -m 0755 $demo/OGLES2/Build/LinuxOMAP3/ReleaseX11/* ${S}/demos/x11 || true
  93                         sed -e s:NAME:$(basename $demo): \
  94                             -e s:EXEC:${bindir}/SGX/demos/X11/$(basename $demo/OGLES2/Build/LinuxOMAP3/ReleaseX11/*): \
  95                              ${WORKDIR}/sample.desktop > ${WORKDIR}/$(basename $demo).desktop
  96                         install -m 0755 $demo/OGLES2/Build/LinuxOMAP3/ReleaseRaw/* ${S}/demos/raw || true
  97                 done
  98         done
  99
 100         mkdir -p ${S}/trainingcourses/raw
 101         mkdir -p ${S}/trainingcourses/x11
 102
 103         find ${S} -name "*_org" -delete
 104
 105         # Build OGLES2 Trainingcourses for both Raw and X11
 106         for X11BUILD in 0 1 ; do
 107                 for training in ${S}/GFX_Linux_SDK/OGLES2/SDKPackage/TrainingCourse/* ; do
 108                         if [ -e $training/OGLES2/Build/LinuxGeneric/Makefile ] ; then
 109                                 cd $training/OGLES2/Build/LinuxGeneric
 110                         fi
 111
 112                         if [ -e $training/OGLES2/Build/LinuxOMAP3/Makefile ] ; then
 113                                 cd $training/OGLES2/Build/LinuxOMAP3
 114                         fi
 115
 116                         oe_runmake Common=1 PLATFORM=$PLATFORM X11BUILD=$X11BUILD
 117                         rm -f $training/OGLES2/Build/LinuxOMAP3/Release*/*.o
 118                         install -m 0755 $training/OGLES2/Build/LinuxOMAP3/ReleaseX11/* ${S}/trainingcourses/x11 || true
 119                         install -m 0755 $training/OGLES2/Build/LinuxOMAP3/ReleaseRaw/* ${S}/trainingcourses/raw || true
 120                 done
 121         done
 122
 123 }
 124
 125 do_install () {
 126         install -d ${D}${libdir}
 127         cp -pPR ${BINLOCATION}/*.so* ${D}${libdir}
 128         install -m 0644 ${BINLOCATION}/*.a ${D}${libdir}
 129
 130         install -d ${D}${bindir}/
 131         install -m 0755 ${WORKDIR}/cputype ${D}${bindir}/
 132
 133         install -m 0755 ${BINLOCATION}/*_test ${D}${bindir}/
 134         install -m 0755 ${BINLOCATION}/gl* ${D}${bindir}/
 135         install -m 0755 ${BINLOCATION}/p[dv]* ${D}${bindir}/
 136         install -m 0755 ${BINLOCATION}/xgles1test1 ${D}${bindir}/
 137
 138         install -m 0755 ${BINLOCATION}/freedesktop/kdrive/usr/X11R6_SGX/bin/Xsgx ${D}${bindir}/|| true
 139         cp -pPR ${S}/GFX_Linux_SDK/OGLES2/SDKPackage/Builds/OGLES2/LinuxOMAP3/lib/*X11WS* ${D}${libdir} || true
 140
 141         install -d ${D}${includedir}
 142         cp -pPR ${S}/GFX_Linux_KM/include4 ${D}${includedir}/
 143         cp -pPR ${S}/GFX_Linux_KM/services4 ${D}${includedir}/
 144
 145         cp -pPR ${S}/GFX_Linux_SDK/OGLES2/SDKPackage/Builds/OGLES2/Include/* ${D}${includedir}/
 146         cp -pPR ${S}/GFX_Linux_SDK/OGLES/SDKPackage/Builds/OGLES/Include/* ${D}${includedir}/
 147         cp -pPR ${S}/GFX_Linux_SDK/OGLES/SDKPackage/Builds/OGLES/LinuxOMAP3/Include/GLES/* ${D}${includedir}/GLES/ || true
 148         cp -pPr ${S}/GFX_Linux_SDK/OGLES2/SDKPackage/Builds/OGLES2/LinuxOMAP3/Include/GLES/* ${D}${includedir}/GLES2/ || true
 149         cp -pPr ${S}/GFX_Linux_SDK/OVG/SDKPackage/Builds/OVG/Include/v* ${D}${includedir}/ || true
 150         cp -pPr ${S}/GFX_Linux_SDK/OVG/SDKPackage/Builds/OVG/Include/V* ${D}${includedir}/ || true
 151         cp -pPr ${S}/include/*.h ${D}${includedir} || true
 152         cp -pPr ${S}/include/wsegl/*.h ${D}${includedir} || true
 153
 154         install -d ${D}${sysconfdir}/init.d/
 155         cp -pP ${WORKDIR}/rc.pvr ${D}${sysconfdir}/init.d/pvr-init
 156
 157         install -d ${D}${sysconfdir}
 158         echo "[default]" > ${D}${sysconfdir}/powervr.ini
 159         echo "WindowSystem=libpvrPVR2D_FRONTWSEGL.so.1" >> ${D}${sysconfdir}/powervr.ini
 160
 161         # The ES2.x, ES3.x, ES5.x and ES6.x CPUs have different SGX hardware, so we need to install multiple sets of userspace
 162
 163         install -d ${D}${libdir}/ES8.0
 164         install -d ${D}${libdir}/ES6.0
 165         install -d ${D}${libdir}/ES5.0
 166         install -d ${D}${libdir}/ES3.0
 167         install -d ${D}${libdir}/ES2.0
 168
 169         install -d ${D}${bindir}/ES8.0
 170         install -d ${D}${bindir}/ES6.0
 171         install -d ${D}${bindir}/ES5.0
 172         install -d ${D}${bindir}/ES3.0
 173         install -d ${D}${bindir}/ES2.0
 174
 175
 176         if [ -e ${ES2LOCATION} ] ; then
 177                 cp -pPR ${ES2LOCATION}/lib*${IMGPV} ${D}${libdir}/ES2.0/
 178                 cp ${ES2LOCATION}/p[dv]* ${D}${bindir}/ES2.0/
 179         fi
 180
 181         if [ -e ${ES3LOCATION} ] ; then
 182                 cp -pPR ${ES3LOCATION}/lib*${IMGPV} ${D}${libdir}/ES3.0/
 183                 cp ${ES3LOCATION}/p[dv]* ${D}${bindir}/ES3.0
 184         fi
 185
 186         if [ -e ${ES5LOCATION} ] ; then
 187                 cp -pPR ${ES5LOCATION}/lib*${IMGPV} ${D}${libdir}/ES5.0/
 188                 cp ${ES5LOCATION}/p[dv]* ${D}${bindir}/ES5.0/
 189         fi
 190
 191         if [ -e ${ES6LOCATION} ] ; then
 192                 cp -pPR ${ES6LOCATION}/lib*${IMGPV} ${D}${libdir}/ES6.0/
 193                 cp ${ES6LOCATION}/p[dv]* ${D}${bindir}/ES6.0/
 194         fi
 195
 196         if [ -e ${ES8LOCATION} ] ; then
 197                 cp -pPR ${ES8LOCATION}/lib*${IMGPV} ${D}${libdir}/ES8.0/
 198                 cp ${ES8LOCATION}/p[dv]* ${D}${bindir}/ES8.0/
 199         fi
 200
 201         rm ${D}${bindir}/ES*/*.h ${D}${bindir}/ES*/pdsasm ${D}${bindir}/pdsasm -f || true
 202
 203         install -d ${D}${prefix}/share/applications
 204         cp ${WORKDIR}/*.desktop ${D}${prefix}/share/applications
 205         rm ${D}${prefix}/share/applications/sample.desktop
 206
 207         install -d ${D}${bindir}/SGX/demos/X11/
 208         install -d ${D}${bindir}/SGX/demos/Raw/
 209         install -m 0755 ${S}/demos/x11/* ${D}${bindir}/SGX/demos/X11/
 210         install -m 0755 ${S}/demos/raw/* ${D}${bindir}/SGX/demos/Raw/
 211
 212         install -d ${D}${bindir}/SGX/trainingcourses/Raw
 213         install -d ${D}${bindir}/SGX/trainingcourses/X11
 214         install -m 0755 ${S}/trainingcourses/x11/* ${D}${bindir}/SGX/trainingcourses/X11/
 215         install -m 0755 ${S}/trainingcourses/raw/* ${D}${bindir}/SGX/trainingcourses/Raw/
 216
 217         # Delete objects and linker scripts hidden between the headers
 218         find ${D} -name "*.o" -delete
 219         find ${D} -name "*.o.cmd" -delete
 220
 221         install -d ${D}${sysconfdir}/udev/rules.d
 222         install -m 0644 ${WORKDIR}/99-bufferclass.rules ${D}${sysconfdir}/udev/rules.d/
 223
 224 }
 225
 226 PACKAGES =+ "${PN}-rawdemos \
 227              ${PN}-x11demos \
 228              ${PN}-rawtrainingcourses \
 229              ${PN}-x11trainingcourses \
 230 "
 231
 232 PACKAGES += "xserver-kdrive-powervrsgx \
 233              ${PN}-tests "
 234
 235 # Package the base libraries per silicon revision
 236 PACKAGES =+ "${PN}-es2 ${PN}-es3 ${PN}-es5 ${PN}-es6 ${PN}-es8"
 237 RRECOMMENDS_${PN} += "${PN}-es2 ${PN}-es3 ${PN}-es5 ${PN}-es6 ${PN}-es8"
 238 FILES_${PN}-es2 = "${libdir}/ES2*/* ${bindir}/ES2*/*"
 239 FILES_${PN}-es3 = "${libdir}/ES3*/* ${bindir}/ES3*/*"
 240 FILES_${PN}-es5 = "${libdir}/ES5*/* ${bindir}/ES5*/*"
 241 FILES_${PN}-es6 = "${libdir}/ES6*/* ${bindir}/ES6*/*"
 242 FILES_${PN}-es8 = "${libdir}/ES8*/* ${bindir}/ES8*/*"
 243
 244 # Stop shlib code from picking a subpackage
 245 PRIVATE_LIBS_${PN}-es2 = "libGLESv2.so libIMGegl.so libsrv_um.so libOpenVG.so libpvr2d.so libsrv_init.so libEGL.so libsrv_um_dri.so libOpenVGU.so libglslcompiler.so libGLES_CM.so"
 246 PRIVATE_LIBS_${PN}-es3 = "libGLESv2.so libIMGegl.so libsrv_um.so libOpenVG.so libpvr2d.so libsrv_init.so libEGL.so libsrv_um_dri.so libOpenVGU.so libglslcompiler.so libGLES_CM.so"
 247 PRIVATE_LIBS_${PN}-es5 = "libGLESv2.so libIMGegl.so libsrv_um.so libOpenVG.so libpvr2d.so libsrv_init.so libEGL.so libsrv_um_dri.so libOpenVGU.so libglslcompiler.so libGLES_CM.so"
 248 PRIVATE_LIBS_${PN}-es6 = "libGLESv2.so libIMGegl.so libsrv_um.so libOpenVG.so libpvr2d.so libsrv_init.so libEGL.so libsrv_um_dri.so libOpenVGU.so libglslcompiler.so libGLES_CM.so"
 249 PRIVATE_LIBS_${PN}-es8 = "libGLESv2.so libIMGegl.so libsrv_um.so libOpenVG.so libpvr2d.so libsrv_init.so libEGL.so libsrv_um_dri.so libOpenVGU.so libglslcompiler.so libGLES_CM.so"
 250
 251 PACKAGES =+ "${PN}-blitwsegl ${PN}-flipwsegl ${PN}-frontwsegl ${PN}-linuxfbwsegl ${PN}-x11wsegl ${PN}-driwsegl"
 252 FILES_${PN}-blitwsegl = "${libdir}/libpvrPVR2D_BLITWSEGL.so.*"
 253 FILES_${PN}-flipwsegl = "${libdir}/libpvrPVR2D_FLIPWSEGL.so.*"
 254 FILES_${PN}-frontwsegl = "${libdir}/libpvrPVR2D_FRONTWSEGL.so.*"
 255 FILES_${PN}-linuxfbwsegl = "${libdir}/libpvrPVR2D_LINUXFBWSEGL.so.*"
 256 FILES_${PN}-x11wsegl = "${libdir}/libpvrPVR2D_X11WSEGL.so*"
 257 FILES_${PN}-driwsegl = "${libdir}/libpvrPVR2D_DRIWSEGL.so*"
 258
 259 PACKAGES =+ "${PN}-blitwsegl-es2 ${PN}-blitwsegl-es3 ${PN}-blitwsegl-es5 ${PN}-blitwsegl-es6 ${PN}-blitwsegl-es8 ${PN}-flipwsegl-es2 ${PN}-flipwsegl-es3 ${PN}-flipwsegl-es5 ${PN}-flipwsegl-es6 ${PN}-flipwsegl-es8 ${PN}-frontwsegl-es2 ${PN}-frontwsegl-es3 ${PN}-frontwsegl-es5 ${PN}-frontwsegl-es6 ${PN}-frontwsegl-es8 ${PN}-linuxfbwsegl-es2 ${PN}-linuxfbwsegl-es3 ${PN}-linuxfbwsegl-es5 ${PN}-linuxfbwsegl-es6 ${PN}-linuxfbwsegl-es8 ${PN}-x11wsegl-es2 ${PN}-x11wsegl-es3 ${PN}-x11wsegl-es5 ${PN}-x11wsegl-es6 ${PN}-x11wsegl-es8 ${PN}-driwsegl-es2 ${PN}-driwsegl-es3 ${PN}-driwsegl-es5 ${PN}-driwsegl-es6 ${PN}-driwsegl-es8"
 260 FILES_${PN}-blitwsegl-es2 = "${libdir}/ES2*/libpvrPVR2D_BLITWSEGL.so.*"
 261 FILES_${PN}-blitwsegl-es3 = "${libdir}/ES3*/libpvrPVR2D_BLITWSEGL.so.*"
 262 FILES_${PN}-blitwsegl-es5 = "${libdir}/ES5*/libpvrPVR2D_BLITWSEGL.so.*"
 263 FILES_${PN}-blitwsegl-es6 = "${libdir}/ES6*/libpvrPVR2D_BLITWSEGL.so.*"
 264 FILES_${PN}-blitwsegl-es8 = "${libdir}/ES8*/libpvrPVR2D_BLITWSEGL.so.*"
 265 RRECOMMENDS_${PN}-blitwsegl = " ${PN}-blitwsegl-es2 ${PN}-blitwsegl-es3 ${PN}-blitwsegl-es5 ${PN}-blitwsegl-es6 ${PN}-blitwsegl-es8"
 266
 267 FILES_${PN}-flipwsegl-es2 = "${libdir}/ES2*/libpvrPVR2D_FLIPWSEGL.so.*"
 268 FILES_${PN}-flipwsegl-es3 = "${libdir}/ES3*/libpvrPVR2D_FLIPWSEGL.so.*"
 269 FILES_${PN}-flipwsegl-es5 = "${libdir}/ES5*/libpvrPVR2D_FLIPWSEGL.so.*"
 270 FILES_${PN}-flipwsegl-es6 = "${libdir}/ES6*/libpvrPVR2D_FLIPWSEGL.so.*"
 271 FILES_${PN}-flipwsegl-es8 = "${libdir}/ES8*/libpvrPVR2D_FLIPWSEGL.so.*"
 272 RRECOMMENDS_${PN}-flipwsegl = " ${PN}-flipwsegl-es2 ${PN}-flipwsegl-es3 ${PN}-flipwsegl-es5 ${PN}-flipwsegl-es6 ${PN}-flipwsegl-es8"
 273
 274 FILES_${PN}-frontwsegl-es2 = "${libdir}/ES2*/libpvrPVR2D_FRONTWSEGL.so.*"
 275 FILES_${PN}-frontwsegl-es3 = "${libdir}/ES3*/libpvrPVR2D_FRONTWSEGL.so.*"
 276 FILES_${PN}-frontwsegl-es5 = "${libdir}/ES5*/libpvrPVR2D_FRONTWSEGL.so.*"
 277 FILES_${PN}-frontwsegl-es6 = "${libdir}/ES6*/libpvrPVR2D_FRONTWSEGL.so.*"
 278 FILES_${PN}-frontwsegl-es8 = "${libdir}/ES8*/libpvrPVR2D_FRONTWSEGL.so.*"
 279 RRECOMMENDS_${PN}-frontwsegl = " ${PN}-frontwsegl-es2 ${PN}-frontwsegl-es3 ${PN}-frontwsegl-es5 ${PN}-frontwsegl-es6 ${PN}-frontwsegl-es8"
 280
 281 FILES_${PN}-linuxfbwsegl-es2 = "${libdir}/ES2*/libpvrPVR2D_LINUXFBWSEGL.so.*"
 282 FILES_${PN}-linuxfbwsegl-es3 = "${libdir}/ES3*/libpvrPVR2D_LINUXFBWSEGL.so.*"
 283 FILES_${PN}-linuxfbwsegl-es5 = "${libdir}/ES5*/libpvrPVR2D_LINUXFBWSEGL.so.*"
 284 FILES_${PN}-linuxfbwsegl-es6 = "${libdir}/ES6*/libpvrPVR2D_LINUXFBWSEGL.so.*"
 285 FILES_${PN}-linuxfbwsegl-es8 = "${libdir}/ES8*/libpvrPVR2D_LINUXFBWSEGL.so.*"
 286 RRECOMMENDS_${PN}-linuxfbwsegl = " ${PN}-linuxfbwsegl-es2 ${PN}-linuxfbwsegl-es3 ${PN}-linuxfbwsegl-es5 ${PN}-linuxfbwsegl-es6 ${PN}-linuxfbwsegl-es8"
 287
 288 FILES_${PN}-x11wsegl-es2 = "${libdir}/ES2*/libpvrPVR2D_X11WSEGL.so.*"
 289 FILES_${PN}-x11wsegl-es3 = "${libdir}/ES3*/libpvrPVR2D_X11WSEGL.so.*"
 290 FILES_${PN}-x11wsegl-es5 = "${libdir}/ES5*/libpvrPVR2D_X11WSEGL.so.*"
 291 FILES_${PN}-x11wsegl-es6 = "${libdir}/ES6*/libpvrPVR2D_X11WSEGL.so.*"
 292 FILES_${PN}-x11wsegl-es8 = "${libdir}/ES8*/libpvrPVR2D_X11WSEGL.so.*"
 293 RRECOMMENDS_${PN}-x11wsegl = " ${PN}-x11wsegl-es2 ${PN}-x11wsegl-es3 ${PN}-x11wsegl-es5 ${PN}-x11wsegl-es6 ${PN}-x11wsegl-es8"
 294
 295 FILES_${PN}-driwsegl-es2 = "${libdir}/ES2*/libpvrPVR2D_DRIWSEGL.so.*"
 296 FILES_${PN}-driwsegl-es3 = "${libdir}/ES3*/libpvrPVR2D_DRIWSEGL.so.*"
 297 FILES_${PN}-driwsegl-es5 = "${libdir}/ES5*/libpvrPVR2D_DRIWSEGL.so.*"
 298 FILES_${PN}-driwsegl-es6 = "${libdir}/ES6*/libpvrPVR2D_DRIWSEGL.so.*"
 299 FILES_${PN}-driwsegl-es8 = "${libdir}/ES8*/libpvrPVR2D_DRIWSEGL.so.*"
 300 RRECOMMENDS_${PN}-driwsegl = " ${PN}-driwsegl-es2 ${PN}-driwsegl-es3 ${PN}-driwsegl-es5 ${PN}-driwsegl-es6 ${PN}-driwsegl-es8"
 301
 302 CONFFILES_${PN} = "${sysconfdir}/powervr.ini"
 303
 304 FILES_${PN} = "${sysconfdir} ${libdir}/lib*.so.* ${libdir}/ES*/* ${bindir}/pvrsrvinit ${bindir}/cputype ${bindir}/*/*"
 305
 306 FILES_xserver-kdrive-powervrsgx = "${bindir}/Xsgx"
 307 FILES_${PN}-tests = "${bindir}/*"
 308 FILES_${PN}-dbg = "${libdir}/.debug/* ${bindir}/.debug/* \
 309                    ${libdir}/ES*/.debug ${bindir}/*/.debug\
 310                    ${bindir}/SGX/demos/*/.debug/* \
 311                    ${bindir}/SGX/trainingcourses/*/.debug/* \
 312         "
 313
 314 FILES_${PN}-rawdemos = "${bindir}/SGX/demos/Raw/*"
 315 FILES_${PN}-x11demos = "${bindir}/SGX/demos/X11/* ${prefix}/share/applications "
 316 RRECOMMENDS_${PN}-x11demos = "${PN}-x11wsegl"
 317
 318 FILES_${PN}-rawtrainingcourses = "${bindir}/SGX/trainingcourses/Raw/*"
 319 FILES_${PN}-x11trainingcourses = "${bindir}/SGX/trainingcourses/X11/*"
 320 RRECOMMENDS_${PN}-x11trainingcourses = "${PN}-x11wsegl"
 321
 322 # The libs need the kernel-modules
 323 RRECOMMENDS_${PN} += "omap3-sgx-modules"
 324
 325 # The initscript calls fbset, cputype calls devmem2
 326 RDEPENDS_${PN} += "fbset devmem2"
 327
 328 #HACK! These are binaries, so we can't guarantee that LDFLAGS match :(
 329 INSANE_SKIP_${PN} = "ldflags dev-so"
 330 INSANE_SKIP_${PN}-blitwsegl = "ldflags"
 331 INSANE_SKIP_${PN}-flipwsegl = "ldflags"
 332 INSANE_SKIP_${PN}-frontwsegl = "ldflags"
 333 INSANE_SKIP_${PN}-linuxfbwsegl = "ldflags"
 334 INSANE_SKIP_${PN}-x11wsegl = "ldflags dev-so"
 335 INSANE_SKIP_${PN}-driwsegl = "ldflags dev-so"
 336 INSANE_SKIP_${PN}-tests = "ldflags"
 337 INSANE_SKIP_xserver-kdrive-powervrsgx = "ldflags"
 338
 339 # Quality control is really poor on these SDKs, so hack around the latest madness:
 340 FILES_${PN} += "${libdir}/*.so "
 341 FILES_${PN}-dev = "${includedir}"
 342
 343 inherit update-rc.d
 344
 345 INITSCRIPT_NAME = "pvr-init"
 346 INITSCRIPT_PARAMS = "start 30 5 2 . stop 40 0 1 6 ."
 347
 348 # Append to update-rc.d postinst
 349 pkg_postinst_${PN}_append() {
 350 rm -f $D${sysconfdir}/powervr-esrev
 351
 352 ln -sf /usr/lib/libXdmcp.so.6.0.0 /usr/lib/libXdmcp.so.0
 353 ln -sf /usr/lib/libXau.so.6.0.0 /usr/lib/libXau.so.0
 354 }
 355
 356 pkg_postinst_${PN}-blitwsegl() {
 357 rm -f $D${sysconfdir}/powervr-esrev
 358 }
 359
 360 pkg_postinst_${PN}-flipwsegl() {
 361 rm -f $D${sysconfdir}/powervr-esrev
 362 }
 363
 364 pkg_postinst_${PN}-frontwsegl() {
 365 rm -f $D${sysconfdir}/powervr-esrev
 366 }
 367 pkg_postinst_${PN}-linuxfbwsegl() {
 368 rm -f $D${sysconfdir}/powervr-esrev
 369 }
 370
 371 pkg_postinst_${PN}-x11wsegl() {
 372 rm -f $D${sysconfdir}/powervr-esrev
 373
 374 echo "[default]" > $D${sysconfdir}/powervr.ini
 375 echo "WindowSystem=libpvrPVR2D_X11WSEGL.so.1" >> $D${sysconfdir}/powervr.ini
 376 }
 377
 378 pkg_postinst_${PN}-driwsegl() {
 379 rm -f $D${sysconfdir}/powervr-esrev
 380 }
 381