TI-BSP: import matrix from OE
authorKoen Kooi <koen@dominion.thruhere.net>
Thu, 13 Jan 2011 11:19:52 +0000 (12:19 +0100)
committerKoen Kooi <koen@dominion.thruhere.net>
Thu, 13 Jan 2011 11:23:17 +0000 (12:23 +0100)
Added license checksums as well

Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
recipes-bsp/ti/am-sysinfo_svn.bb [new file with mode: 0644]
recipes-bsp/ti/matrix-gui-common.inc [new file with mode: 0644]
recipes-bsp/ti/matrix-gui-common_1.3.bb [new file with mode: 0644]
recipes-bsp/ti/matrix-gui-common_1.4.bb [new file with mode: 0644]
recipes-bsp/ti/matrix-gui-e.inc [new file with mode: 0644]
recipes-bsp/ti/matrix-gui-e_1.3.bb [new file with mode: 0644]
recipes-bsp/ti/matrix-gui.inc [new file with mode: 0644]
recipes-bsp/ti/matrix-gui_1.3.bb [new file with mode: 0644]
recipes-bsp/ti/matrix-tui.inc [new file with mode: 0644]
recipes-bsp/ti/matrix-tui/init [new file with mode: 0755]

diff --git a/recipes-bsp/ti/am-sysinfo_svn.bb b/recipes-bsp/ti/am-sysinfo_svn.bb
new file mode 100644 (file)
index 0000000..34830c9
--- /dev/null
@@ -0,0 +1,24 @@
+DESCRIPTION = "AM SysInfo"
+HOMEPAGE = "https://gforge.ti.com/gf/project/am_sysinfo/"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://mem_util/mem_util.c;beginline=1;endline=37;md5=8aa8e714ab729cfe8177298af8a5a25d"
+
+SECTION = "system"
+PRIORITY = "optional"
+
+SRCREV = "5"
+PV = "1.0"
+PR = "r1+svnr${SRCPV}"
+
+SRC_URI = "svn://gforge.ti.com/svn/am_sysinfo/;module=trunk;proto=https;user=anonymous;pswd=''"
+
+S = "${WORKDIR}/trunk"
+
+do_compile() {
+       ${CC} ${CFLAGS} ${LDFLAGS} -o mem_util/mem_util mem_util/mem_util.c
+}
+
+do_install() {
+       install -d ${D}/${bindir}
+       install -m 0755 ${S}/mem_util/mem_util ${D}/${bindir}
+}
diff --git a/recipes-bsp/ti/matrix-gui-common.inc b/recipes-bsp/ti/matrix-gui-common.inc
new file mode 100644 (file)
index 0000000..58f41d0
--- /dev/null
@@ -0,0 +1,42 @@
+DESCRIPTION = "Common files for all versions of Matrix GUI"
+HOMEPAGE = "https://gforge.ti.com/gf/project/matrix_gui/"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://main.cpp;beginline=1;endline=37;md5=a802a01a3a58f2ebb1e83c25f883f0c0"
+
+SECTION = "multimedia"
+PRIORITY = "optional"
+
+INC_PR = "r6"
+
+COMPATIBLE_MACHINE = "(dm365|omapl138|omap3|ti816x)"
+
+PLATFORM_dm365 = "dm365"
+PLATFORM_omapl138 = "omapl138"
+PLATFORM_omap3evm = "omap3530"
+PLATFORM_dm37x-evm = "dm3730"
+PLATFORM_am37x-evm = "am3715"
+PLATFORM_beagleboard = "am3715"
+PLATFORM_ti816x = "ti816x"
+PLATFORM_am180x-evm = "am180x"
+PLATFORM_am181x-evm = "am181x"
+PLATFORM_am3517-evm = "am3517"
+
+#Checkout the project repository to get access to the scripts and data
+#files.
+SRC_URI = "svn://gforge.ti.com/svn/matrix_gui/;module=trunk;proto=https;user=anonymous;pswd='' "
+
+S = "${WORKDIR}/trunk"
+
+PACKAGE_ARCH = ${MACHINE_ARCH}
+
+do_install() {
+    install -d ${D}/${bindir}
+    install -m 0755 ${S}/${PLATFORM}/bin/* ${D}/${bindir}/
+    install -d ${D}/${datadir}/matrix/html
+    install -m 0644 ${S}/${PLATFORM}/html/* ${D}/${datadir}/matrix/html
+    install -d ${D}/${datadir}/matrix/images
+    install -m 0644 ${S}/images/*.png ${D}/${datadir}/matrix/images/
+
+}
+
+FILES_${PN} += "${datadir}/matrix/*"
diff --git a/recipes-bsp/ti/matrix-gui-common_1.3.bb b/recipes-bsp/ti/matrix-gui-common_1.3.bb
new file mode 100644 (file)
index 0000000..a879720
--- /dev/null
@@ -0,0 +1,8 @@
+require matrix-gui-common.inc
+
+# Use the mem_util application from am-sysinfo instead of a
+# prebuilt version in the repository.
+RRECOMMENDS_${PN} = "am-sysinfo"
+
+SRCREV = "156"
+PR = "${INC_PR}.0"
diff --git a/recipes-bsp/ti/matrix-gui-common_1.4.bb b/recipes-bsp/ti/matrix-gui-common_1.4.bb
new file mode 100644 (file)
index 0000000..c578a47
--- /dev/null
@@ -0,0 +1,8 @@
+require matrix-gui-common.inc
+
+# Use the mem_util application from am-sysinfo instead of a
+# prebuilt version in the repository.
+RRECOMMENDS_${PN} = "am-sysinfo"
+
+SRCREV = "192"
+PR = "${INC_PR}.0"
diff --git a/recipes-bsp/ti/matrix-gui-e.inc b/recipes-bsp/ti/matrix-gui-e.inc
new file mode 100644 (file)
index 0000000..a04327b
--- /dev/null
@@ -0,0 +1,47 @@
+DESCRIPTION = "Matrix GUI for Qt Embedded"
+HOMEPAGE = "https://gforge.ti.com/gf/project/matrix_gui/"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://main.cpp;beginline=1;endline=37;md5=a802a01a3a58f2ebb1e83c25f883f0c0"
+
+SECTION = "multimedia"
+PRIORITY = "optional"
+
+INC_PR = "r21"
+
+COMPATIBLE_MACHINE = "(dm365|omapl138|omap3|ti816x)"
+
+PLATFORM_dm365 = "dm365"
+PLATFORM_omapl138 = "omapl138"
+PLATFORM_omap3evm = "omap3530"
+PLATFORM_dm37x-evm = "dm3730"
+PLATFORM_am37x-evm = "am3715"
+PLATFORM_beagleboard = "am3715"
+PLATFORM_ti816x = "ti816x"
+PLATFORM_am180x-evm = "am180x"
+PLATFORM_am181x-evm = "am181x"
+PLATFORM_am3517-evm = "am3517"
+
+SRC_URI = "svn://gforge.ti.com/svn/matrix_gui/;module=trunk;proto=https;user=anonymous;pswd='' "
+
+S = "${WORKDIR}/trunk"
+
+INITSCRIPT_NAME = "matrix-gui-e"
+INITSCRIPT_PARAMS = "defaults 99"
+#INITSCRIPT_PARAMS = "start 99 3 . stop 99 3 ."
+
+CXXFLAGS_omapl138_append = " -DPlatform_omapl138 "
+CXXFLAGS_dm365_append = " -DPlatform_dm365 "
+PACKAGE_ARCH = ${MACHINE_ARCH}
+
+inherit qt4e update-rc.d
+
+do_install() {
+       install -d ${D}/${bindir}
+       install -m 0755 ${S}/matrix_gui ${D}/${bindir}/matrix_guiE
+       install -d ${D}${sysconfdir}/init.d/
+       install -c -m 0755 ${S}/${PLATFORM}/etc/init ${D}${sysconfdir}/init.d/matrix-gui-e
+
+}
+
+RRECOMMENDS_${PN} = "qt4-embedded-plugin-mousedriver-tslib qt4-embedded-fonts"
+RDEPENDS_${PN} += "matrix-gui-common"
diff --git a/recipes-bsp/ti/matrix-gui-e_1.3.bb b/recipes-bsp/ti/matrix-gui-e_1.3.bb
new file mode 100644 (file)
index 0000000..dd1b16b
--- /dev/null
@@ -0,0 +1,5 @@
+require matrix-gui-e.inc
+
+SRCREV = "192"
+PR = "${INC_PR}.0"
+
diff --git a/recipes-bsp/ti/matrix-gui.inc b/recipes-bsp/ti/matrix-gui.inc
new file mode 100644 (file)
index 0000000..1b2968e
--- /dev/null
@@ -0,0 +1,50 @@
+DESCRIPTION = "Matrix GUI for Qt X11"
+HOMEPAGE = "https://gforge.ti.com/gf/project/matrix_gui/"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://main.cpp;beginline=1;endline=37;md5=a802a01a3a58f2ebb1e83c25f883f0c0"
+
+SECTION = "multimedia"
+PRIORITY = "optional"
+
+INC_PR = "r19"
+
+COMPATIBLE_MACHINE = "(dm365|omapl138|omap3|ti816x)"
+
+PLATFORM_dm365 = "dm365"
+PLATFORM_omapl138 = "omapl138"
+PLATFORM_omap3evm = "omap3530"
+PLATFORM_dm37x-evm = "dm3730"
+PLATFORM_am37x-evm = "am3715"
+PLATFORM_beagleboard = "am3715"
+PLATFORM_ti816x = "ti816x"
+PLATFORM_am180x-evm = "am180x"
+PLATFORM_am181x-evm = "am181x"
+PLATFORM_am3517-evm = "am3517"
+
+SRC_URI = "svn://gforge.ti.com/svn/matrix_gui/;module=trunk;proto=https;user=anonymous;pswd='' "
+
+S = "${WORKDIR}/trunk"
+
+CXXFLAGS_omapl138_append = " -DPlatform_omapl138 "
+CXXFLAGS_dm365_append = " -DPlatform_dm365 "
+PACKAGE_ARCH = ${MACHINE_ARCH}
+
+inherit qt4x11
+
+do_install() {
+       install -d ${D}/${bindir}
+       install -m 0755 ${S}/matrix_gui ${D}/${bindir}
+       install -d ${D}${sysconfdir}/init.d/
+       install -c -m 0755 ${S}/${PLATFORM}/etc/x11/init ${D}${sysconfdir}/init.d/matrix-gui
+       install -d ${D}/${sysconfdir}/xdg/autostart
+       install -m 0755 ${S}/${PLATFORM}/etc/x11/matrix-gui.desktop ${D}/${sysconfdir}/xdg/autostart
+}
+
+FILES_${PN}-autostart = "${sysconfdir}/xdg/autostart/matrix-gui.desktop"
+
+#Make autostart package depend on matrix-gui package.  Doesn't make sense
+#to install the autostart package without the underlying matrix-gui package.
+RDEPENDS_${PN}-autostart += "${PN}"
+PACKAGES =+ "${PN}-autostart"
+
+RDEPENDS_${PN} += "matrix-gui-common"
diff --git a/recipes-bsp/ti/matrix-gui_1.3.bb b/recipes-bsp/ti/matrix-gui_1.3.bb
new file mode 100644 (file)
index 0000000..53db8af
--- /dev/null
@@ -0,0 +1,4 @@
+require matrix-gui.inc
+
+SRCREV = "192"
+PR = "${INC_PR}.0"
diff --git a/recipes-bsp/ti/matrix-tui.inc b/recipes-bsp/ti/matrix-tui.inc
new file mode 100644 (file)
index 0000000..1ad8aa8
--- /dev/null
@@ -0,0 +1,52 @@
+DESCRIPTION = "Matrix TUI"
+HOMEPAGE = "https://gforge.ti.com/gf/project/matrix_tui/"
+LICENSE = "BSD"
+SECTION = "multimedia"
+PRIORITY = "optional"
+DEPENDS = "libxml2 zlib ncurses"
+
+INC_PR = "r7"
+
+COMPATIBLE_MACHINE = "(omapl138|omap3)"
+
+PLATFORM_am37x-evm = "am3715"
+PLATFORM_beagleboard = "am3715"
+PLATFORM_am3517-evm = "am3517"
+PLATFORM_am180x-evm = "am180x"
+PLATFORM_am181x-evm = "am181x"
+PLATFORM_da850-omapl138-evm = "am180x"
+
+SRC_URI = "svn://gforge.ti.com/svn/matrix_tui/;module=trunk;proto=https;user=anonymous;pswd='' \
+       file://init \
+"
+
+S = "${WORKDIR}/trunk"
+
+# Do not auto-start TUI by default, uncomment otherwise
+#inherit update-rc.d
+#INITSCRIPT_NAME = "matrix-tui"
+#INITSCRIPT_PARAMS = "defaults 99"
+
+do_configure() {
+       sed -i -e 's:PATH=${LINUX_DEVKIT_PATH}/arm-none-linux-gnueabi:PATH ?= ${LINUX_DEVKIT_PATH}/arm-none-linux-gnueabi:' makefile.init
+       sed -i -e 's|LIBS :=|LIBS := ${LDFLAGS} |' Release/objects.mk
+}
+
+do_compile() {
+       # don't build debug version
+       touch debug
+       export CROSS_COMPILE=${TARGET_PREFIX}
+       export TUI_INCLUDE_PATH=${STAGING_INCDIR}
+       export XML_INCLUDE_PATH=${STAGING_INCDIR}/libxml2
+       export TUI_LIB_PATH=${STAGING_LIBDIR}
+       make release
+}
+
+do_install() {
+       export PLATFORM=${PLATFORM}
+       make DESTDIR=${D} install
+       install -d ${D}${sysconfdir}/init.d/
+       install -c -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/matrix-tui
+}
+
+FILES_${PN} += "${datadir}/matrix/*"
diff --git a/recipes-bsp/ti/matrix-tui/init b/recipes-bsp/ti/matrix-tui/init
new file mode 100755 (executable)
index 0000000..e581382
--- /dev/null
@@ -0,0 +1,24 @@
+#! /bin/sh
+
+matrixtui="/usr/bin/matrix_tui"
+TUI_OPTS="/usr/share/matrix/xml/matrix.xml"
+
+test -x "$matrixtui" || exit 0
+
+case "$1" in
+  start)
+    echo -n "Starting Matrix TUI application"
+    start-stop-daemon --start --quiet --background --pidfile /var/run/matrix-tui.pid --exec $matrixtui -- $TUI_OPTS
+    echo "."
+    ;;
+  stop)
+    echo -n "Stopping Matrix TUI application"
+    start-stop-daemon --stop --quiet --pidfile /var/run/matrix-tui.pid
+    echo "."
+    ;;
+  *)
+    echo "Usage: /etc/init.d/matrix-tui {start|stop}"
+    exit 1
+esac
+
+exit 0