recipes-kernel/linux/linux.inc

   1 DESCRIPTION = "Linux Kernel"
   2 SECTION = "kernel"
   3 LICENSE = "GPLv2"
   4
   5 LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
   6
   7 inherit kernel siteinfo
   8
   9 # Enable OABI compat for people stuck with obsolete userspace
  10 ARM_KEEP_OABI ?= "1"
  11
  12 # Quirk for udev greater or equal 141
  13 UDEV_GE_141 ?= "0"
  14
  15 # Specify the commandline for your device
  16
  17 # Boot from mmc
  18 CMDLINE_at91sam9263ek = "mem=64M console=ttyS0,115200 root=/dev/mmcblk0p1 rootfstype=ext2 rootdelay=5"
  19 # Boot from nfs
  20 #CMDLINE_at91sam9263ek = "mem=64M console=ttyS0,115200 root=301 root=/dev/nfs nfsroot=172.20.3.1:/data/at91 ip=172.20.0.5:::255.255.0.0"
  21
  22 # Set the verbosity of kernel messages during runtime
  23 # You can define CMDLINE_DEBUG in your local.conf or distro.conf to override this behaviour
  24 CMDLINE_DEBUG ?= '${@base_conditional("DISTRO_TYPE", "release", "quiet", "debug", d)}'
  25 CMDLINE_append = " ${CMDLINE_DEBUG} "
  26
  27 # Kernel bootlogo is distro-specific (default is OE logo).
  28 # Logo resolution (qvga, vga, ...) is machine-specific.
  29 LOGO_SIZE ?= "."
  30
  31 # Support for binary device tree generation
  32
  33 FILES_kernel-devicetree = "/boot/devicetree*"
  34
  35 KERNEL_DEVICETREE_boc01 = "${WORKDIR}/boc01.dts"
  36 KERNEL_DEVICETREE_calamari = "arch/${ARCH}/boot/dts/mpc8536ds.dts"
  37 KERNEL_DEVICETREE_canyonlands = "arch/${ARCH}/boot/dts/canyonlands.dts"
  38 KERNEL_DEVICETREE_kilauea = "arch/${ARCH}/boot/dts/kilauea.dts"
  39 KERNEL_DEVICETREE_lite5200 = "arch/${ARCH}/boot/dts/lite5200.dts"
  40 KERNEL_DEVICETREE_lsppchd = "arch/${ARCH}/boot/dts/kuroboxHD.dts"
  41 KERNEL_DEVICETREE_lsppchg = "arch/${ARCH}/boot/dts/kuroboxHG.dts"
  42 KERNEL_DEVICETREE_mpc8313e-rdb = "arch/${ARCH}/boot/dts/mpc8313erdb.dts"
  43 KERNEL_DEVICETREE_mpc8315e-rdb = "arch/${ARCH}/boot/dts/mpc8315erdb.dts"
  44 KERNEL_DEVICETREE_mpc8323e-rdb = "arch/${ARCH}/boot/dts/mpc832x_rdb.dts"
  45 KERNEL_DEVICETREE_mpc8544ds = "arch/${ARCH}/boot/dts/mpc8544ds.dts"
  46 KERNEL_DEVICETREE_mpc8641-hpcn = "arch/${ARCH}/boot/dts/mpc8641_hpcn.dts"
  47 KERNEL_DEVICETREE_p1020rdb = "arch/${ARCH}/boot/dts/p1020rdb.dts"
  48 KERNEL_DEVICETREE_p2020ds = "arch/${ARCH}/boot/dts/p2020ds.dts"
  49 KERNEL_DEVICETREE_sequoia = "arch/${ARCH}/boot/dts/sequoia.dts"
  50 KERNEL_DEVICETREE_tqm8540 = "arch/${ARCH}/boot/dts/tqm8540.dts"
  51 KERNEL_DEVICETREE_xilinx-ml507 = "arch/${ARCH}/boot/dts/virtex440-ml507.dts"
  52
  53 KERNEL_DEVICETREE_FLAGS = "-R 8 -S 0x3000"
  54
  55 CORTEXA8FIXUP ?= "yes"
  56
  57 python __anonymous () {
  58
  59     import bb
  60
  61     devicetree = bb.data.getVar('KERNEL_DEVICETREE', d, 1) or ''
  62     if devicetree:
  63         depends = bb.data.getVar("DEPENDS", d, 1)
  64         bb.data.setVar("DEPENDS", "%s dtc-native" % depends, d)
  65         packages = bb.data.getVar("PACKAGES", d, 1)
  66         bb.data.setVar("PACKAGES", "%s kernel-devicetree" % packages, d)
  67 }
  68
  69 do_configure_prepend() {
  70
  71         # Rename getline in ./scripts/unifdef.c
  72         # Kernels up to 2.6.29 are currently failing to build unifdef.c,
  73         # clashing with exposed getline() from <stdio.h>
  74         # see https://patchwork.kernel.org/patch/11166/
  75         # committed in 2.6.29 (commit d15bd1067b1fcb2b7250d22bc0c7c7fea0b759f7)
  76
  77         sed -i -e 's/getline/parseline/g' ${S}/scripts/unifdef.c
  78
  79
  80         echo "" > ${S}/.config
  81
  82         #
  83         # logo support, if you supply logo_linux_clut224.ppm in SRC_URI, then it's going to be used
  84         #
  85         if [ -e ${WORKDIR}/${LOGO_SIZE}/logo_linux_clut224.ppm ]; then
  86                 install -m 0644 ${WORKDIR}/${LOGO_SIZE}/logo_linux_clut224.ppm drivers/video/logo/logo_linux_clut224.ppm
  87                 echo "CONFIG_LOGO=y"                    >> ${S}/.config
  88                 echo "CONFIG_LOGO_LINUX_CLUT224=y"      >> ${S}/.config
  89         fi
  90
  91         #
  92         # oabi / eabi support
  93         #
  94         if [ "${TARGET_OS}" = "linux-gnueabi" -o  "${TARGET_OS}" = "linux-uclibceabi" ]; then
  95                 echo "CONFIG_AEABI=y"                   >> ${S}/.config
  96                 if [ "${ARM_KEEP_OABI}" = "1" ] ; then
  97                         echo "CONFIG_OABI_COMPAT=y"             >> ${S}/.config
  98                 else
  99                         echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
 100                 fi
 101         else
 102                 echo "# CONFIG_AEABI is not set"        >> ${S}/.config
 103                 echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
 104         fi
 105
 106         # When enabling thumb for userspace we also need thumb support in the kernel
 107         if [ "${ARM_INSTRUCTION_SET}" = "thumb" ] ; then
 108             sed -i -e /CONFIG_ARM_THUMB/d ${WORKDIR}/defconfig
 109             echo "CONFIG_ARM_THUMB=y" >> ${S}/.config
 110         fi
 111
 112         # Enable thumb2 fixup for specific issue in angstrom toolchains when used on A8 r1p[012] silicon
 113         if [ "${CORTEXA8FIXUP}" = "yes" ] ; then
 114             sed -i -e /CONFIG_ARM_ERRATA_430973/d ${WORKDIR}/defconfig
 115             echo "CONFIG_ARM_ERRATA_430973=y" >> ${S}/.config
 116         fi
 117
 118         #
 119         # endian support
 120         #
 121         if [ "${SITEINFO_ENDIANNESS}" = "be" ]; then
 122                 echo "CONFIG_CPU_BIG_ENDIAN=y"          >> ${S}/.config
 123         fi
 124
 125         echo "CONFIG_CMDLINE=\"${CMDLINE}\"" >> ${S}/.config
 126
 127         sed -e '/CONFIG_AEABI/d' \
 128             -e '/CONFIG_OABI_COMPAT=/d' \
 129             -e '/CONFIG_CMDLINE=/d' \
 130             -e '/CONFIG_CPU_BIG_ENDIAN/d' \
 131             -e '/CONFIG_LOGO=/d' \
 132             -e '/CONFIG_LOGO_LINUX_CLUT224=/d' \
 133             -e '/CONFIG_LOCALVERSION/d' \
 134             -e '/CONFIG_LOCALVERSION_AUTO/d' \
 135             < '${WORKDIR}/defconfig' >>'${S}/.config'
 136
 137         echo 'CONFIG_LOCALVERSION=""' >>${S}/.config
 138         echo '# CONFIG_LOCALVERSION_AUTO is not set' >>${S}/.config
 139
 140         #
 141         # Udev quirks
 142         #
 143
 144         # Newer versions of udev mandate that sysfs doesn't have deprecated entries
 145         if [ "${UDEV_GE_141}" = "1" ] ; then
 146             sed -e /CONFIG_SYSFS_DEPRECATED/d \
 147                 -e /CONFIG_SYSFS_DEPRECATED_V2/d \
 148                 -e /CONFIG_HOTPLUG/d \
 149                 -e /CONFIG_UEVENT_HELPER_PATH/d \
 150                 -e /CONFIG_UNIX/d \
 151                 -e /CONFIG_SYSFS/d \
 152                 -e /CONFIG_PROC_FS/d \
 153                 -e /CONFIG_TMPFS/d \
 154                 -e /CONFIG_INOTIFY_USER/d \
 155                 -e /CONFIG_SIGNALFD/d \
 156                 -e /CONFIG_TMPFS_POSIX_ACL/d \
 157                 -e /CONFIG_BLK_DEV_BSG/d \
 158                 -i '${S}/.config'
 159
 160             echo '# CONFIG_SYSFS_DEPRECATED is not set' >> ${S}/.config
 161             echo '# CONFIG_SYSFS_DEPRECATED_V2 is not set' >> ${S}/.config
 162             echo 'CONFIG_HOTPLUG=y' >> ${S}/.config
 163             echo 'CONFIG_UEVENT_HELPER_PATH=""' >> ${S}/.config
 164             echo 'CONFIG_UNIX=y' >> ${S}/.config
 165             echo 'CONFIG_SYSFS=y' >> ${S}/.config
 166             echo 'CONFIG_PROC_FS=y' >> ${S}/.config
 167             echo 'CONFIG_TMPFS=y' >> ${S}/.config
 168             echo 'CONFIG_INOTIFY_USER=y' >> ${S}/.config
 169             echo 'CONFIG_SIGNALFD=y' >> ${S}/.config
 170             echo 'CONFIG_TMPFS_POSIX_ACL=y' >> ${S}/.config
 171             echo 'CONFIG_BLK_DEV_BSG=y' >> ${S}/.config
 172             echo 'CONFIG_DEVTMPFS=y' >> ${S}/.config
 173             echo 'CONFIG_DEVTMPFS_MOUNT=y' >> ${S}/.config
 174         fi
 175
 176         # Newer inits like systemd need cgroup support
 177         if [ "${KERNEL_ENABLE_CGROUPS}" = "1" ] ; then
 178             sed -e /CONFIG_CGROUP_SCHED/d \
 179                 -e /CONFIG_CGROUPS/d \
 180                 -i '${S}/.config'
 181
 182             echo 'CONFIG_CGROUP_SCHED=y' >> ${S}/.config
 183             echo 'CONFIG_CGROUPS=y' >> ${S}/.config
 184             echo 'CONFIG_CGROUP_NS=y' >> ${S}/.config
 185             echo 'CONFIG_CGROUP_FREEZER=y' >> ${S}/.config
 186             echo 'CONFIG_CGROUP_DEVICE=y' >> ${S}/.config
 187             echo 'CONFIG_CPUSETS=y' >> ${S}/.config
 188             echo 'CONFIG_PROC_PID_CPUSET=y' >> ${S}/.config
 189             echo 'CONFIG_CGROUP_CPUACCT=y' >> ${S}/.config
 190             echo 'CONFIG_RESOURCE_COUNTERS=y' >> ${S}/.config
 191         fi
 192
 193         #
 194         # root-over-nfs-over-usb-eth support. Limited, but should cover some cases.
 195         # Enable this by setting a proper CMDLINE_NFSROOT_USB.
 196         #
 197         if [ ! -z "${CMDLINE_NFSROOT_USB}" ]; then
 198                 oenote "Configuring the kernel for root-over-nfs-over-usb-eth with CMDLINE ${CMDLINE_NFSROOT_USB}"
 199                 sed -e '/CONFIG_INET/d' \
 200                     -e '/CONFIG_IP_PNP=/d' \
 201                     -e '/CONFIG_USB_GADGET=/d' \
 202                     -e '/CONFIG_USB_GADGET_SELECTED=/d' \
 203                     -e '/CONFIG_USB_ETH=/d' \
 204                     -e '/CONFIG_NFS_FS=/d' \
 205                     -e '/CONFIG_ROOT_NFS=/d' \
 206                     -e '/CONFIG_CMDLINE=/d' \
 207                     -i ${S}/.config
 208                 echo "CONFIG_INET=y"                     >> ${S}/.config
 209                 echo "CONFIG_IP_PNP=y"                   >> ${S}/.config
 210                 echo "CONFIG_USB_GADGET=y"               >> ${S}/.config
 211                 echo "CONFIG_USB_GADGET_SELECTED=y"      >> ${S}/.config
 212                 echo "CONFIG_USB_ETH=y"                  >> ${S}/.config
 213                 echo "CONFIG_NFS_FS=y"                   >> ${S}/.config
 214                 echo "CONFIG_ROOT_NFS=y"                 >> ${S}/.config
 215                 echo "CONFIG_CMDLINE=\"${CMDLINE_NFSROOT_USB}\"" >> ${S}/.config
 216         fi
 217                 yes '' | oe_runmake oldconfig
 218 }
 219
 220 do_configure_append() {
 221         if test -e scripts/Makefile.fwinst ; then
 222                 sed -i -e "s:-m0644:-m 0644:g" scripts/Makefile.fwinst
 223         fi
 224 }
 225
 226 # bitbake.conf only prepends PARALLEL make in tasks called do_compile, which isn't the case for compile_modules
 227 # So explicitly enable it for that in here
 228 EXTRA_OEMAKE = "${PARALLEL_MAKE} "
 229
 230 do_install_append() {
 231         oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix}/src/linux-${KERNEL_VERSION} ARCH=$ARCH
 232 }
 233
 234 PACKAGES =+ "kernel-headers"
 235 FILES_kernel-headers = "${exec_prefix}/src/linux*"
 236
 237 do_devicetree_image() {
 238     if test -n "${KERNEL_DEVICETREE}" ; then
 239         dtc -I dts -O dtb ${KERNEL_DEVICETREE_FLAGS} -o devicetree ${KERNEL_DEVICETREE}
 240         install -d ${D}/boot
 241         install -m 0644 devicetree ${D}/boot/devicetree-${KERNEL_VERSION}
 242         install -d ${DEPLOY_DIR_IMAGE}
 243         install -m 0644 devicetree ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.dtb
 244         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.dtb
 245         cd ${DEPLOY_DIR_IMAGE}
 246         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 247         ln -sf ${KERNEL_IMAGE_BASE_NAME}.dtb ${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 248         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 249     fi
 250 }
 251
 252 addtask devicetree_image after do_install before do_package do_deploy
 253
 254 pkg_postinst_kernel-devicetree () {
 255         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/devicetree devicetree devicetree-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 256 }
 257
 258 pkg_postrm_kernel-devicetree () {
 259         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove devicetree devicetree-${KERNEL_VERSION} || true
 260 }
 261
 262 # Automatically depend on lzop-native if CONFIG_KERNEL_LZO is enabled
 263 python () {
 264     try:
 265         defconfig = bb.fetch2.localpath('file://defconfig', d)
 266     except bb.fetch2.FetchError:
 267         return
 268
 269     try:
 270         configfile = open(defconfig)
 271     except IOError:
 272         return
 273
 274     if 'CONFIG_KERNEL_LZO=y\n' in configfile.readlines():
 275         depends = d.getVar('DEPENDS', False)
 276         d.setVar('DEPENDS', depends + ' lzop-native')
 277 }