1edea945c4b07f48f59ef6ad67afd70b3e6f2572
[opencl/llvm.git] / CMakeLists.txt
1 project(LLVM)
2 cmake_minimum_required(VERSION 2.6.1)
4 set(PACKAGE_NAME llvm)
5 set(PACKAGE_VERSION 2.6svn)
6 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
7 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
9 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
10   message(FATAL_ERROR "In-source builds are not allowed.
11 CMake would overwrite the makefiles distributed with LLVM.
12 Please create a directory and run cmake from there, passing the path
13 to this source directory as the last argument.
14 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
15 Please delete them.")
16 endif()
18 include(FindPerl)
20 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
21 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
22 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
23 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
24 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
26 set(LLVM_ALL_TARGETS
27   Alpha
28   ARM
29   CBackend
30   CellSPU
31   CppBackend
32   IA64
33   Mips
34   MSIL
35   PIC16
36   PowerPC
37   Sparc
38   X86
39   XCore
40   )
42 # List of targets whose asmprinters need to be forced to link
43 # into executables on some platforms (i.e. Windows):
44 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
46 if( MSVC )
47   set(LLVM_TARGETS_TO_BUILD X86
48     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
49 else( MSVC )
50   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
51     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
52 endif( MSVC )
54 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
56 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
57   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
58 endif()
60 foreach(c ${LLVM_TARGETS_TO_BUILD})
61   list(FIND LLVM_ALL_TARGETS ${c} idx)
62   if( idx LESS 0 )
63     message(FATAL_ERROR "The target `${c}' does not exists.
64     It should be one of\n${LLVM_ALL_TARGETS}")
65   endif()
66 endforeach(c)
68 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
70 # Add path for custom modules
71 set(CMAKE_MODULE_PATH
72   ${CMAKE_MODULE_PATH}
73   "${LLVM_MAIN_SRC_DIR}/cmake"
74   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
75   )
77 if(WIN32)
78   if(CYGWIN)
79     set(LLVM_ON_WIN32 0)
80     set(LLVM_ON_UNIX 1)
81   else(CYGWIN)
82     set(LLVM_ON_WIN32 1)
83     set(LLVM_ON_UNIX 0)
84   endif(CYGWIN)
85   set(LTDL_SHLIB_EXT ".dll")
86   set(EXEEXT ".exe")
87   # Maximum path length is 160 for non-unicode paths
88   set(MAXPATHLEN 160)
89 else(WIN32)
90   if(UNIX)
91     set(LLVM_ON_WIN32 0)
92     set(LLVM_ON_UNIX 1)
93     set(LTDL_SHLIB_EXT ".so")
94     set(EXEEXT "")
95     # FIXME: Maximum path length is currently set to 'safe' fixed value
96     set(MAXPATHLEN 2024)
97   else(UNIX)
98     MESSAGE(SEND_ERROR "Unable to determine platform")
99   endif(UNIX)
100 endif(WIN32)
102 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
103   set(HAVE_LLVM_CONFIG 1)
104 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
106 include(config-ix)
108 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
110 if( LLVM_ENABLE_PIC )
111   if( SUPPORTS_FPIC_FLAG )
112     message(STATUS "Building with -fPIC")
113     add_definitions(-fPIC)
114   else( SUPPORTS_FPIC_FLAG )
115     message(STATUS "Warning: -fPIC not supported.")
116   endif()
117 endif()
119 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
120 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
121 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
123 # set(CMAKE_VERBOSE_MAKEFILE true)
125 add_definitions( -D__STDC_LIMIT_MACROS )
126 add_definitions( -D__STDC_CONSTANT_MACROS )
128 set(LLVM_PLO_FLAGS "" CACHE
129   STRING "Flags for creating partially linked objects.")
131 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
132   # TODO: support other platforms and toolchains.
133   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
134   if( LLVM_BUILD_32_BITS )
135     message(STATUS "Building 32 bits executables and libraries.")
136     add_definitions( -m32 )
137     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
138     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
139     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
140   endif( LLVM_BUILD_32_BITS )
141 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
143 if( MSVC )
144   add_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
145   add_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
146   add_definitions( -D_SCL_SECURE_NO_DEPRECATE )
147   add_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
148   add_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
149 endif( MSVC )
151 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
153 include(AddLLVM)
154 include(AddPartiallyLinkedObject)
155 include(TableGen)
157 add_subdirectory(lib/Support)
158 add_subdirectory(lib/System)
160 # Everything else depends on Support and System:
161 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
163 set(LLVM_TABLEGEN "tblgen" CACHE
164   STRING "Native TableGen executable. Saves building one when cross-compiling.")
166 add_subdirectory(utils/TableGen)
168 if( CMAKE_CROSSCOMPILING )
169   # This adds a dependency on target `tblgen', so must go after utils/TableGen
170   include( CrossCompileLLVM )
171 endif( CMAKE_CROSSCOMPILING )
173 add_subdirectory(include/llvm)
175 add_subdirectory(lib/VMCore)
176 add_subdirectory(lib/CodeGen)
177 add_subdirectory(lib/CodeGen/SelectionDAG)
178 add_subdirectory(lib/CodeGen/AsmPrinter)
179 add_subdirectory(lib/Bitcode/Reader)
180 add_subdirectory(lib/Bitcode/Writer)
181 add_subdirectory(lib/Transforms/Utils)
182 add_subdirectory(lib/Transforms/Instrumentation)
183 add_subdirectory(lib/Transforms/Scalar)
184 add_subdirectory(lib/Transforms/IPO)
185 add_subdirectory(lib/Transforms/Hello)
186 add_subdirectory(lib/Linker)
187 add_subdirectory(lib/Analysis)
188 add_subdirectory(lib/Analysis/IPA)
190 foreach(t ${LLVM_TARGETS_TO_BUILD})
191   message(STATUS "Targeting ${t}")
192   add_subdirectory(lib/Target/${t})
193   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
194     add_subdirectory(lib/Target/${t}/AsmPrinter)
195   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
196 endforeach(t)
198 add_subdirectory(lib/ExecutionEngine)
199 add_subdirectory(lib/ExecutionEngine/Interpreter)
200 add_subdirectory(lib/ExecutionEngine/JIT)
201 add_subdirectory(lib/Target)
202 add_subdirectory(lib/AsmParser)
203 add_subdirectory(lib/Debugger)
204 add_subdirectory(lib/Archive)
206 add_subdirectory(projects)
207 add_subdirectory(tools)
209 add_subdirectory(examples)
211 install(DIRECTORY include
212   DESTINATION .
213   PATTERN ".svn" EXCLUDE
214   PATTERN "*.cmake" EXCLUDE
215   PATTERN "*.in" EXCLUDE
216   )
218 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
219   DESTINATION .
220   )
222 # TODO: make and install documentation.