CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 5)
  15
  16 if (NOT PACKAGE_VERSION)
  17   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  18 endif()
  19
  20 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  21
  22 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  23 if ( LLVM_USE_FOLDERS )
  24   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  25 endif()
  26
  27 include(VersionFromVCS)
  28
  29 option(LLVM_APPEND_VC_REV
  30   "Append the version control system revision id to LLVM version" OFF)
  31
  32 if( LLVM_APPEND_VC_REV )
  33   add_version_info_from_vcs(PACKAGE_VERSION)
  34 endif()
  35
  36 set(PACKAGE_NAME LLVM)
  37 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  38 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  39
  40 # Configure CPack.
  41 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  42 set(CPACK_PACKAGE_VENDOR "LLVM")
  43 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  44 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  45 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  46 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  47 if(WIN32 AND NOT UNIX)
  48   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  49   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  50   set(CPACK_NSIS_MODIFY_PATH "ON")
  51   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  52   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  53     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  54   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  55     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  56 endif()
  57 include(CPack)
  58
  59 # Sanity check our source directory to make sure that we are not trying to
  60 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  61 # sure that we don't have any stray generated files lying around in the tree
  62 # (which would end up getting picked up by header search, instead of the correct
  63 # versions).
  64 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  65   message(FATAL_ERROR "In-source builds are not allowed.
  66 CMake would overwrite the makefiles distributed with LLVM.
  67 Please create a directory and run cmake from there, passing the path
  68 to this source directory as the last argument.
  69 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  70 Please delete them.")
  71 endif()
  72 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  73   file(GLOB_RECURSE
  74     tablegenned_files_on_include_dir
  75     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  76   file(GLOB_RECURSE
  77     tablegenned_files_on_lib_dir
  78     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  79   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  80     message(FATAL_ERROR "Apparently there is a previous in-source build,
  81 probably as the result of running `configure' and `make' on
  82 ${CMAKE_CURRENT_SOURCE_DIR}.
  83 This may cause problems. The suspicious files are:
  84 ${tablegenned_files_on_lib_dir}
  85 ${tablegenned_files_on_include_dir}
  86 Please clean the source directory.")
  87   endif()
  88 endif()
  89
  90 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  91
  92 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  93 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  94 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  95 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  96 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  97 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
  98 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  99
 100 set(LLVM_RUNTIME_OUTPUT_INTDIR ${LLVM_BINARY_DIR}/bin/${CMAKE_CFG_INTDIR})
 101 set(LLVM_LIBRARY_OUTPUT_INTDIR ${LLVM_BINARY_DIR}/lib/${CMAKE_CFG_INTDIR})
 102
 103 set(LLVM_ALL_TARGETS
 104   AArch64
 105   ARM
 106   CppBackend
 107   Hexagon
 108   Mips
 109   MSP430
 110   NVPTX
 111   PowerPC
 112   R600
 113   Sparc
 114   SystemZ
 115   X86
 116   XCore
 117   )
 118
 119 # List of targets with JIT support:
 120 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 121
 122 set(LLVM_TARGETS_TO_BUILD "all"
 123     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 124
 125 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 126   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 127
 128 option(BUILD_SHARED_LIBS
 129   "Build all libraries as shared libraries instead of static" OFF)
 130
 131 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 132 if(LLVM_ENABLE_CBE_PRINTF_A)
 133   set(ENABLE_CBE_PRINTF_A 1)
 134 endif()
 135
 136 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 137 if(LLVM_ENABLE_TIMESTAMPS)
 138   set(ENABLE_TIMESTAMPS 1)
 139 endif()
 140
 141 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 142 if(LLVM_ENABLE_BACKTRACES)
 143   set(ENABLE_BACKTRACES 1)
 144 endif()
 145
 146 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 147 if(LLVM_ENABLE_CRASH_OVERRIDES)
 148   set(ENABLE_CRASH_OVERRIDES 1)
 149 endif()
 150
 151 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 152 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 153 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 154
 155 set(LLVM_TARGET_ARCH "host"
 156   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 157
 158 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 159
 160 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 161
 162 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 163
 164 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 165   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 166 endif()
 167
 168 set(LLVM_TARGETS_TO_BUILD
 169    ${LLVM_TARGETS_TO_BUILD}
 170    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 171 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 172
 173 include(AddLLVMDefinitions)
 174
 175 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 176
 177 # MSVC has a gazillion warnings with this.
 178 if( MSVC )
 179   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 180 else( MSVC )
 181   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 182 endif()
 183
 184 option(LLVM_ENABLE_CXX11 "Compile with C++11 enabled." OFF)
 185 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 186 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 187
 188 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 189   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 190 else()
 191   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 192 endif()
 193
 194 option(LLVM_USE_INTEL_JITEVENTS
 195   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 196   OFF)
 197
 198 if( LLVM_USE_INTEL_JITEVENTS )
 199   # Verify we are on a supported platform
 200   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 201     message(FATAL_ERROR
 202       "Intel JIT API support is available on Linux and Windows only.")
 203   endif()
 204 endif( LLVM_USE_INTEL_JITEVENTS )
 205
 206 option(LLVM_USE_OPROFILE
 207   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 208
 209 # If enabled, verify we are on a platform that supports oprofile.
 210 if( LLVM_USE_OPROFILE )
 211   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 212     message(FATAL_ERROR "OProfile support is available on Linux only.")
 213   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 214 endif( LLVM_USE_OPROFILE )
 215
 216 set(LLVM_USE_SANITIZER "" CACHE STRING
 217   "Define the sanitizer used to build binaries and tests.")
 218
 219 option(LLVM_USE_SPLIT_DWARF
 220   "Use -gsplit-dwarf when compiling llvm." OFF)
 221
 222 # Define an option controlling whether we should build for 32-bit on 64-bit
 223 # platforms, where supported.
 224 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 225   # TODO: support other platforms and toolchains.
 226   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 227 endif()
 228
 229 # Define the default arguments to use with 'lit', and an option for the user to
 230 # override.
 231 set(LIT_ARGS_DEFAULT "-sv")
 232 if (MSVC OR XCODE)
 233   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 234 endif()
 235 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 236
 237 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 238 if( WIN32 AND NOT CYGWIN )
 239   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 240 endif()
 241
 242 # Define options to control the inclusion and default build behavior for
 243 # components which may not strictly be necessary (tools, examples, and tests).
 244 #
 245 # This is primarily to support building smaller or faster project files.
 246 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 247 option(LLVM_BUILD_TOOLS
 248   "Build the LLVM tools. If OFF, just generate build targets." ON)
 249
 250 option(LLVM_BUILD_RUNTIME
 251   "Build the LLVM runtime libraries." ON)
 252 option(LLVM_BUILD_EXAMPLES
 253   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 254 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 255
 256 option(LLVM_BUILD_TESTS
 257   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 258 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 259
 260 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 261 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 262 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 263
 264 # All options referred to from HandleLLVMOptions have to be specified
 265 # BEFORE this include, otherwise options will not be correctly set on
 266 # first cmake run
 267 include(config-ix)
 268
 269 # By default, we target the host, but this can be overridden at CMake
 270 # invocation time.
 271 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 272   "Default target for which LLVM will generate code." )
 273 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 274
 275 include(HandleLLVMOptions)
 276
 277 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 278 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 279 include(FindPythonInterp)
 280 if( NOT PYTHONINTERP_FOUND )
 281   message(FATAL_ERROR
 282 "Unable to find Python interpreter, required for builds and testing.
 283
 284 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 285 endif()
 286
 287 ######
 288 # LLVMBuild Integration
 289 #
 290 # We use llvm-build to generate all the data required by the CMake based
 291 # build system in one swoop:
 292 #
 293 #  - We generate a file (a CMake fragment) in the object root which contains
 294 #    all the definitions that are required by CMake.
 295 #
 296 #  - We generate the library table used by llvm-config.
 297 #
 298 #  - We generate the dependencies for the CMake fragment, so that we will
 299 #    automatically reconfigure outselves.
 300
 301 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 302 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 303   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 304 set(LLVMBUILDCMAKEFRAG
 305   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 306
 307 # Create the list of optional components that are enabled
 308 if (LLVM_USE_INTEL_JITEVENTS)
 309   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 310 endif (LLVM_USE_INTEL_JITEVENTS)
 311 if (LLVM_USE_OPROFILE)
 312   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 313 endif (LLVM_USE_OPROFILE)
 314
 315 message(STATUS "Constructing LLVMBuild project information")
 316 execute_process(
 317   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 318             --native-target "${LLVM_NATIVE_ARCH}"
 319             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 320             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 321             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 322             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 323             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 324             ERROR_VARIABLE LLVMBUILDERRORS
 325             OUTPUT_STRIP_TRAILING_WHITESPACE
 326             ERROR_STRIP_TRAILING_WHITESPACE
 327   RESULT_VARIABLE LLVMBUILDRESULT)
 328
 329 # On Win32, CMake doesn't properly handle piping the default output/error
 330 # streams into the GUI console. So, we explicitly catch and report them.
 331 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 332   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 333 endif()
 334 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 335   message(FATAL_ERROR
 336     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 337 endif()
 338
 339 # Include the generated CMake fragment. This will define properties from the
 340 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 341 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 342 # files change.
 343 include(${LLVMBUILDCMAKEFRAG})
 344
 345 ######
 346
 347 # Configure all of the various header file fragments LLVM uses which depend on
 348 # configuration variables.
 349 set(LLVM_ENUM_TARGETS "")
 350 set(LLVM_ENUM_ASM_PRINTERS "")
 351 set(LLVM_ENUM_ASM_PARSERS "")
 352 set(LLVM_ENUM_DISASSEMBLERS "")
 353 foreach(t ${LLVM_TARGETS_TO_BUILD})
 354   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 355
 356   list(FIND LLVM_ALL_TARGETS ${t} idx)
 357   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 358   if( idx LESS 0 AND idy LESS 0 )
 359     message(FATAL_ERROR "The target `${t}' does not exist.
 360     It should be one of\n${LLVM_ALL_TARGETS}")
 361   else()
 362     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 363   endif()
 364
 365   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 366   if( asmp_file )
 367     set(LLVM_ENUM_ASM_PRINTERS
 368       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 369   endif()
 370   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 371     set(LLVM_ENUM_ASM_PARSERS
 372       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 373   endif()
 374   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 375     set(LLVM_ENUM_DISASSEMBLERS
 376       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 377   endif()
 378 endforeach(t)
 379
 380 # Produce the target definition files, which provide a way for clients to easily
 381 # include various classes of targets.
 382 configure_file(
 383   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 384   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 385   )
 386 configure_file(
 387   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 388   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 389   )
 390 configure_file(
 391   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 392   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 393   )
 394 configure_file(
 395   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 396   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 397   )
 398
 399 # Configure the three LLVM configuration header files.
 400 configure_file(
 401   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 402   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 403 configure_file(
 404   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 405   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 406 configure_file(
 407   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 408   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 409
 410 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 411 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 412 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 413
 414 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 415
 416 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 417
 418 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 419   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 420   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 421   include_directories("/usr/local/include")
 422   link_directories("/usr/local/lib")
 423 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 424
 425 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 426    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 427 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 428
 429 # Make sure we don't get -rdynamic in every binary. For those that need it,
 430 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 431 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 432
 433 include(AddLLVM)
 434 include(TableGen)
 435
 436 if( MINGW )
 437   # People report that -O3 is unreliable on MinGW. The traditional
 438   # build also uses -O2 for that reason:
 439   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 440 endif()
 441
 442 # Put this before tblgen. Else we have a circular dependence.
 443 add_subdirectory(lib/Support)
 444 add_subdirectory(lib/TableGen)
 445
 446 add_subdirectory(utils/TableGen)
 447
 448 add_subdirectory(include/llvm)
 449
 450 add_subdirectory(lib)
 451
 452 add_subdirectory(utils/FileCheck)
 453 add_subdirectory(utils/FileUpdate)
 454 add_subdirectory(utils/count)
 455 add_subdirectory(utils/not)
 456 add_subdirectory(utils/llvm-lit)
 457 add_subdirectory(utils/yaml-bench)
 458
 459 add_subdirectory(projects)
 460
 461 if( LLVM_INCLUDE_TOOLS )
 462   add_subdirectory(tools)
 463 endif()
 464
 465 if( LLVM_INCLUDE_EXAMPLES )
 466   add_subdirectory(examples)
 467 endif()
 468
 469 if( LLVM_INCLUDE_TESTS )
 470   add_subdirectory(test)
 471   add_subdirectory(utils/unittest)
 472   add_subdirectory(unittests)
 473   if (MSVC)
 474     # This utility is used to prevent crashing tests from calling Dr. Watson on
 475     # Windows.
 476     add_subdirectory(utils/KillTheDoctor)
 477   endif()
 478
 479   # Add a global check rule now that all subdirectories have been traversed
 480   # and we know the total set of lit testsuites.
 481   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 482   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 483   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 484   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 485   add_lit_target(check-all
 486     "Running all regression tests"
 487     ${LLVM_LIT_TESTSUITES}
 488     PARAMS ${LLVM_LIT_PARAMS}
 489     DEPENDS ${LLVM_LIT_DEPENDS}
 490     ARGS ${LLVM_LIT_EXTRA_ARGS}
 491     )
 492 endif()
 493
 494 if (LLVM_INCLUDE_DOCS)
 495   add_subdirectory(docs)
 496 endif()
 497
 498 add_subdirectory(cmake/modules)
 499
 500 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 501   install(DIRECTORY include/
 502     DESTINATION include
 503     FILES_MATCHING
 504     PATTERN "*.def"
 505     PATTERN "*.h"
 506     PATTERN "*.td"
 507     PATTERN "*.inc"
 508     PATTERN "LICENSE.TXT"
 509     PATTERN ".svn" EXCLUDE
 510     )
 511
 512   install(DIRECTORY ${LLVM_INCLUDE_DIR}/
 513     DESTINATION include
 514     FILES_MATCHING
 515     PATTERN "*.def"
 516     PATTERN "*.h"
 517     PATTERN "*.gen"
 518     PATTERN "*.inc"
 519     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 520     PATTERN "CMakeFiles" EXCLUDE
 521     PATTERN ".svn" EXCLUDE
 522     )
 523 endif()
 524
 525 # Workaround for MSVS10 to avoid the Dialog Hell
 526 # FIXME: This could be removed with future version of CMake.
 527 if(MSVC_VERSION EQUAL 1600)
 528   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 529   if( EXISTS "${LLVM_SLN_FILENAME}" )
 530     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 531   endif()
 532 endif()
 533