c71f74e67c7e103632ae0793c32898078b852c37
[opencl/llvm.git] / CMakeLists.txt
1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
3 project(LLVM)
4 cmake_minimum_required(VERSION 2.8)
6 # Add path for custom modules
7 set(CMAKE_MODULE_PATH
8   ${CMAKE_MODULE_PATH}
9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
11   )
13 set(LLVM_VERSION_MAJOR 3)
14 set(LLVM_VERSION_MINOR 4)
16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
19 if ( LLVM_USE_FOLDERS )
20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
21 endif()
23 include(VersionFromVCS)
25 option(LLVM_APPEND_VC_REV
26   "Append the version control system revision id to LLVM version" OFF)
28 if( LLVM_APPEND_VC_REV )
29   add_version_info_from_vcs(PACKAGE_VERSION)
30 endif()
32 set(PACKAGE_NAME LLVM)
33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
36 # Sanity check our source directory to make sure that we are not trying to
37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
38 # sure that we don't have any stray generated files lying around in the tree
39 # (which would end up getting picked up by header search, instead of the correct
40 # versions).
41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
42   message(FATAL_ERROR "In-source builds are not allowed.
43 CMake would overwrite the makefiles distributed with LLVM.
44 Please create a directory and run cmake from there, passing the path
45 to this source directory as the last argument.
46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
47 Please delete them.")
48 endif()
49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
50   file(GLOB_RECURSE
51     tablegenned_files_on_include_dir
52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
53   file(GLOB_RECURSE
54     tablegenned_files_on_lib_dir
55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
57     message(FATAL_ERROR "Apparently there is a previous in-source build,
58 probably as the result of running `configure' and `make' on
59 ${CMAKE_CURRENT_SOURCE_DIR}.
60 This may cause problems. The suspicious files are:
61 ${tablegenned_files_on_lib_dir}
62 ${tablegenned_files_on_include_dir}
63 Please clean the source directory.")
64   endif()
65 endif()
67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
76 set(LLVM_ALL_TARGETS
77   AArch64
78   ARM
79   CppBackend
80   Hexagon
81   Mips
82   MSP430
83   NVPTX
84   PowerPC
85   R600
86   Sparc
87   SystemZ
88   X86
89   XCore
90   )
92 # List of targets with JIT support:
93 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
95 set(LLVM_TARGETS_TO_BUILD "all"
96     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
98 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
99   CACHE STRING "Semicolon-separated list of experimental targets to build.")
101 option(BUILD_SHARED_LIBS
102   "Build all libraries as shared libraries instead of static" OFF)
104 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
105 if(LLVM_ENABLE_CBE_PRINTF_A)
106   set(ENABLE_CBE_PRINTF_A 1)
107 endif()
109 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
110 if(LLVM_ENABLE_TIMESTAMPS)
111   set(ENABLE_TIMESTAMPS 1)
112 endif()
114 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
115 if(LLVM_ENABLE_BACKTRACES)
116   set(ENABLE_BACKTRACES 1)
117 endif()
119 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
120 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
121 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
123 set(LLVM_TARGET_ARCH "host"
124   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
126 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
128 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
130 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
132 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
133   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
134 endif()
136 set(LLVM_TARGETS_TO_BUILD
137    ${LLVM_TARGETS_TO_BUILD}
138    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
139 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
141 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
143 include(AddLLVMDefinitions)
145 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
147 # MSVC has a gazillion warnings with this.
148 if( MSVC )
149   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
150 else( MSVC )
151   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
152 endif()
154 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
155 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
157 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
158   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
159 else()
160   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
161 endif()
163 option(LLVM_USE_INTEL_JITEVENTS
164   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
165   OFF)
167 if( LLVM_USE_INTEL_JITEVENTS )
168   # Verify we are on a supported platform
169   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
170     message(FATAL_ERROR
171       "Intel JIT API support is available on Linux and Windows only.")
172   endif()
173 endif( LLVM_USE_INTEL_JITEVENTS )
175 option(LLVM_USE_OPROFILE
176   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
178 # If enabled, verify we are on a platform that supports oprofile.
179 if( LLVM_USE_OPROFILE )
180   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
181     message(FATAL_ERROR "OProfile support is available on Linux only.") 
182   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
183 endif( LLVM_USE_OPROFILE )
185 set(LLVM_USE_SANITIZER "" CACHE STRING
186   "Define the sanitizer used to build binaries and tests.")
188 option(LLVM_USE_SPLIT_DWARF
189   "Use -gsplit-dwarf when compiling llvm." OFF)
191 # Define an option controlling whether we should build for 32-bit on 64-bit
192 # platforms, where supported.
193 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
194   # TODO: support other platforms and toolchains.
195   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
196 endif()
198 # Define the default arguments to use with 'lit', and an option for the user to
199 # override.
200 set(LIT_ARGS_DEFAULT "-sv")
201 if (MSVC OR XCODE)
202   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
203 endif()
204 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
206 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
207 if( WIN32 AND NOT CYGWIN )
208   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
209 endif()
211 # Define options to control the inclusion and default build behavior for
212 # components which may not strictly be necessary (tools, runtime, examples, and
213 # tests).
215 # This is primarily to support building smaller or faster project files.
216 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
217 option(LLVM_BUILD_TOOLS
218   "Build the LLVM tools. If OFF, just generate build targets." ON)
220 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
221 option(LLVM_BUILD_RUNTIME
222   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
224 option(LLVM_BUILD_EXAMPLES
225   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
226 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
228 option(LLVM_BUILD_TESTS
229   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
230 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
232 # All options referred to from HandleLLVMOptions have to be specified
233 # BEFORE this include, otherwise options will not be correctly set on
234 # first cmake run
235 include(config-ix)
237 # By default, we target the host, but this can be overridden at CMake
238 # invocation time.
239 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
240   "Default target for which LLVM will generate code." )
241 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
243 include(HandleLLVMOptions)
245 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
246 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5 2.4)
247 include(FindPythonInterp)
248 if( NOT PYTHONINTERP_FOUND )
249   message(FATAL_ERROR
250 "Unable to find Python interpreter, required for builds and testing.
252 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
253 endif()
255 ######
256 # LLVMBuild Integration
258 # We use llvm-build to generate all the data required by the CMake based
259 # build system in one swoop:
261 #  - We generate a file (a CMake fragment) in the object root which contains
262 #    all the definitions that are required by CMake.
264 #  - We generate the library table used by llvm-config.
266 #  - We generate the dependencies for the CMake fragment, so that we will
267 #    automatically reconfigure outselves.
269 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
270 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
271   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
272 set(LLVMBUILDCMAKEFRAG
273   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
275 # Create the list of optional components that are enabled
276 if (LLVM_USE_INTEL_JITEVENTS)
277   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
278 endif (LLVM_USE_INTEL_JITEVENTS)
279 if (LLVM_USE_OPROFILE)
280   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
281 endif (LLVM_USE_OPROFILE)
283 message(STATUS "Constructing LLVMBuild project information")
284 execute_process(
285   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
286             --native-target "${LLVM_NATIVE_ARCH}"
287             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
288             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
289             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
290             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
291             OUTPUT_VARIABLE LLVMBUILDOUTPUT
292             ERROR_VARIABLE LLVMBUILDERRORS
293             OUTPUT_STRIP_TRAILING_WHITESPACE
294             ERROR_STRIP_TRAILING_WHITESPACE
295   RESULT_VARIABLE LLVMBUILDRESULT)
297 # On Win32, CMake doesn't properly handle piping the default output/error
298 # streams into the GUI console. So, we explicitly catch and report them.
299 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
300   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
301 endif()
302 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
303   message(FATAL_ERROR
304     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
305 endif()
307 # Include the generated CMake fragment. This will define properties from the
308 # LLVMBuild files in a format which is easy to consume from CMake, and will add
309 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
310 # files change.
311 include(${LLVMBUILDCMAKEFRAG})
313 ######
315 # Configure all of the various header file fragments LLVM uses which depend on
316 # configuration variables.
317 set(LLVM_ENUM_TARGETS "")
318 set(LLVM_ENUM_ASM_PRINTERS "")
319 set(LLVM_ENUM_ASM_PARSERS "")
320 set(LLVM_ENUM_DISASSEMBLERS "")
321 foreach(t ${LLVM_TARGETS_TO_BUILD})
322   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
324   list(FIND LLVM_ALL_TARGETS ${t} idx)
325   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
326   if( idx LESS 0 AND idy LESS 0 )
327     message(FATAL_ERROR "The target `${t}' does not exist.
328     It should be one of\n${LLVM_ALL_TARGETS}")
329   else()
330     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
331   endif()
333   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
334   if( asmp_file )
335     set(LLVM_ENUM_ASM_PRINTERS
336       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
337   endif()
338   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
339     set(LLVM_ENUM_ASM_PARSERS
340       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
341   endif()
342   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
343     set(LLVM_ENUM_DISASSEMBLERS
344       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
345   endif()
346 endforeach(t)
348 # Produce the target definition files, which provide a way for clients to easily
349 # include various classes of targets.
350 configure_file(
351   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
352   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
353   )
354 configure_file(
355   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
356   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
357   )
358 configure_file(
359   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
360   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
361   )
362 configure_file(
363   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
364   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
365   )
367 # Configure the three LLVM configuration header files.
368 configure_file(
369   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
370   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
371 configure_file(
372   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
373   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
374 configure_file(
375   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
376   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
378 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
379 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
380 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
382 set(CMAKE_INCLUDE_CURRENT_DIR ON)
384 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
386 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
387   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
388   # with libxml2, iconv.h, etc., we must add /usr/local paths.
389   include_directories("/usr/local/include")
390   link_directories("/usr/local/lib")
391 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
393 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
394    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
395 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
397 # Make sure we don't get -rdynamic in every binary. For those that need it,
398 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
399 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
401 include(AddLLVM)
402 include(TableGen)
404 if( MINGW )
405   # People report that -O3 is unreliable on MinGW. The traditional
406   # build also uses -O2 for that reason:
407   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
408 endif()
410 # Put this before tblgen. Else we have a circular dependence.
411 add_subdirectory(lib/Support)
412 add_subdirectory(lib/TableGen)
414 add_subdirectory(utils/TableGen)
416 add_subdirectory(include/llvm)
418 add_subdirectory(lib)
420 add_subdirectory(utils/FileCheck)
421 add_subdirectory(utils/FileUpdate)
422 add_subdirectory(utils/count)
423 add_subdirectory(utils/not)
424 add_subdirectory(utils/llvm-lit)
425 add_subdirectory(utils/yaml-bench)
427 add_subdirectory(projects)
429 if( LLVM_INCLUDE_TOOLS )
430   add_subdirectory(tools)
431 endif()
433 if( LLVM_INCLUDE_RUNTIME )
434   add_subdirectory(runtime)
435 endif()
437 if( LLVM_INCLUDE_EXAMPLES )
438   add_subdirectory(examples)
439 endif()
441 if( LLVM_INCLUDE_TESTS )
442   add_subdirectory(test)
443   add_subdirectory(utils/unittest)
444   add_subdirectory(unittests)
445   if (MSVC)
446     # This utility is used to prevent crashing tests from calling Dr. Watson on
447     # Windows.
448     add_subdirectory(utils/KillTheDoctor)
449   endif()
451   # Add a global check rule now that all subdirectories have been traversed
452   # and we know the total set of lit testsuites.
453   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
454   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
455   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
456   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
457   add_lit_target(check-all
458     "Running all regression tests"
459     ${LLVM_LIT_TESTSUITES}
460     PARAMS ${LLVM_LIT_PARAMS}
461     DEPENDS ${LLVM_LIT_DEPENDS}
462     ARGS ${LLVM_LIT_EXTRA_ARGS}
463     )
464 endif()
466 add_subdirectory(cmake/modules)
468 install(DIRECTORY include/
469   DESTINATION include
470   FILES_MATCHING
471   PATTERN "*.def"
472   PATTERN "*.h"
473   PATTERN "*.td"
474   PATTERN "*.inc"
475   PATTERN "LICENSE.TXT"
476   PATTERN ".svn" EXCLUDE
477   )
479 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
480   DESTINATION include
481   FILES_MATCHING
482   PATTERN "*.def"
483   PATTERN "*.h"
484   PATTERN "*.gen"
485   PATTERN "*.inc"
486   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
487   PATTERN "CMakeFiles" EXCLUDE
488   PATTERN ".svn" EXCLUDE
489   )
491 # TODO: make and install documentation.
493 set(CPACK_PACKAGE_VENDOR "LLVM")
494 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
495 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
496 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
497 include(CPack)
499 # Workaround for MSVS10 to avoid the Dialog Hell
500 # FIXME: This could be removed with future version of CMake.
501 if(MSVC_VERSION EQUAL 1600)
502   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
503   if( EXISTS "${LLVM_SLN_FILENAME}" )
504     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
505   endif()
506 endif()