CMake: Added notes pointing to the LLVM CMake documentation.
[opencl/llvm.git] / CMakeLists.txt
1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
3 project(LLVM)
4 cmake_minimum_required(VERSION 2.6.1)
6 set(PACKAGE_NAME llvm)
7 set(PACKAGE_VERSION 2.6svn)
8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
12   message(FATAL_ERROR "In-source builds are not allowed.
13 CMake would overwrite the makefiles distributed with LLVM.
14 Please create a directory and run cmake from there, passing the path
15 to this source directory as the last argument.
16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
17 Please delete them.")
18 endif()
20 include(FindPerl)
22 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
23 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
24 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
25 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
26 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
28 set(LLVM_ALL_TARGETS
29   Alpha
30   ARM
31   CBackend
32   CellSPU
33   CppBackend
34   IA64
35   Mips
36   MSIL
37   PIC16
38   PowerPC
39   Sparc
40   X86
41   XCore
42   )
44 # List of targets whose asmprinters need to be forced to link
45 # into executables on some platforms (i.e. Windows):
46 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
48 if( MSVC )
49   set(LLVM_TARGETS_TO_BUILD X86
50     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
51 else( MSVC )
52   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
53     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
54 endif( MSVC )
56 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
58 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
59   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
60 endif()
62 foreach(c ${LLVM_TARGETS_TO_BUILD})
63   list(FIND LLVM_ALL_TARGETS ${c} idx)
64   if( idx LESS 0 )
65     message(FATAL_ERROR "The target `${c}' does not exists.
66     It should be one of\n${LLVM_ALL_TARGETS}")
67   endif()
68 endforeach(c)
70 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
72 # Add path for custom modules
73 set(CMAKE_MODULE_PATH
74   ${CMAKE_MODULE_PATH}
75   "${LLVM_MAIN_SRC_DIR}/cmake"
76   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
77   )
79 include(AddLLVMDefinitions)
81 if(WIN32)
82   if(CYGWIN)
83     set(LLVM_ON_WIN32 0)
84     set(LLVM_ON_UNIX 1)
85   else(CYGWIN)
86     set(LLVM_ON_WIN32 1)
87     set(LLVM_ON_UNIX 0)
88   endif(CYGWIN)
89   set(LTDL_SHLIB_EXT ".dll")
90   set(EXEEXT ".exe")
91   # Maximum path length is 160 for non-unicode paths
92   set(MAXPATHLEN 160)
93 else(WIN32)
94   if(UNIX)
95     set(LLVM_ON_WIN32 0)
96     set(LLVM_ON_UNIX 1)
97     set(LTDL_SHLIB_EXT ".so")
98     set(EXEEXT "")
99     # FIXME: Maximum path length is currently set to 'safe' fixed value
100     set(MAXPATHLEN 2024)
101   else(UNIX)
102     MESSAGE(SEND_ERROR "Unable to determine platform")
103   endif(UNIX)
104 endif(WIN32)
106 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
107   set(HAVE_LLVM_CONFIG 1)
108 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
110 include(config-ix)
112 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
114 if( LLVM_ENABLE_PIC )
115   if( SUPPORTS_FPIC_FLAG )
116     message(STATUS "Building with -fPIC")
117     add_llvm_definitions(-fPIC)
118   else( SUPPORTS_FPIC_FLAG )
119     message(STATUS "Warning: -fPIC not supported.")
120   endif()
121 endif()
123 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
124 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
125 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
127 # set(CMAKE_VERBOSE_MAKEFILE true)
129 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
130 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
132 set(LLVM_PLO_FLAGS "" CACHE
133   STRING "Flags for creating partially linked objects.")
135 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
136   # TODO: support other platforms and toolchains.
137   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
138   if( LLVM_BUILD_32_BITS )
139     message(STATUS "Building 32 bits executables and libraries.")
140     add_llvm_definitions( -m32 )
141     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
142     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
143     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
144   endif( LLVM_BUILD_32_BITS )
145 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
147 if( MSVC )
148   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
149   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
150   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
151   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
152   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
153 endif( MSVC )
155 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
157 include(AddLLVM)
158 include(AddPartiallyLinkedObject)
159 include(TableGen)
161 add_subdirectory(lib/Support)
162 add_subdirectory(lib/System)
164 # Everything else depends on Support and System:
165 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
167 set(LLVM_TABLEGEN "tblgen" CACHE
168   STRING "Native TableGen executable. Saves building one when cross-compiling.")
170 add_subdirectory(utils/TableGen)
172 if( CMAKE_CROSSCOMPILING )
173   # This adds a dependency on target `tblgen', so must go after utils/TableGen
174   include( CrossCompileLLVM )
175 endif( CMAKE_CROSSCOMPILING )
177 add_subdirectory(include/llvm)
179 add_subdirectory(lib/VMCore)
180 add_subdirectory(lib/CodeGen)
181 add_subdirectory(lib/CodeGen/SelectionDAG)
182 add_subdirectory(lib/CodeGen/AsmPrinter)
183 add_subdirectory(lib/Bitcode/Reader)
184 add_subdirectory(lib/Bitcode/Writer)
185 add_subdirectory(lib/Transforms/Utils)
186 add_subdirectory(lib/Transforms/Instrumentation)
187 add_subdirectory(lib/Transforms/Scalar)
188 add_subdirectory(lib/Transforms/IPO)
189 add_subdirectory(lib/Transforms/Hello)
190 add_subdirectory(lib/Linker)
191 add_subdirectory(lib/Analysis)
192 add_subdirectory(lib/Analysis/IPA)
194 foreach(t ${LLVM_TARGETS_TO_BUILD})
195   message(STATUS "Targeting ${t}")
196   add_subdirectory(lib/Target/${t})
197   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
198     add_subdirectory(lib/Target/${t}/AsmPrinter)
199   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
200 endforeach(t)
202 add_subdirectory(lib/ExecutionEngine)
203 add_subdirectory(lib/ExecutionEngine/Interpreter)
204 add_subdirectory(lib/ExecutionEngine/JIT)
205 add_subdirectory(lib/Target)
206 add_subdirectory(lib/AsmParser)
207 add_subdirectory(lib/Debugger)
208 add_subdirectory(lib/Archive)
210 add_subdirectory(projects)
211 add_subdirectory(tools)
213 add_subdirectory(examples)
215 install(DIRECTORY include
216   DESTINATION .
217   PATTERN ".svn" EXCLUDE
218   PATTERN "*.cmake" EXCLUDE
219   PATTERN "*.in" EXCLUDE
220   )
222 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
223   DESTINATION .
224   )
226 # TODO: make and install documentation.