CMake: defines and uses macro add_llvm_definitions for keeping track
[opencl/llvm.git] / CMakeLists.txt
1 project(LLVM)
2 cmake_minimum_required(VERSION 2.6.1)
4 set(PACKAGE_NAME llvm)
5 set(PACKAGE_VERSION 2.6svn)
6 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
7 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
9 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
10   message(FATAL_ERROR "In-source builds are not allowed.
11 CMake would overwrite the makefiles distributed with LLVM.
12 Please create a directory and run cmake from there, passing the path
13 to this source directory as the last argument.
14 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
15 Please delete them.")
16 endif()
18 include(FindPerl)
20 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
21 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
22 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
23 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
24 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
26 set(LLVM_ALL_TARGETS
27   Alpha
28   ARM
29   CBackend
30   CellSPU
31   CppBackend
32   IA64
33   Mips
34   MSIL
35   PIC16
36   PowerPC
37   Sparc
38   X86
39   XCore
40   )
42 # List of targets whose asmprinters need to be forced to link
43 # into executables on some platforms (i.e. Windows):
44 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
46 if( MSVC )
47   set(LLVM_TARGETS_TO_BUILD X86
48     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
49 else( MSVC )
50   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
51     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
52 endif( MSVC )
54 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
56 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
57   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
58 endif()
60 foreach(c ${LLVM_TARGETS_TO_BUILD})
61   list(FIND LLVM_ALL_TARGETS ${c} idx)
62   if( idx LESS 0 )
63     message(FATAL_ERROR "The target `${c}' does not exists.
64     It should be one of\n${LLVM_ALL_TARGETS}")
65   endif()
66 endforeach(c)
68 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
70 # Add path for custom modules
71 set(CMAKE_MODULE_PATH
72   ${CMAKE_MODULE_PATH}
73   "${LLVM_MAIN_SRC_DIR}/cmake"
74   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
75   )
77 include(AddLLVMDefinitions)
79 if(WIN32)
80   if(CYGWIN)
81     set(LLVM_ON_WIN32 0)
82     set(LLVM_ON_UNIX 1)
83   else(CYGWIN)
84     set(LLVM_ON_WIN32 1)
85     set(LLVM_ON_UNIX 0)
86   endif(CYGWIN)
87   set(LTDL_SHLIB_EXT ".dll")
88   set(EXEEXT ".exe")
89   # Maximum path length is 160 for non-unicode paths
90   set(MAXPATHLEN 160)
91 else(WIN32)
92   if(UNIX)
93     set(LLVM_ON_WIN32 0)
94     set(LLVM_ON_UNIX 1)
95     set(LTDL_SHLIB_EXT ".so")
96     set(EXEEXT "")
97     # FIXME: Maximum path length is currently set to 'safe' fixed value
98     set(MAXPATHLEN 2024)
99   else(UNIX)
100     MESSAGE(SEND_ERROR "Unable to determine platform")
101   endif(UNIX)
102 endif(WIN32)
104 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
105   set(HAVE_LLVM_CONFIG 1)
106 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
108 include(config-ix)
110 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
112 if( LLVM_ENABLE_PIC )
113   if( SUPPORTS_FPIC_FLAG )
114     message(STATUS "Building with -fPIC")
115     add_llvm_definitions(-fPIC)
116   else( SUPPORTS_FPIC_FLAG )
117     message(STATUS "Warning: -fPIC not supported.")
118   endif()
119 endif()
121 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
122 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
123 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
125 # set(CMAKE_VERBOSE_MAKEFILE true)
127 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
128 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
130 set(LLVM_PLO_FLAGS "" CACHE
131   STRING "Flags for creating partially linked objects.")
133 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
134   # TODO: support other platforms and toolchains.
135   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
136   if( LLVM_BUILD_32_BITS )
137     message(STATUS "Building 32 bits executables and libraries.")
138     add_llvm_definitions( -m32 )
139     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
140     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
141     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
142   endif( LLVM_BUILD_32_BITS )
143 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
145 if( MSVC )
146   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
147   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
148   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
149   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
150   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
151 endif( MSVC )
153 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
155 include(AddLLVM)
156 include(AddPartiallyLinkedObject)
157 include(TableGen)
159 add_subdirectory(lib/Support)
160 add_subdirectory(lib/System)
162 # Everything else depends on Support and System:
163 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
165 set(LLVM_TABLEGEN "tblgen" CACHE
166   STRING "Native TableGen executable. Saves building one when cross-compiling.")
168 add_subdirectory(utils/TableGen)
170 if( CMAKE_CROSSCOMPILING )
171   # This adds a dependency on target `tblgen', so must go after utils/TableGen
172   include( CrossCompileLLVM )
173 endif( CMAKE_CROSSCOMPILING )
175 add_subdirectory(include/llvm)
177 add_subdirectory(lib/VMCore)
178 add_subdirectory(lib/CodeGen)
179 add_subdirectory(lib/CodeGen/SelectionDAG)
180 add_subdirectory(lib/CodeGen/AsmPrinter)
181 add_subdirectory(lib/Bitcode/Reader)
182 add_subdirectory(lib/Bitcode/Writer)
183 add_subdirectory(lib/Transforms/Utils)
184 add_subdirectory(lib/Transforms/Instrumentation)
185 add_subdirectory(lib/Transforms/Scalar)
186 add_subdirectory(lib/Transforms/IPO)
187 add_subdirectory(lib/Transforms/Hello)
188 add_subdirectory(lib/Linker)
189 add_subdirectory(lib/Analysis)
190 add_subdirectory(lib/Analysis/IPA)
192 foreach(t ${LLVM_TARGETS_TO_BUILD})
193   message(STATUS "Targeting ${t}")
194   add_subdirectory(lib/Target/${t})
195   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
196     add_subdirectory(lib/Target/${t}/AsmPrinter)
197   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
198 endforeach(t)
200 add_subdirectory(lib/ExecutionEngine)
201 add_subdirectory(lib/ExecutionEngine/Interpreter)
202 add_subdirectory(lib/ExecutionEngine/JIT)
203 add_subdirectory(lib/Target)
204 add_subdirectory(lib/AsmParser)
205 add_subdirectory(lib/Debugger)
206 add_subdirectory(lib/Archive)
208 add_subdirectory(projects)
209 add_subdirectory(tools)
211 add_subdirectory(examples)
213 install(DIRECTORY include
214   DESTINATION .
215   PATTERN ".svn" EXCLUDE
216   PATTERN "*.cmake" EXCLUDE
217   PATTERN "*.in" EXCLUDE
218   )
220 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
221   DESTINATION .
222   )
224 # TODO: make and install documentation.