Updates to sync with changes in upstream.
[opencl/llvm.git] / CMakeLists.txt
1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
3 cmake_minimum_required(VERSION 2.8.8)
5 # FIXME: It may be removed when we use 2.8.12.
6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
7   # Invalidate a couple of keywords.
8   set(cmake_2_8_12_INTERFACE)
9   set(cmake_2_8_12_PRIVATE)
10 else()
11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
12   set(cmake_2_8_12_INTERFACE INTERFACE)
13   set(cmake_2_8_12_PRIVATE PRIVATE)
14   if(POLICY CMP0022)
15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
16   endif()
17 endif()
19 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
20   set(cmake_3_2_USES_TERMINAL)
21 else()
22   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
23 endif()
25 project(LLVM)
27 # The following only works with the Ninja generator in CMake >= 3.0.
28 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
29   "Define the maximum number of concurrent compilation jobs.")
30 if(LLVM_PARALLEL_COMPILE_JOBS)
31   set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
32   set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
33 endif()
35 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
36   "Define the maximum number of concurrent link jobs.")
37 if(LLVM_PARALLEL_LINK_JOBS)
38   set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
39   set(CMAKE_JOB_POOL_LINK link_job_pool)
40 endif()
42 # Add path for custom modules
43 set(CMAKE_MODULE_PATH
44   ${CMAKE_MODULE_PATH}
45   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
46   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
47   )
49 set(LLVM_VERSION_MAJOR 3)
50 set(LLVM_VERSION_MINOR 7)
51 set(LLVM_VERSION_PATCH 0)
53 if (NOT PACKAGE_VERSION)
54   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
55 endif()
57 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
59 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
60 if ( LLVM_USE_FOLDERS )
61   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
62 endif()
64 include(VersionFromVCS)
66 option(LLVM_APPEND_VC_REV
67   "Append the version control system revision id to LLVM version" OFF)
69 if( LLVM_APPEND_VC_REV )
70   add_version_info_from_vcs(PACKAGE_VERSION)
71 endif()
73 set(PACKAGE_NAME LLVM)
74 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
75 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
77 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
78   "Default URL where bug reports are to be submitted.")
80 # Configure CPack.
81 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
82 set(CPACK_PACKAGE_VENDOR "LLVM")
83 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
84 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
85 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
86 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
87 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
88 if(WIN32 AND NOT UNIX)
89   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
90   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
91   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
92   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
93   set(CPACK_NSIS_MODIFY_PATH "ON")
94   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
95   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
96     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
97   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
98     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
99 endif()
100 include(CPack)
102 # Sanity check our source directory to make sure that we are not trying to
103 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
104 # sure that we don't have any stray generated files lying around in the tree
105 # (which would end up getting picked up by header search, instead of the correct
106 # versions).
107 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
108   message(FATAL_ERROR "In-source builds are not allowed.
109 CMake would overwrite the makefiles distributed with LLVM.
110 Please create a directory and run cmake from there, passing the path
111 to this source directory as the last argument.
112 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
113 Please delete them.")
114 endif()
115 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
116   file(GLOB_RECURSE
117     tablegenned_files_on_include_dir
118     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
119   file(GLOB_RECURSE
120     tablegenned_files_on_lib_dir
121     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
122   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
123     message(FATAL_ERROR "Apparently there is a previous in-source build,
124 probably as the result of running `configure' and `make' on
125 ${CMAKE_CURRENT_SOURCE_DIR}.
126 This may cause problems. The suspicious files are:
127 ${tablegenned_files_on_lib_dir}
128 ${tablegenned_files_on_include_dir}
129 Please clean the source directory.")
130   endif()
131 endif()
133 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
135 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
137 # They are used as destination of target generators.
138 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
139 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
140 if(WIN32 OR CYGWIN)
141   # DLL platform -- put DLLs into bin.
142   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
143 else()
144   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
145 endif()
147 # Each of them corresponds to llvm-config's.
148 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
149 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
150 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
151 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
152 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
154 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
155 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
157 set(LLVM_ALL_TARGETS
158   AArch64
159   ARM
160   CppBackend
161   Hexagon
162   Mips
163   MSP430
164   C6000
165   NVPTX
166   PowerPC
167   R600
168   Sparc
169   SystemZ
170   X86
171   XCore
172   )
174 # List of targets with JIT support:
175 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
177 set(LLVM_TARGETS_TO_BUILD "all"
178     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
180 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
181   CACHE STRING "Semicolon-separated list of experimental targets to build.")
183 option(BUILD_SHARED_LIBS
184   "Build all libraries as shared libraries instead of static" OFF)
186 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
187 if(LLVM_ENABLE_TIMESTAMPS)
188   set(ENABLE_TIMESTAMPS 1)
189 endif()
191 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
192 if(LLVM_ENABLE_BACKTRACES)
193   set(ENABLE_BACKTRACES 1)
194 endif()
196 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
197 if(LLVM_ENABLE_CRASH_OVERRIDES)
198   set(ENABLE_CRASH_OVERRIDES 1)
199 endif()
201 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
202 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
203 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
205 set(LLVM_TARGET_ARCH "host"
206   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
208 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
210 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
212 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
214 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
215   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
216 endif()
218 set(LLVM_TARGETS_TO_BUILD
219    ${LLVM_TARGETS_TO_BUILD}
220    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
221 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
223 include(AddLLVMDefinitions)
225 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
227 # MSVC has a gazillion warnings with this.
228 if( MSVC )
229   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
230 else()
231   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
232 endif()
234 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
235 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
236 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
237 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
238 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
240 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
241   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
242 else()
243   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
244 endif()
246 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
247        "Set to ON to force using an old, unsupported host toolchain." OFF)
249 option(LLVM_USE_INTEL_JITEVENTS
250   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
251   OFF)
253 if( LLVM_USE_INTEL_JITEVENTS )
254   # Verify we are on a supported platform
255   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
256     message(FATAL_ERROR
257       "Intel JIT API support is available on Linux and Windows only.")
258   endif()
259 endif( LLVM_USE_INTEL_JITEVENTS )
261 option(LLVM_USE_OPROFILE
262   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
264 # If enabled, verify we are on a platform that supports oprofile.
265 if( LLVM_USE_OPROFILE )
266   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
267     message(FATAL_ERROR "OProfile support is available on Linux only.")
268   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
269 endif( LLVM_USE_OPROFILE )
271 set(LLVM_USE_SANITIZER "" CACHE STRING
272   "Define the sanitizer used to build binaries and tests.")
274 option(LLVM_USE_SPLIT_DWARF
275   "Use -gsplit-dwarf when compiling llvm." OFF)
277 option(WITH_POLLY "Build LLVM with Polly" ON)
278 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
280 # Define an option controlling whether we should build for 32-bit on 64-bit
281 # platforms, where supported.
282 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
283   # TODO: support other platforms and toolchains.
284   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
285 endif()
287 # Define the default arguments to use with 'lit', and an option for the user to
288 # override.
289 set(LIT_ARGS_DEFAULT "-sv")
290 if (MSVC OR XCODE)
291   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
292 endif()
293 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
295 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
296 if( WIN32 AND NOT CYGWIN )
297   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
298 endif()
300 # Define options to control the inclusion and default build behavior for
301 # components which may not strictly be necessary (tools, examples, and tests).
303 # This is primarily to support building smaller or faster project files.
304 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
305 option(LLVM_BUILD_TOOLS
306   "Build the LLVM tools. If OFF, just generate build targets." ON)
308 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
310 option(LLVM_BUILD_RUNTIME
311   "Build the LLVM runtime libraries." ON)
312 option(LLVM_BUILD_EXAMPLES
313   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
314 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
316 option(LLVM_BUILD_TESTS
317   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
318 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
320 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
321 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
322 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
323 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
325 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
326   "Build compiler-rt as an external project." OFF)
328 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
329 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
330 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
331   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
332 endif()
334 # All options referred to from HandleLLVMOptions have to be specified
335 # BEFORE this include, otherwise options will not be correctly set on
336 # first cmake run
337 include(config-ix)
339 # By default, we target the host, but this can be overridden at CMake
340 # invocation time.
341 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
342   "Default target for which LLVM will generate code." )
343 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
345 include(HandleLLVMOptions)
347 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
348 # FIXME: We should support systems with only Python 3, but that requires work
349 # on LLDB.
350 set(Python_ADDITIONAL_VERSIONS 2.7)
351 include(FindPythonInterp)
352 if( NOT PYTHONINTERP_FOUND )
353   message(FATAL_ERROR
354 "Unable to find Python interpreter, required for builds and testing.
356 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
357 endif()
359 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
360   message(FATAL_ERROR "Python 2.7 or newer is required")
361 endif()
363 ######
364 # LLVMBuild Integration
366 # We use llvm-build to generate all the data required by the CMake based
367 # build system in one swoop:
369 #  - We generate a file (a CMake fragment) in the object root which contains
370 #    all the definitions that are required by CMake.
372 #  - We generate the library table used by llvm-config.
374 #  - We generate the dependencies for the CMake fragment, so that we will
375 #    automatically reconfigure outselves.
377 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
378 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
379   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
380 set(LLVMBUILDCMAKEFRAG
381   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
383 # Create the list of optional components that are enabled
384 if (LLVM_USE_INTEL_JITEVENTS)
385   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
386 endif (LLVM_USE_INTEL_JITEVENTS)
387 if (LLVM_USE_OPROFILE)
388   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
389 endif (LLVM_USE_OPROFILE)
391 message(STATUS "Constructing LLVMBuild project information")
392 execute_process(
393   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
394             --native-target "${LLVM_NATIVE_ARCH}"
395             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
396             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
397             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
398             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
399             OUTPUT_VARIABLE LLVMBUILDOUTPUT
400             ERROR_VARIABLE LLVMBUILDERRORS
401             OUTPUT_STRIP_TRAILING_WHITESPACE
402             ERROR_STRIP_TRAILING_WHITESPACE
403   RESULT_VARIABLE LLVMBUILDRESULT)
405 # On Win32, CMake doesn't properly handle piping the default output/error
406 # streams into the GUI console. So, we explicitly catch and report them.
407 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
408   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
409 endif()
410 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
411   message(FATAL_ERROR
412     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
413 endif()
415 # Include the generated CMake fragment. This will define properties from the
416 # LLVMBuild files in a format which is easy to consume from CMake, and will add
417 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
418 # files change.
419 include(${LLVMBUILDCMAKEFRAG})
421 ######
423 # Configure all of the various header file fragments LLVM uses which depend on
424 # configuration variables.
425 set(LLVM_ENUM_TARGETS "")
426 set(LLVM_ENUM_ASM_PRINTERS "")
427 set(LLVM_ENUM_ASM_PARSERS "")
428 set(LLVM_ENUM_DISASSEMBLERS "")
429 foreach(t ${LLVM_TARGETS_TO_BUILD})
430   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
432   list(FIND LLVM_ALL_TARGETS ${t} idx)
433   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
434   if( idx LESS 0 AND idy LESS 0 )
435     message(FATAL_ERROR "The target `${t}' does not exist.
436     It should be one of\n${LLVM_ALL_TARGETS}")
437   else()
438     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
439   endif()
441   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
442   if( asmp_file )
443     set(LLVM_ENUM_ASM_PRINTERS
444       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
445   endif()
446   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
447     set(LLVM_ENUM_ASM_PARSERS
448       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
449   endif()
450   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
451     set(LLVM_ENUM_DISASSEMBLERS
452       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
453   endif()
454 endforeach(t)
456 # Produce the target definition files, which provide a way for clients to easily
457 # include various classes of targets.
458 configure_file(
459   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
460   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
461   )
462 configure_file(
463   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
464   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
465   )
466 configure_file(
467   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
468   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
469   )
470 configure_file(
471   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
472   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
473   )
475 # Configure the three LLVM configuration header files.
476 configure_file(
477   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
478   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
479 configure_file(
480   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
481   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
482 configure_file(
483   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
484   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
486 # They are not referenced. See set_output_directory().
487 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
488 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
489 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
491 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
492 if (APPLE)
493   set(CMAKE_INSTALL_NAME_DIR "@rpath")
494   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
495 else(UNIX)
496   if(NOT DEFINED CMAKE_INSTALL_RPATH)
497     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
498     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
499       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
500       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
501     endif()
502   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
503 endif()
505 # Work around a broken bfd ld behavior. When linking a binary with a
506 # foo.so library, it will try to find any library that foo.so uses and
507 # check its symbols. This is wasteful (the check was done when foo.so
508 # was created) and can fail since it is not the dynamic linker and
509 # doesn't know how to handle search paths correctly.
510 if (UNIX AND NOT APPLE)
511   set(CMAKE_EXE_LINKER_FLAGS
512       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
513 endif()
515 set(CMAKE_INCLUDE_CURRENT_DIR ON)
517 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
519 # when crosscompiling import the executable targets from a file
520 if(CMAKE_CROSSCOMPILING)
521   include(CrossCompile)
522 endif(CMAKE_CROSSCOMPILING)
524 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
525   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
526   # with libxml2, iconv.h, etc., we must add /usr/local paths.
527   include_directories("/usr/local/include")
528   link_directories("/usr/local/lib")
529 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
531 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
532    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
533 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
535 # Make sure we don't get -rdynamic in every binary. For those that need it,
536 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
537 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
539 include(AddLLVM)
540 include(TableGen)
542 if( MINGW )
543   # People report that -O3 is unreliable on MinGW. The traditional
544   # build also uses -O2 for that reason:
545   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
546 endif()
548 # Put this before tblgen. Else we have a circular dependence.
549 add_subdirectory(lib/Support)
550 add_subdirectory(lib/TableGen)
552 add_subdirectory(utils/TableGen)
554 add_subdirectory(include/llvm)
556 add_subdirectory(lib)
558 if( LLVM_INCLUDE_UTILS )
559   add_subdirectory(utils/FileCheck)
560   add_subdirectory(utils/PerfectShuffle)
561   add_subdirectory(utils/count)
562   add_subdirectory(utils/not)
563   add_subdirectory(utils/llvm-lit)
564   add_subdirectory(utils/yaml-bench)
565 else()
566   if ( LLVM_INCLUDE_TESTS )
567     message(FATAL_ERROR "Including tests when not building utils will not work.
568     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
569   endif()
570 endif()
572 if(LLVM_INCLUDE_TESTS)
573   add_subdirectory(utils/unittest)
574 endif()
576 foreach( binding ${LLVM_BINDINGS_LIST} )
577   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
578     add_subdirectory(bindings/${binding})
579   endif()
580 endforeach()
582 add_subdirectory(projects)
584 if(WITH_POLLY)
585   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
586     set(WITH_POLLY OFF)
587   endif()
588 endif(WITH_POLLY)
590 if( LLVM_INCLUDE_TOOLS )
591   add_subdirectory(tools)
592 endif()
594 if( LLVM_INCLUDE_EXAMPLES )
595   add_subdirectory(examples)
596 endif()
598 if( LLVM_INCLUDE_TESTS )
599   add_subdirectory(test)
600   add_subdirectory(unittests)
601   if (MSVC)
602     # This utility is used to prevent crashing tests from calling Dr. Watson on
603     # Windows.
604     add_subdirectory(utils/KillTheDoctor)
605   endif()
607   # Add a global check rule now that all subdirectories have been traversed
608   # and we know the total set of lit testsuites.
609   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
610   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
611   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
612   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
613   add_lit_target(check-all
614     "Running all regression tests"
615     ${LLVM_LIT_TESTSUITES}
616     PARAMS ${LLVM_LIT_PARAMS}
617     DEPENDS ${LLVM_LIT_DEPENDS}
618     ARGS ${LLVM_LIT_EXTRA_ARGS}
619     )
620 endif()
622 if (LLVM_INCLUDE_DOCS)
623   add_subdirectory(docs)
624 endif()
626 add_subdirectory(cmake/modules)
628 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
629   install(DIRECTORY include/llvm include/llvm-c
630     DESTINATION include
631     FILES_MATCHING
632     PATTERN "*.def"
633     PATTERN "*.h"
634     PATTERN "*.td"
635     PATTERN "*.inc"
636     PATTERN "LICENSE.TXT"
637     PATTERN ".svn" EXCLUDE
638     )
640   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
641     DESTINATION include
642     FILES_MATCHING
643     PATTERN "*.def"
644     PATTERN "*.h"
645     PATTERN "*.gen"
646     PATTERN "*.inc"
647     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
648     PATTERN "CMakeFiles" EXCLUDE
649     PATTERN "config.h" EXCLUDE
650     PATTERN ".svn" EXCLUDE
651     )
652 endif()