cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(AddLLVMDefinitions)
   6 include(CheckCCompilerFlag)
   7
   8 if( CMAKE_COMPILER_IS_GNUCXX )
   9   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  10 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
  11   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  12 endif()
  13
  14 # Run-time build mode; It is used for unittests.
  15 if(MSVC_IDE)
  16   # Expect "$(Configuration)", "$(OutDir)", etc.
  17   # It is expanded by msbuild or similar.
  18   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  19 elseif(NOT CMAKE_BUILD_TYPE STREQUAL "")
  20   # Expect "Release" "Debug", etc.
  21   # Or unittests could not run.
  22   set(RUNTIME_BUILD_MODE ${CMAKE_BUILD_TYPE})
  23 else()
  24   # It might be "."
  25   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  26 endif()
  27
  28 if( LLVM_ENABLE_ASSERTIONS )
  29   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  30   if( NOT MSVC )
  31     add_definitions( -D_DEBUG )
  32   endif()
  33   # On Release builds cmake automatically defines NDEBUG, so we
  34   # explicitly undefine it:
  35   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  36     add_definitions( -UNDEBUG )
  37   endif()
  38 else()
  39   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  40     if( NOT MSVC_IDE AND NOT XCODE )
  41       add_definitions( -DNDEBUG )
  42     endif()
  43   endif()
  44 endif()
  45
  46 if(WIN32)
  47   if(CYGWIN)
  48     set(LLVM_ON_WIN32 0)
  49     set(LLVM_ON_UNIX 1)
  50   else(CYGWIN)
  51     set(LLVM_ON_WIN32 1)
  52     set(LLVM_ON_UNIX 0)
  53   endif(CYGWIN)
  54   set(LTDL_SHLIB_EXT ".dll")
  55   set(EXEEXT ".exe")
  56   # Maximum path length is 160 for non-unicode paths
  57   set(MAXPATHLEN 160)
  58 else(WIN32)
  59   if(UNIX)
  60     set(LLVM_ON_WIN32 0)
  61     set(LLVM_ON_UNIX 1)
  62     if(APPLE)
  63       set(LTDL_SHLIB_EXT ".dylib")
  64     else(APPLE)
  65       set(LTDL_SHLIB_EXT ".so")
  66     endif(APPLE)
  67     set(EXEEXT "")
  68     # FIXME: Maximum path length is currently set to 'safe' fixed value
  69     set(MAXPATHLEN 2024)
  70   else(UNIX)
  71     MESSAGE(SEND_ERROR "Unable to determine platform")
  72   endif(UNIX)
  73 endif(WIN32)
  74
  75 if( LLVM_ENABLE_PIC )
  76   if( XCODE )
  77     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  78     # know how to disable this, so just force ENABLE_PIC off for now.
  79     message(WARNING "-fPIC not supported with Xcode.")
  80   elseif( WIN32 OR CYGWIN)
  81     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  82   else()
  83     include(CheckCXXCompilerFlag)
  84     check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  85     if( SUPPORTS_FPIC_FLAG )
  86       message(STATUS "Building with -fPIC")
  87       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  88       set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
  89     else( SUPPORTS_FPIC_FLAG )
  90       message(WARNING "-fPIC not supported.")
  91     endif()
  92
  93     if( WIN32 OR CYGWIN)
  94       # MinGW warns if -fvisibility-inlines-hidden is used.
  95     else()
  96       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
  97       if( SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG )
  98         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
  99       endif()
 100      endif()
 101   endif()
 102 endif()
 103
 104 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 105   # TODO: support other platforms and toolchains.
 106   if( LLVM_BUILD_32_BITS )
 107     message(STATUS "Building 32 bits executables and libraries.")
 108     add_llvm_definitions( -m32 )
 109     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 110     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 111     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 112   endif( LLVM_BUILD_32_BITS )
 113 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 114
 115 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 116 # to use.
 117 if( MSVC_IDE )
 118   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 119     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 120   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 121     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 122       add_llvm_definitions( /MP )
 123     else()
 124       if (MSVC10)
 125         message(FATAL_ERROR
 126           "Due to a bug in CMake only 0 and 1 is supported for "
 127           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 128       else()
 129         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 130         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 131       endif()
 132     endif()
 133   else()
 134     message(STATUS "Parallel compilation disabled")
 135   endif()
 136 endif()
 137
 138 if( MSVC )
 139   include(ChooseMSVCCRT)
 140
 141   if( MSVC11 )
 142     add_llvm_definitions(-D_VARIADIC_MAX=10)
 143   endif()
 144
 145   # Add definitions that make MSVC much less annoying.
 146   add_llvm_definitions(
 147     # For some reason MS wants to deprecate a bunch of standard functions...
 148     -D_CRT_SECURE_NO_DEPRECATE
 149     -D_CRT_SECURE_NO_WARNINGS
 150     -D_CRT_NONSTDC_NO_DEPRECATE
 151     -D_CRT_NONSTDC_NO_WARNINGS
 152     -D_SCL_SECURE_NO_DEPRECATE
 153     -D_SCL_SECURE_NO_WARNINGS
 154
 155     # Disabled warnings.
 156     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 157     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 158     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 159     -wd4181 # Suppress 'qualifier applied to reference type; ignored'
 160     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 161     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 162     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 163     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 164     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 165     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 166     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 167     -wd4355 # Suppress ''this' : used in base member initializer list'
 168     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 169     -wd4551 # Suppress 'function call missing argument list'
 170     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 171     -wd4715 # Suppress ''function' : not all control paths return a value'
 172     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 173
 174     # Promoted warnings.
 175     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 176
 177     # Promoted warnings to errors.
 178     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 179     -we4239 # Promote 'nonstandard extension used : 'token' : conversion from 'type' to 'type'' to error.
 180     )
 181
 182   # Enable warnings
 183   if (LLVM_ENABLE_WARNINGS)
 184     add_llvm_definitions( /W4 )
 185     if (LLVM_ENABLE_PEDANTIC)
 186       # No MSVC equivalent available
 187     endif (LLVM_ENABLE_PEDANTIC)
 188   endif (LLVM_ENABLE_WARNINGS)
 189   if (LLVM_ENABLE_WERROR)
 190     add_llvm_definitions( /WX )
 191   endif (LLVM_ENABLE_WERROR)
 192 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 193   if (LLVM_ENABLE_WARNINGS)
 194     add_llvm_definitions( -Wall -W -Wno-unused-parameter -Wwrite-strings )
 195     if (LLVM_ENABLE_PEDANTIC)
 196       add_llvm_definitions( -pedantic -Wno-long-long )
 197     endif (LLVM_ENABLE_PEDANTIC)
 198     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 199     if( CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG )
 200       set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wcovered-switch-default" )
 201     endif()
 202     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 203     if( C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG )
 204       set( CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wcovered-switch-default" )
 205     endif()
 206   endif (LLVM_ENABLE_WARNINGS)
 207   if (LLVM_ENABLE_WERROR)
 208     add_llvm_definitions( -Werror )
 209   endif (LLVM_ENABLE_WERROR)
 210 endif( MSVC )
 211
 212 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 213 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 214 add_llvm_definitions( -D__STDC_LIMIT_MACROS )