1 SECTION = "kernel"
2 DESCRIPTION = "Linux kernel for TI33x devices from PSP"
3 LICENSE = "GPLv2"
4 LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
5 COMPATIBLE_MACHINE = "ti33x"
7 DEFAULT_PREFERENCE = "-1"
9 inherit kernel
10 require setup-defconfig.inc
12 # Stage the power management firmware before building the kernel
13 DEPENDS += "am33x-cm3"
15 KERNEL_IMAGETYPE = "uImage"
17 # The main PR is now using MACHINE_KERNEL_PR, for ti33x see conf/machine/include/ti33x.inc
18 MACHINE_KERNEL_PR_append = "c+gitr${SRCPV}"
20 BRANCH = "v3.2-staging"
22 # SRCREV corresponds to the commit id of tag v3.2_AM335xPSP_04.06.00.10-rc3
23 SRCREV = "18ce4a630452348b8308b922491130e8ce1e9134"
25 SRC_URI = "git://arago-project.org/git/projects/linux-am33x.git;protocol=git;branch=${BRANCH} \
26 file://defconfig \
27 ${KERNEL_PATCHES} \
28 "
30 S = "${WORKDIR}/git"
32 # Allow a layer to easily add to the list of patches or completely override them
33 KERNEL_PATCHES = "${PATCHES}"
35 # Add a set of patches that enabled features, fixed bugs or disabled buggy features
36 # that weren't part of the official PSP release
37 PATCHES = "file://0001-musb-update-PIO-mode-help-information-in-Kconfig.patch \
38 file://0001-am335x_evm_defconfig-turn-off-MUSB-DMA.patch \
39 file://0001-mach-omap2-pm33xx-Disable-VT-switch.patch"
41 # Add Cryptography support early driver patches while working to get the driver
42 # upstream.
43 PATCHES += "file://0001-am33x-Add-memory-addresses-for-crypto-modules.patch \
44 file://0002-am33x-Add-crypto-device-and-resource-structures.patch \
45 file://0003-am33x-Add-crypto-device-and-resource-structure-for-T.patch \
46 file://0004-am33x-Add-crypto-drivers-to-Kconfig-and-Makefiles.patch \
47 file://0005-am33x-Create-header-file-for-OMAP4-crypto-modules.patch \
48 file://0006-am33x-Create-driver-for-TRNG-crypto-module.patch \
49 file://0007-am33x-Create-driver-for-AES-crypto-module.patch \
50 file://0008-am33x-Create-driver-for-SHA-MD5-crypto-module.patch \
51 file://0002-AM335x-OCF-Driver-for-Linux-3.patch \
52 file://0001-am335x-Add-crypto-driver-settings-to-defconfig.patch \
53 file://0001-am335x-Add-pm_runtime-API-to-crypto-driver.patch \
54 file://0002-am335x-Add-suspend-resume-routines-to-crypto-driver.patch \
55 file://0001-ARM-AM33xx-hwmod-Convert-SHA0-crypto-device-data-to-.patch \
56 file://0002-crypto-omap4-sham-Use-finer-grained-PM-management.patch \
57 file://0003-crypto-omap4-sham-Add-suspend-resume-PM-support.patch \
58 file://0004-crypto-omap4-sham-Don-t-use-hardcoded-base-address.patch \
59 file://0005-ARM-AM33xx-hwmod-Convert-AES0-crypto-device-data-to-.patch \
60 file://0006-crypto-omap4-aes-User-finer-grained-PM-management.patch \
61 file://0007-crypto-omap4-aes-Add-suspend-resume-PM-support.patch \
62 file://0008-crypto-omap4-aes-Don-t-use-hardcoded-base-address.patch \
63 file://0009-ARM-AM33xx-hwmod-Convert-RNG-device-data-to-hwmod.patch \
64 file://0010-hwrng-omap4-rng-Convert-to-use-pm_runtime-API.patch \
65 file://0001-omap4-rng-Remove-check-for-GP-only-device-type-in-RN.patch \
66 "
68 # Add SmartReflex support early driver patches while working to get the driver
69 # upstream.
70 PATCHES += "file://0001-am33xx-Add-SmartReflex-support.patch \
71 file://0002-am33xx-Enable-CONFIG_AM33XX_SMARTREFLEX.patch \
72 file://0002-Smartreflex-limited-to-ES-1.0.patch \
73 "
75 # Add a patch to the omap-serial driver to allow suspend/resume during
76 # Bluetooth traffic
77 PATCHES += "file://0001-omap-serial-add-delay-before-suspending.patch"
79 # Add patch to allow wireless to work properly on EVM-SK 1.2.
80 PATCHES += "file://0001-am3358-sk-modified-WLAN-enable-and-irq-to-match-boar.patch"
82 # Add CPU utilization patch for WLAN
83 PATCHES += "file://0001-am335xevm-using-edge-triggered-interrupts-for-WLAN.patch"
85 # Add patch to enable pullup on WLAN enable
86 PATCHES += "file://0001-am335x-enable-pullup-on-the-WLAN-enable-pin-fo.patch"
88 # Update SPI flash layout. Increase space allocated for u-boot
89 PATCHES += "file://0001-ARM-OMAP2-AM335x-Update-SPI-flash-layout.patch"
91 # Copy the am33x-cm3 firmware if it is available
92 do_configure_append() {
93 if [ -e "${STAGING_DIR_HOST}/${base_libdir}/firmware/am335x-pm-firmware.bin" ]
94 then
95 cp "${STAGING_DIR_HOST}/${base_libdir}/firmware/am335x-pm-firmware.bin" "${S}/firmware"
96 fi
97 }