recipes-kernel/linux/linux-ti-staging_3.8.bb

   1 SECTION = "kernel"
   2 DESCRIPTION = "Linux kernel for TI devices"
   3 LICENSE = "GPLv2"
   4 LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
   5 KERNEL_IMAGETYPE = "uImage"
   6
   7 inherit kernel
   8
   9 # This function must be here BEFORE the require of linux-dtb.inc below.
  10 # There is a "bug" in the base kernel.bbclass that after it's do_deploy
  11 # step it does not return back to the ${S} directory but stays in the
  12 # DEPLOY_DIR.  However, the do_deploy_append defined in linux-dtb.inc
  13 # assumes that it is being run in the ${S} directory.  A patch is
  14 # being submitted to fix this issue by either changing the do_deploy
  15 # in the kernel.bbclass to do "cd -" as the last step or to add
  16 # "cd ${S}" as the first line of do_deploy in linux-dtb.inc and this
  17 # function can be removed once that change is available.
  18 # If the function is not placed BEFORE the require then the change
  19 # directory is not appended before the linux-dtb.inc changes.
  20 do_deploy_append() {
  21     cd ${S}
  22 }
  23
  24 require recipes-kernel/linux/linux-dtb.inc
  25 require recipes-kernel/linux/setup-defconfig.inc
  26
  27 # Stage the power management firmware before building the kernel
  28 # for ti33x SOC_FAMILY devices
  29 DEPENDS_ti33x += "am33x-cm3"
  30
  31 # Default is to package all dts files for ti33x devices unless building
  32 # for the specific beaglebone machine.
  33 KERNEL_DEVICETREE_ti33x = "arch/arm/boot/dts/am335x-evm.dts arch/arm/boot/dts/am335x-evmsk.dts arch/arm/boot/dts/am335x-bone.dts"
  34 KERNEL_DEVICETREE_beaglebone = "arch/arm/boot/dts/am335x-bone.dts"
  35 KERNEL_DEVICETREE_omap5-evm = "arch/arm/boot/dts/omap5-sevm.dts arch/arm/boot/dts/omap5-uevm.dts"
  36
  37 COMPATIBLE_MACHINE = "ti33x|omap-a15"
  38
  39 S = "${WORKDIR}/git"
  40
  41 BRANCH = "ti-linux-3.8.y"
  42
  43 SRCREV = "881dfafeae47da3a8f5ff8c791753e4b4df8065b"
  44 PV = "3.8.5"
  45
  46 # Append to the MACHINE_KERNEL_PR so that a new SRCREV will cause a rebuild
  47 MACHINE_KERNEL_PR_append = "d+gitr${SRCPV}"
  48
  49 SRC_URI = "git://git.ti.com/ti-linux-kernel/ti-linux-kernel.git;protocol=git;branch=${BRANCH} \
  50            file://defconfig \
  51           "
  52
  53 # Copy the am33x-cm3 firmware if it is available for ti33x SOC_FAMILY devices
  54 do_compile_prepend_ti33x() {
  55     if [ -e "${STAGING_DIR_HOST}/${base_libdir}/firmware/am335x-pm-firmware.bin" ]
  56     then
  57         cp "${STAGING_DIR_HOST}/${base_libdir}/firmware/am335x-pm-firmware.bin" "${S}/firmware"
  58     fi
  59 }