1 # This CMake module is responsible for interpreting the user defined LLVM_
2 # options and executing the appropriate CMake commands to realize the users'
3 # selections.
5 # This is commonly needed so make sure it's defined before we include anything
6 # else.
7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
9 include(HandleLLVMStdlib)
10 include(AddLLVMDefinitions)
11 include(CheckCCompilerFlag)
12 include(CheckCXXCompilerFlag)
14 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
15 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
16 if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
17 message(FATAL_ERROR "Host GCC version must be at least 4.7!")
18 endif()
19 elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
20 if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
21 message(FATAL_ERROR "Host Clang version must be at least 3.1!")
22 endif()
24 # Also test that we aren't using too old of a version of libstdc++ with the
25 # Clang compiler. This is tricky as there is no real way to check the
26 # version of libstdc++ directly. Instead we test for a known bug in
27 # libstdc++4.6 that is fixed in libstdc++4.7.
28 if(NOT LLVM_ENABLE_LIBCXX)
29 set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
30 set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
31 set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
32 check_cxx_source_compiles("
33 #include <atomic>
34 std::atomic<float> x(0.0f);
35 int main() { return (float)x; }"
36 LLVM_NO_OLD_LIBSTDCXX)
37 if(NOT LLVM_NO_OLD_LIBSTDCXX)
38 message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
39 endif()
40 set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
41 set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
42 endif()
43 elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
44 if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 17.0)
45 message(FATAL_ERROR "Host Visual Studio must be at least 2012 (MSVC 17.0)")
46 endif()
47 endif()
48 endif()
50 if( LLVM_ENABLE_ASSERTIONS )
51 # MSVC doesn't like _DEBUG on release builds. See PR 4379.
52 if( NOT MSVC )
53 add_definitions( -D_DEBUG )
54 endif()
55 # On non-Debug builds cmake automatically defines NDEBUG, so we
56 # explicitly undefine it:
57 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
58 add_definitions( -UNDEBUG )
59 # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
60 foreach (flags_var_to_scrub
61 CMAKE_CXX_FLAGS_RELEASE
62 CMAKE_CXX_FLAGS_RELWITHDEBINFO
63 CMAKE_CXX_FLAGS_MINSIZEREL
64 CMAKE_C_FLAGS_RELEASE
65 CMAKE_C_FLAGS_RELWITHDEBINFO
66 CMAKE_C_FLAGS_MINSIZEREL)
67 string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
68 "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
69 endforeach()
70 endif()
71 endif()
73 if(WIN32)
74 set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
75 if(CYGWIN)
76 set(LLVM_ON_WIN32 0)
77 set(LLVM_ON_UNIX 1)
78 else(CYGWIN)
79 set(LLVM_ON_WIN32 1)
80 set(LLVM_ON_UNIX 0)
81 endif(CYGWIN)
82 else(WIN32)
83 if(UNIX)
84 set(LLVM_ON_WIN32 0)
85 set(LLVM_ON_UNIX 1)
86 if(APPLE)
87 set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
88 else(APPLE)
89 set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
90 endif(APPLE)
91 else(UNIX)
92 MESSAGE(SEND_ERROR "Unable to determine platform")
93 endif(UNIX)
94 endif(WIN32)
96 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
97 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
99 # We use *.dylib rather than *.so on darwin.
100 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
102 if(APPLE)
103 # Darwin-specific linker flags for loadable modules.
104 set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
105 endif()
107 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
108 # build might work on ELF but fail on MachO/COFF.
109 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR
110 ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD") AND
111 NOT LLVM_USE_SANITIZER)
112 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
113 endif()
116 function(append value)
117 foreach(variable ${ARGN})
118 set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
119 endforeach(variable)
120 endfunction()
122 function(append_if condition value)
123 if (${condition})
124 foreach(variable ${ARGN})
125 set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
126 endforeach(variable)
127 endif()
128 endfunction()
130 macro(add_flag_if_supported flag name)
131 check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
132 append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
133 check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
134 append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
135 endmacro()
137 function(add_flag_or_print_warning flag name)
138 check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
139 check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
140 if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
141 message(STATUS "Building with ${flag}")
142 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
143 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
144 else()
145 message(WARNING "${flag} is not supported.")
146 endif()
147 endfunction()
149 if( LLVM_ENABLE_PIC )
150 if( XCODE )
151 # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
152 # know how to disable this, so just force ENABLE_PIC off for now.
153 message(WARNING "-fPIC not supported with Xcode.")
154 elseif( WIN32 OR CYGWIN)
155 # On Windows all code is PIC. MinGW warns if -fPIC is used.
156 else()
157 add_flag_or_print_warning("-fPIC" FPIC)
159 if( WIN32 OR CYGWIN)
160 # MinGW warns if -fvisibility-inlines-hidden is used.
161 else()
162 check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
163 append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
164 endif()
165 endif()
166 endif()
168 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
169 # TODO: support other platforms and toolchains.
170 if( LLVM_BUILD_32_BITS )
171 message(STATUS "Building 32 bits executables and libraries.")
172 add_llvm_definitions( -m32 )
173 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
174 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
175 set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
176 endif( LLVM_BUILD_32_BITS )
177 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
179 if (LLVM_BUILD_STATIC)
180 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
181 endif()
183 if( XCODE )
184 # For Xcode enable several build settings that correspond to
185 # many warnings that are on by default in Clang but are
186 # not enabled for historical reasons. For versions of Xcode
187 # that do not support these options they will simply
188 # be ignored.
189 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
190 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
191 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
192 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
193 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
194 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
195 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
196 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
197 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
198 set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
199 set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
200 set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
201 set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
202 set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
203 set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
204 endif()
206 # On Win32 using MS tools, provide an option to set the number of parallel jobs
207 # to use.
208 if( MSVC_IDE )
209 set(LLVM_COMPILER_JOBS "0" CACHE STRING
210 "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
211 if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
212 if( LLVM_COMPILER_JOBS STREQUAL "0" )
213 add_llvm_definitions( /MP )
214 else()
215 message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
216 add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
217 endif()
218 else()
219 message(STATUS "Parallel compilation disabled")
220 endif()
221 endif()
223 if( MSVC )
224 include(ChooseMSVCCRT)
226 if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
227 # set stack reserved size to ~10MB
228 # CMake previously automatically set this value for MSVC builds, but the
229 # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
230 # value (1 MB) which is not enough for us in tasks such as parsing recursive
231 # C++ templates in Clang.
232 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
233 endif()
235 if( MSVC11 )
236 add_llvm_definitions(-D_VARIADIC_MAX=10)
237 endif()
239 # Add definitions that make MSVC much less annoying.
240 add_llvm_definitions(
241 # For some reason MS wants to deprecate a bunch of standard functions...
242 -D_CRT_SECURE_NO_DEPRECATE
243 -D_CRT_SECURE_NO_WARNINGS
244 -D_CRT_NONSTDC_NO_DEPRECATE
245 -D_CRT_NONSTDC_NO_WARNINGS
246 -D_SCL_SECURE_NO_DEPRECATE
247 -D_SCL_SECURE_NO_WARNINGS
249 # Disabled warnings.
250 -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
251 -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
252 -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
253 -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
254 -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
255 -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
256 -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
257 -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
258 -wd4355 # Suppress ''this' : used in base member initializer list'
259 -wd4456 # Suppress 'declaration of 'var' hides local variable'
260 -wd4457 # Suppress 'declaration of 'var' hides function parameter'
261 -wd4458 # Suppress 'declaration of 'var' hides class member'
262 -wd4459 # Suppress 'declaration of 'var' hides global declaration'
263 -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
264 -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
265 -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
266 -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
268 # Promoted warnings.
269 -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
271 # Promoted warnings to errors.
272 -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
273 )
275 # Enable warnings
276 if (LLVM_ENABLE_WARNINGS)
277 add_llvm_definitions( /W4 )
278 if (LLVM_ENABLE_PEDANTIC)
279 # No MSVC equivalent available
280 endif (LLVM_ENABLE_PEDANTIC)
281 endif (LLVM_ENABLE_WARNINGS)
282 if (LLVM_ENABLE_WERROR)
283 add_llvm_definitions( /WX )
284 endif (LLVM_ENABLE_WERROR)
285 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
286 if (LLVM_ENABLE_WARNINGS)
287 append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
288 append("-Wcast-qual" CMAKE_CXX_FLAGS)
290 # Turn off missing field initializer warnings for gcc to avoid noise from
291 # false positives with empty {}. Turn them on otherwise (they're off by
292 # default for clang).
293 check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
294 if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
295 if (CMAKE_COMPILER_IS_GNUCXX)
296 append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
297 else()
298 append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
299 endif()
300 endif()
302 append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
303 add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
304 append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
305 append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
307 # Check if -Wnon-virtual-dtor warns even though the class is marked final.
308 # If it does, don't add it. So it won't be added on clang 3.4 and older.
309 # This also catches cases when -Wnon-virtual-dtor isn't supported by
310 # the compiler at all.
311 set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
312 set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
313 CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
314 class derived final : public base { public: ~derived();};
315 int main() { return 0; }"
316 CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
317 set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
318 append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
319 "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
321 # Check if -Wcomment is OK with an // comment ending with '\' if the next
322 # line is also a // comment.
323 set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
324 set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
325 CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
326 C_WCOMMENT_ALLOWS_LINE_WRAP)
327 set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
328 if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
329 append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
330 endif()
331 endif (LLVM_ENABLE_WARNINGS)
332 append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
333 if (NOT LLVM_ENABLE_TIMESTAMPS)
334 add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
335 endif ()
336 if (LLVM_ENABLE_CXX1Y)
337 check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
338 append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
339 else()
340 check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
341 if (CXX_SUPPORTS_CXX11)
342 if (CYGWIN OR MINGW)
343 # MinGW and Cygwin are a bit stricter and lack things like
344 # 'strdup', 'stricmp', etc in c++11 mode.
345 append("-std=gnu++11" CMAKE_CXX_FLAGS)
346 else()
347 append("-std=c++11" CMAKE_CXX_FLAGS)
348 endif()
349 else()
350 message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
351 endif()
352 endif()
353 if (LLVM_ENABLE_MODULES)
354 set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
355 set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fmodules -fcxx-modules")
356 # Check that we can build code with modules enabled, and that repeatedly
357 # including <cassert> still manages to respect NDEBUG properly.
358 CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
359 #include <cassert>
360 #define NDEBUG
361 #include <cassert>
362 int main() { assert(this code is not compiled); }"
363 CXX_SUPPORTS_MODULES)
364 set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
365 if (CXX_SUPPORTS_MODULES)
366 append_if(CXX_SUPPORTS_MODULES "-fmodules" CMAKE_C_FLAGS)
367 append_if(CXX_SUPPORTS_MODULES "-fmodules -fcxx-modules" CMAKE_CXX_FLAGS)
368 else()
369 message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
370 endif()
371 endif(LLVM_ENABLE_MODULES)
372 endif( MSVC )
374 macro(append_common_sanitizer_flags)
375 # Append -fno-omit-frame-pointer and turn on debug info to get better
376 # stack traces.
377 add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
378 if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
379 NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
380 add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
381 endif()
382 # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
383 if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
384 add_flag_if_supported("-O1" O1)
385 endif()
386 endmacro()
388 # Turn on sanitizers if necessary.
389 if(LLVM_USE_SANITIZER)
390 if (LLVM_ON_UNIX)
391 if (LLVM_USE_SANITIZER STREQUAL "Address")
392 append_common_sanitizer_flags()
393 append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
394 elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
395 append_common_sanitizer_flags()
396 append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
397 if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
398 append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
399 endif()
400 elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
401 append_common_sanitizer_flags()
402 append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover"
403 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
404 elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
405 append_common_sanitizer_flags()
406 append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
407 else()
408 message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
409 endif()
410 else()
411 message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
412 endif()
413 endif()
415 # Turn on -gsplit-dwarf if requested
416 if(LLVM_USE_SPLIT_DWARF)
417 add_definitions("-gsplit-dwarf")
418 endif()
420 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
421 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
422 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
424 # clang doesn't print colored diagnostics when invoked from Ninja
425 if (UNIX AND
426 CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
427 CMAKE_GENERATOR STREQUAL "Ninja")
428 append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
429 endif()
431 # Add flags for add_dead_strip().
432 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
433 # But MinSizeRel seems to add that automatically, so maybe disable these
434 # flags instead if LLVM_NO_DEAD_STRIP is set.
435 if(NOT CYGWIN AND NOT WIN32)
436 if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
437 check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
438 if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
439 # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
440 # Doing so will break sanitizers.
441 add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
442 endif()
443 add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
444 endif()
445 endif()
447 if(CYGWIN OR MINGW)
448 # Prune --out-implib from executables. It doesn't make sense even
449 # with --export-all-symbols.
450 string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
451 CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
452 string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
453 CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
454 endif()
456 if(MSVC)
457 # Remove flags here, for exceptions and RTTI.
458 # Each target property or source property should be responsible to control
459 # them.
460 # CL.EXE complains to override flags like "/GR /GR-".
461 string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
462 string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
463 endif()
465 # Provide public options to globally control RTTI and EH
466 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
467 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
468 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
469 message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
470 endif()
472 # Plugin support
473 # FIXME: Make this configurable.
474 if(WIN32 OR CYGWIN)
475 if(BUILD_SHARED_LIBS)
476 set(LLVM_ENABLE_PLUGINS ON)
477 else()
478 set(LLVM_ENABLE_PLUGINS OFF)
479 endif()
480 else()
481 set(LLVM_ENABLE_PLUGINS ON)
482 endif()