recipes-kernel/linux/tipspkernel.inc

   1 # Include this file for kernel recipes that need to handle different defconfigs
   2 # and apply patches based on "tipspkernel" DISTRO_FEATURES
   3
   4 def get_major_pv(p):
   5         import re
   6         r = re.compile("([0-9]+\.[0-9]+).*")
   7         m = r.match(p);
   8         if m:
   9                 return m.group(1)
  10         return None
  11
  12 PMV = "${@get_major_pv(d.getVar('PV', True))}"
  13
  14 # First of all, set own FILESPATH avoiding unnecessary BP and BPN, but adding
  15 # extra level of major version
  16 FILESPATH = "${@base_set_filespath([ "${FILE_DIRNAME}/${PF}", "${FILE_DIRNAME}/${P}", "${FILE_DIRNAME}/${PN}-${PMV}", \
  17 "${FILE_DIRNAME}/${PN}", "${FILE_DIRNAME}/files", "${FILE_DIRNAME}" ], d)}"
  18
  19 # We don't want "tipspkernel" to be another OVERRIDE, but rather a new level of
  20 # FILESPATH with all the OVERRIDES applied to it
  21 CONFIGS_PSP = "${@base_set_filespath(["${FILE_DIRNAME}/${PF}/tipspkernel", "${FILE_DIRNAME}/${P}/tipspkernel", \
  22 "${FILE_DIRNAME}/${PN}-${PMV}/tipspkernel", "${FILE_DIRNAME}/${PN}/tipspkernel", "${FILE_DIRNAME}/files/tipspkernel", \
  23 "${FILE_DIRNAME}/tipspkernel"], d)}:"
  24
  25 # When "tipspkernel" is ENABLED, prepend additional set of directories to FILESPATH
  26 FILESPATH =. "${@base_contains('DISTRO_FEATURES', 'tipspkernel', "${CONFIGS_PSP}", "", d)}"
  27
  28 # When "tipspkernel" is NOT ENABLED, append additional list of PATCHES_OVER_PSP to SRC_URI
  29 SRC_URI_append = "${@base_contains('DISTRO_FEATURES', 'tipspkernel', "", "${PATCHES_OVER_PSP}", d)}"
  30
  31 # List additional patches to apply on top of PSP kernel, start with a space
  32 PATCHES_OVER_PSP = ""