1 # This CMake module is responsible for interpreting the user defined LLVM_
2 # options and executing the appropriate CMake commands to realize the users'
3 # selections.
5 include(AddLLVMDefinitions)
6 include(CheckCCompilerFlag)
7 include(CheckCXXCompilerFlag)
9 if( CMAKE_COMPILER_IS_GNUCXX )
10 set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
11 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
12 set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
13 endif()
15 if( LLVM_ENABLE_ASSERTIONS )
16 # MSVC doesn't like _DEBUG on release builds. See PR 4379.
17 if( NOT MSVC )
18 add_definitions( -D_DEBUG )
19 endif()
20 # On Release builds cmake automatically defines NDEBUG, so we
21 # explicitly undefine it:
22 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
23 add_definitions( -UNDEBUG )
24 endif()
25 else()
26 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
27 if( NOT MSVC_IDE AND NOT XCODE )
28 add_definitions( -DNDEBUG )
29 endif()
30 endif()
31 endif()
33 if(WIN32)
34 if(CYGWIN)
35 set(LLVM_ON_WIN32 0)
36 set(LLVM_ON_UNIX 1)
37 else(CYGWIN)
38 set(LLVM_ON_WIN32 1)
39 set(LLVM_ON_UNIX 0)
40 endif(CYGWIN)
41 set(LTDL_SHLIB_EXT ".dll")
42 set(EXEEXT ".exe")
43 # Maximum path length is 160 for non-unicode paths
44 set(MAXPATHLEN 160)
45 else(WIN32)
46 if(UNIX)
47 set(LLVM_ON_WIN32 0)
48 set(LLVM_ON_UNIX 1)
49 if(APPLE)
50 set(LTDL_SHLIB_EXT ".dylib")
51 else(APPLE)
52 set(LTDL_SHLIB_EXT ".so")
53 endif(APPLE)
54 set(EXEEXT "")
55 # FIXME: Maximum path length is currently set to 'safe' fixed value
56 set(MAXPATHLEN 2024)
57 else(UNIX)
58 MESSAGE(SEND_ERROR "Unable to determine platform")
59 endif(UNIX)
60 endif(WIN32)
62 function(add_flag_or_print_warning flag)
63 check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
64 check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
65 if (C_SUPPORTS_FLAG AND CXX_SUPPORTS_FLAG)
66 message(STATUS "Building with ${flag}")
67 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
68 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
69 else()
70 message(WARNING "${flag} is not supported.")
71 endif()
72 endfunction()
74 function(append value)
75 foreach(variable ${ARGN})
76 set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
77 endforeach(variable)
78 endfunction()
80 function(append_if condition value)
81 if (${condition})
82 foreach(variable ${ARGN})
83 set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
84 endforeach(variable)
85 endif()
86 endfunction()
88 macro(add_flag_if_supported flag)
89 check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
90 append_if(C_SUPPORTS_FLAG "${flag}" CMAKE_C_FLAGS)
91 check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
92 append_if(CXX_SUPPORTS_FLAG "${flag}" CMAKE_CXX_FLAGS)
93 endmacro()
95 if( LLVM_ENABLE_PIC )
96 if( XCODE )
97 # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
98 # know how to disable this, so just force ENABLE_PIC off for now.
99 message(WARNING "-fPIC not supported with Xcode.")
100 elseif( WIN32 OR CYGWIN)
101 # On Windows all code is PIC. MinGW warns if -fPIC is used.
102 else()
103 add_flag_or_print_warning("-fPIC")
105 if( WIN32 OR CYGWIN)
106 # MinGW warns if -fvisibility-inlines-hidden is used.
107 else()
108 check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
109 append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
110 endif()
111 endif()
112 endif()
114 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
115 # TODO: support other platforms and toolchains.
116 if( LLVM_BUILD_32_BITS )
117 message(STATUS "Building 32 bits executables and libraries.")
118 add_llvm_definitions( -m32 )
119 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
120 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
121 set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
122 endif( LLVM_BUILD_32_BITS )
123 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
125 # On Win32 using MS tools, provide an option to set the number of parallel jobs
126 # to use.
127 if( MSVC_IDE )
128 set(LLVM_COMPILER_JOBS "0" CACHE STRING
129 "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
130 if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
131 if( LLVM_COMPILER_JOBS STREQUAL "0" )
132 add_llvm_definitions( /MP )
133 else()
134 if (MSVC10)
135 message(FATAL_ERROR
136 "Due to a bug in CMake only 0 and 1 is supported for "
137 "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
138 else()
139 message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
140 add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
141 endif()
142 endif()
143 else()
144 message(STATUS "Parallel compilation disabled")
145 endif()
146 endif()
148 if( MSVC )
149 include(ChooseMSVCCRT)
151 if( MSVC11 )
152 add_llvm_definitions(-D_VARIADIC_MAX=10)
153 endif()
155 # Add definitions that make MSVC much less annoying.
156 add_llvm_definitions(
157 # For some reason MS wants to deprecate a bunch of standard functions...
158 -D_CRT_SECURE_NO_DEPRECATE
159 -D_CRT_SECURE_NO_WARNINGS
160 -D_CRT_NONSTDC_NO_DEPRECATE
161 -D_CRT_NONSTDC_NO_WARNINGS
162 -D_SCL_SECURE_NO_DEPRECATE
163 -D_SCL_SECURE_NO_WARNINGS
165 # Disabled warnings.
166 -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
167 -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
168 -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
169 -wd4181 # Suppress 'qualifier applied to reference type; ignored'
170 -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
171 -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
172 -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
173 -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
174 -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
175 -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
176 -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
177 -wd4355 # Suppress ''this' : used in base member initializer list'
178 -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
179 -wd4551 # Suppress 'function call missing argument list'
180 -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
181 -wd4715 # Suppress ''function' : not all control paths return a value'
182 -wd4722 # Suppress ''function' : destructor never returns, potential memory leak'
183 -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
185 # Promoted warnings.
186 -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
188 # Promoted warnings to errors.
189 -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
190 )
192 # Enable warnings
193 if (LLVM_ENABLE_WARNINGS)
194 add_llvm_definitions( /W4 )
195 if (LLVM_ENABLE_PEDANTIC)
196 # No MSVC equivalent available
197 endif (LLVM_ENABLE_PEDANTIC)
198 endif (LLVM_ENABLE_WARNINGS)
199 if (LLVM_ENABLE_WERROR)
200 add_llvm_definitions( /WX )
201 endif (LLVM_ENABLE_WERROR)
202 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
203 if (LLVM_ENABLE_WARNINGS)
204 append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
206 # Turn off missing field initializer warnings for gcc to avoid noise from
207 # false positives with empty {}. Turn them on otherwise (they're off by
208 # default for clang).
209 check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
210 if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
211 if (CMAKE_COMPILER_IS_GNUCXX)
212 append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
213 else()
214 append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
215 endif()
216 endif()
218 append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
219 check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
220 append_if(CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_CXX_FLAGS)
221 check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
222 append_if(C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_C_FLAGS)
223 append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
224 append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
225 check_cxx_compiler_flag("-Werror -Wnon-virtual-dtor" CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG)
226 append_if(CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
227 endif (LLVM_ENABLE_WARNINGS)
228 if (LLVM_ENABLE_WERROR)
229 add_llvm_definitions( -Werror )
230 endif (LLVM_ENABLE_WERROR)
231 endif( MSVC )
233 macro(append_common_sanitizer_flags)
234 # Append -fno-omit-frame-pointer and turn on debug info to get better
235 # stack traces.
236 add_flag_if_supported("-fno-omit-frame-pointer")
237 if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
238 NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
239 add_flag_if_supported("-gline-tables-only")
240 endif()
241 endmacro()
243 # Turn on sanitizers if necessary.
244 if(LLVM_USE_SANITIZER)
245 if (LLVM_ON_UNIX)
246 if (LLVM_USE_SANITIZER STREQUAL "Address")
247 append_common_sanitizer_flags()
248 add_flag_or_print_warning("-fsanitize=address")
249 elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
250 append_common_sanitizer_flags()
251 add_flag_or_print_warning("-fsanitize=memory")
252 # -pie is required for MSan.
253 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pie")
254 if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
255 add_flag_or_print_warning("-fsanitize-memory-track-origins")
256 endif()
257 else()
258 message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
259 endif()
260 else()
261 message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
262 endif()
263 endif()
265 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
266 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
267 add_llvm_definitions( -D__STDC_LIMIT_MACROS )