recipes-kernel/linux/linux-ti33x-psp_3.1.bb

   1 SECTION = "kernel"
   2 DESCRIPTION = "Linux kernel for TI33x EVM from PSP, based on am335x-kernel"
   3 LICENSE = "GPLv2"
   4 KERNEL_IMAGETYPE = "uImage"
   5
   6 require multi-kernel.inc
   7
   8 S = "${WORKDIR}/git"
   9
  10 MULTI_CONFIG_BASE_SUFFIX = ""
  11
  12 BRANCH = "master"
  13 SRCREV = "fd97d5068496ab770991a263e9046781ca2441a5"
  14 MACHINE_KERNEL_PR_append = "m+gitr${SRCREV}"
  15
  16 COMPATIBLE_MACHINE = "(ti33x)"
  17
  18 THISDIR := "${@os.path.dirname(bb.data.getVar('FILE', d, True))}"
  19 CONFIGS_PSP = "${@base_set_filespath(["${THISDIR}/${PN}-${PV}/tipspkernel"], d)}:\
  20 ${@base_set_filespath(["${THISDIR}/${PN}/tipspkernel"], d)}:\
  21 ${@base_set_filespath(["${THISDIR}/files/tipspkernel"], d)}:"
  22 FILESPATH =. "${@base_contains('DISTRO_FEATURES', 'tipspkernel', "${CONFIGS_PSP}", "", d)}"
  23
  24 SRC_URI += "git://arago-project.org/git/projects/linux-am33x.git;protocol=git;branch=${BRANCH} \
  25         file://defconfig"
  26
  27 PATCHES_OVER_PSP = " \
  28         file://0001-f_rndis-HACK-around-undefined-variables.patch \
  29         file://0001-am335x-Add-pin-mux-and-init-for-beaglebone-specific-.patch \
  30         file://0001-am335x-Check-return-value-of-omap_mux_init_signal.patch \
  31         file://0002-at24-Add-ability-to-dynamically-reconfigure-chip-inf.patch \
  32         file://0003-am335x-evm-Reconfigure-EEPROM-with-new-eeprom_info-in.patch \
  33         file://0001-ARM-OMAP2-beaglebone-hack-in-DVI-support.patch \
  34         "
  35
  36 SRC_URI += "${@base_contains('DISTRO_FEATURES', 'tipspkernel', "", "${PATCHES_OVER_PSP}", d)}"