CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4 project(LLVM)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 5)
  15
  16 if (NOT PACKAGE_VERSION)
  17   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  18 endif()
  19
  20 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  21
  22 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  23 if ( LLVM_USE_FOLDERS )
  24   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  25 endif()
  26
  27 include(VersionFromVCS)
  28
  29 option(LLVM_APPEND_VC_REV
  30   "Append the version control system revision id to LLVM version" OFF)
  31
  32 if( LLVM_APPEND_VC_REV )
  33   add_version_info_from_vcs(PACKAGE_VERSION)
  34 endif()
  35
  36 set(PACKAGE_NAME LLVM)
  37 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  38 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  39
  40 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  41   "Default URL where bug reports are to be submitted.")
  42
  43 # Configure CPack.
  44 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  45 set(CPACK_PACKAGE_VENDOR "LLVM")
  46 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  47 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  48 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  50 if(WIN32 AND NOT UNIX)
  51   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  52   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  53   set(CPACK_NSIS_MODIFY_PATH "ON")
  54   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  55   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  56     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  57   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  58     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  59 endif()
  60 include(CPack)
  61
  62 # Sanity check our source directory to make sure that we are not trying to
  63 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  64 # sure that we don't have any stray generated files lying around in the tree
  65 # (which would end up getting picked up by header search, instead of the correct
  66 # versions).
  67 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  68   message(FATAL_ERROR "In-source builds are not allowed.
  69 CMake would overwrite the makefiles distributed with LLVM.
  70 Please create a directory and run cmake from there, passing the path
  71 to this source directory as the last argument.
  72 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  73 Please delete them.")
  74 endif()
  75 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  76   file(GLOB_RECURSE
  77     tablegenned_files_on_include_dir
  78     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  79   file(GLOB_RECURSE
  80     tablegenned_files_on_lib_dir
  81     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  82   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  83     message(FATAL_ERROR "Apparently there is a previous in-source build,
  84 probably as the result of running `configure' and `make' on
  85 ${CMAKE_CURRENT_SOURCE_DIR}.
  86 This may cause problems. The suspicious files are:
  87 ${tablegenned_files_on_lib_dir}
  88 ${tablegenned_files_on_include_dir}
  89 Please clean the source directory.")
  90   endif()
  91 endif()
  92
  93 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  94
  95 # They are used as destination of target generators.
  96 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  97 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
  98
  99 # Each of them corresponds to llvm-config's.
 100 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 101 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 102 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 103 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 104 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 105
 106 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 107 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 108 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 109
 110 set(LLVM_ALL_TARGETS
 111   AArch64
 112   ARM
 113   CppBackend
 114   Hexagon
 115   Mips
 116   MSP430
 117   NVPTX
 118   PowerPC
 119   R600
 120   Sparc
 121   SystemZ
 122   X86
 123   XCore
 124   )
 125
 126 # List of targets with JIT support:
 127 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 128
 129 set(LLVM_TARGETS_TO_BUILD "all"
 130     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 131
 132 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 133   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 134
 135 option(BUILD_SHARED_LIBS
 136   "Build all libraries as shared libraries instead of static" OFF)
 137
 138 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 139 if(LLVM_ENABLE_CBE_PRINTF_A)
 140   set(ENABLE_CBE_PRINTF_A 1)
 141 endif()
 142
 143 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 144 if(LLVM_ENABLE_TIMESTAMPS)
 145   set(ENABLE_TIMESTAMPS 1)
 146 endif()
 147
 148 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 149 if(LLVM_ENABLE_BACKTRACES)
 150   set(ENABLE_BACKTRACES 1)
 151 endif()
 152
 153 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 154 if(LLVM_ENABLE_CRASH_OVERRIDES)
 155   set(ENABLE_CRASH_OVERRIDES 1)
 156 endif()
 157
 158 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 159 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 160 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 161
 162 set(LLVM_TARGET_ARCH "host"
 163   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 164
 165 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 166
 167 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 168
 169 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 170
 171 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 172   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 173 endif()
 174
 175 set(LLVM_TARGETS_TO_BUILD
 176    ${LLVM_TARGETS_TO_BUILD}
 177    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 178 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 179
 180 include(AddLLVMDefinitions)
 181
 182 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 183
 184 # MSVC has a gazillion warnings with this.
 185 if( MSVC )
 186   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 187 else( MSVC )
 188   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 189 endif()
 190
 191 option(LLVM_ENABLE_CXX11 "Compile with C++11 enabled." OFF)
 192 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 193 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 194 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 195
 196 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 197   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 198 else()
 199   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 200 endif()
 201
 202 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 203        "Set to ON to force using an old, unsupported host toolchain." OFF)
 204
 205 option(LLVM_USE_INTEL_JITEVENTS
 206   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 207   OFF)
 208
 209 if( LLVM_USE_INTEL_JITEVENTS )
 210   # Verify we are on a supported platform
 211   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 212     message(FATAL_ERROR
 213       "Intel JIT API support is available on Linux and Windows only.")
 214   endif()
 215 endif( LLVM_USE_INTEL_JITEVENTS )
 216
 217 option(LLVM_USE_OPROFILE
 218   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 219
 220 # If enabled, verify we are on a platform that supports oprofile.
 221 if( LLVM_USE_OPROFILE )
 222   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 223     message(FATAL_ERROR "OProfile support is available on Linux only.")
 224   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 225 endif( LLVM_USE_OPROFILE )
 226
 227 set(LLVM_USE_SANITIZER "" CACHE STRING
 228   "Define the sanitizer used to build binaries and tests.")
 229
 230 option(LLVM_USE_SPLIT_DWARF
 231   "Use -gsplit-dwarf when compiling llvm." OFF)
 232
 233 # Define an option controlling whether we should build for 32-bit on 64-bit
 234 # platforms, where supported.
 235 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 236   # TODO: support other platforms and toolchains.
 237   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 238 endif()
 239
 240 # Define the default arguments to use with 'lit', and an option for the user to
 241 # override.
 242 set(LIT_ARGS_DEFAULT "-sv")
 243 if (MSVC OR XCODE)
 244   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 245 endif()
 246 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 247
 248 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 249 if( WIN32 AND NOT CYGWIN )
 250   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 251 endif()
 252
 253 # Define options to control the inclusion and default build behavior for
 254 # components which may not strictly be necessary (tools, examples, and tests).
 255 #
 256 # This is primarily to support building smaller or faster project files.
 257 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 258 option(LLVM_BUILD_TOOLS
 259   "Build the LLVM tools. If OFF, just generate build targets." ON)
 260
 261 option(LLVM_BUILD_RUNTIME
 262   "Build the LLVM runtime libraries." ON)
 263 option(LLVM_BUILD_EXAMPLES
 264   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 265 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 266
 267 option(LLVM_BUILD_TESTS
 268   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 269 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 270
 271 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 272 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 273 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 274
 275 # All options referred to from HandleLLVMOptions have to be specified
 276 # BEFORE this include, otherwise options will not be correctly set on
 277 # first cmake run
 278 include(config-ix)
 279
 280 # By default, we target the host, but this can be overridden at CMake
 281 # invocation time.
 282 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 283   "Default target for which LLVM will generate code." )
 284 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 285
 286 include(HandleLLVMOptions)
 287
 288 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 289 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 290 include(FindPythonInterp)
 291 if( NOT PYTHONINTERP_FOUND )
 292   message(FATAL_ERROR
 293 "Unable to find Python interpreter, required for builds and testing.
 294
 295 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 296 endif()
 297
 298 ######
 299 # LLVMBuild Integration
 300 #
 301 # We use llvm-build to generate all the data required by the CMake based
 302 # build system in one swoop:
 303 #
 304 #  - We generate a file (a CMake fragment) in the object root which contains
 305 #    all the definitions that are required by CMake.
 306 #
 307 #  - We generate the library table used by llvm-config.
 308 #
 309 #  - We generate the dependencies for the CMake fragment, so that we will
 310 #    automatically reconfigure outselves.
 311
 312 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 313 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 314   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 315 set(LLVMBUILDCMAKEFRAG
 316   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 317
 318 # Create the list of optional components that are enabled
 319 if (LLVM_USE_INTEL_JITEVENTS)
 320   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 321 endif (LLVM_USE_INTEL_JITEVENTS)
 322 if (LLVM_USE_OPROFILE)
 323   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 324 endif (LLVM_USE_OPROFILE)
 325
 326 message(STATUS "Constructing LLVMBuild project information")
 327 execute_process(
 328   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 329             --native-target "${LLVM_NATIVE_ARCH}"
 330             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 331             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 332             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 333             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 334             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 335             ERROR_VARIABLE LLVMBUILDERRORS
 336             OUTPUT_STRIP_TRAILING_WHITESPACE
 337             ERROR_STRIP_TRAILING_WHITESPACE
 338   RESULT_VARIABLE LLVMBUILDRESULT)
 339
 340 # On Win32, CMake doesn't properly handle piping the default output/error
 341 # streams into the GUI console. So, we explicitly catch and report them.
 342 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 343   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 344 endif()
 345 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 346   message(FATAL_ERROR
 347     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 348 endif()
 349
 350 # Include the generated CMake fragment. This will define properties from the
 351 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 352 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 353 # files change.
 354 include(${LLVMBUILDCMAKEFRAG})
 355
 356 ######
 357
 358 # Configure all of the various header file fragments LLVM uses which depend on
 359 # configuration variables.
 360 set(LLVM_ENUM_TARGETS "")
 361 set(LLVM_ENUM_ASM_PRINTERS "")
 362 set(LLVM_ENUM_ASM_PARSERS "")
 363 set(LLVM_ENUM_DISASSEMBLERS "")
 364 foreach(t ${LLVM_TARGETS_TO_BUILD})
 365   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 366
 367   list(FIND LLVM_ALL_TARGETS ${t} idx)
 368   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 369   if( idx LESS 0 AND idy LESS 0 )
 370     message(FATAL_ERROR "The target `${t}' does not exist.
 371     It should be one of\n${LLVM_ALL_TARGETS}")
 372   else()
 373     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 374   endif()
 375
 376   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 377   if( asmp_file )
 378     set(LLVM_ENUM_ASM_PRINTERS
 379       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 380   endif()
 381   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 382     set(LLVM_ENUM_ASM_PARSERS
 383       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 384   endif()
 385   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 386     set(LLVM_ENUM_DISASSEMBLERS
 387       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 388   endif()
 389 endforeach(t)
 390
 391 # Produce the target definition files, which provide a way for clients to easily
 392 # include various classes of targets.
 393 configure_file(
 394   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 395   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 396   )
 397 configure_file(
 398   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 399   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 400   )
 401 configure_file(
 402   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 403   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 404   )
 405 configure_file(
 406   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 407   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 408   )
 409
 410 # Configure the three LLVM configuration header files.
 411 configure_file(
 412   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 413   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 414 configure_file(
 415   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 416   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 417 configure_file(
 418   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 419   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 420
 421 # They are not referenced. See set_output_directory().
 422 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 423 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 424 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 425
 426 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 427 if (APPLE)
 428   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 429   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 430 else(UNIX)
 431   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 432     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 433   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 434 endif()
 435
 436 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 437
 438 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 439
 440 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 441   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 442   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 443   include_directories("/usr/local/include")
 444   link_directories("/usr/local/lib")
 445 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 446
 447 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 448    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 449 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 450
 451 # Make sure we don't get -rdynamic in every binary. For those that need it,
 452 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 453 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 454
 455 include(AddLLVM)
 456 include(TableGen)
 457
 458 if( MINGW )
 459   # People report that -O3 is unreliable on MinGW. The traditional
 460   # build also uses -O2 for that reason:
 461   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 462 endif()
 463
 464 # Put this before tblgen. Else we have a circular dependence.
 465 add_subdirectory(lib/Support)
 466 add_subdirectory(lib/TableGen)
 467
 468 add_subdirectory(utils/TableGen)
 469
 470 add_subdirectory(include/llvm)
 471
 472 add_subdirectory(lib)
 473
 474 add_subdirectory(utils/FileCheck)
 475 add_subdirectory(utils/FileUpdate)
 476 add_subdirectory(utils/count)
 477 add_subdirectory(utils/not)
 478 add_subdirectory(utils/llvm-lit)
 479 add_subdirectory(utils/yaml-bench)
 480
 481 if(LLVM_INCLUDE_TESTS)
 482   add_subdirectory(utils/unittest)
 483 endif()
 484
 485 add_subdirectory(projects)
 486
 487 if( LLVM_INCLUDE_TOOLS )
 488   add_subdirectory(tools)
 489 endif()
 490
 491 if( LLVM_INCLUDE_EXAMPLES )
 492   add_subdirectory(examples)
 493 endif()
 494
 495 if( LLVM_INCLUDE_TESTS )
 496   add_subdirectory(test)
 497   add_subdirectory(unittests)
 498   if (MSVC)
 499     # This utility is used to prevent crashing tests from calling Dr. Watson on
 500     # Windows.
 501     add_subdirectory(utils/KillTheDoctor)
 502   endif()
 503
 504   # Add a global check rule now that all subdirectories have been traversed
 505   # and we know the total set of lit testsuites.
 506   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 507   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 508   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 509   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 510   add_lit_target(check-all
 511     "Running all regression tests"
 512     ${LLVM_LIT_TESTSUITES}
 513     PARAMS ${LLVM_LIT_PARAMS}
 514     DEPENDS ${LLVM_LIT_DEPENDS}
 515     ARGS ${LLVM_LIT_EXTRA_ARGS}
 516     )
 517 endif()
 518
 519 if (LLVM_INCLUDE_DOCS)
 520   add_subdirectory(docs)
 521 endif()
 522
 523 add_subdirectory(cmake/modules)
 524
 525 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 526   install(DIRECTORY include/llvm include/llvm-c
 527     DESTINATION include
 528     FILES_MATCHING
 529     PATTERN "*.def"
 530     PATTERN "*.h"
 531     PATTERN "*.td"
 532     PATTERN "*.inc"
 533     PATTERN "LICENSE.TXT"
 534     PATTERN ".svn" EXCLUDE
 535     )
 536
 537   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 538     DESTINATION include
 539     FILES_MATCHING
 540     PATTERN "*.def"
 541     PATTERN "*.h"
 542     PATTERN "*.gen"
 543     PATTERN "*.inc"
 544     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 545     PATTERN "CMakeFiles" EXCLUDE
 546     PATTERN ".svn" EXCLUDE
 547     )
 548 endif()
 549
 550 # Workaround for MSVS10 to avoid the Dialog Hell
 551 # FIXME: This could be removed with future version of CMake.
 552 if(MSVC_VERSION EQUAL 1600)
 553   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 554   if( EXISTS "${LLVM_SLN_FILENAME}" )
 555     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 556   endif()
 557 endif()
 558