e8c42fc8dc7c6fce5b0454fd981f49942661cdb7
[opencl/llvm.git] / cmake / modules / LLVM-Config.cmake
1 function(get_system_libs return_var)
2   message(AUTHOR_WARNING "get_system_libs no longer needed")
3   set(${return_var} "" PARENT_SCOPE)
4 endfunction()
7 function(link_system_libs target)
8   message(AUTHOR_WARNING "link_system_libs no longer needed")
9 endfunction()
12 function(is_llvm_target_library library return_var)
13   # Sets variable `return_var' to ON if `library' corresponds to a
14   # LLVM supported target. To OFF if it doesn't.
15   set(${return_var} OFF PARENT_SCOPE)
16   string(TOUPPER "${library}" capitalized_lib)
17   string(TOUPPER "${LLVM_ALL_TARGETS}" targets)
18   foreach(t ${targets})
19     if( capitalized_lib STREQUAL t OR
20         capitalized_lib STREQUAL "LLVM${t}" OR
21         capitalized_lib STREQUAL "LLVM${t}CODEGEN" OR
22         capitalized_lib STREQUAL "LLVM${t}ASMPARSER" OR
23         capitalized_lib STREQUAL "LLVM${t}ASMPRINTER" OR
24         capitalized_lib STREQUAL "LLVM${t}DISASSEMBLER" OR
25         capitalized_lib STREQUAL "LLVM${t}INFO" )
26       set(${return_var} ON PARENT_SCOPE)
27       break()
28     endif()
29   endforeach()
30 endfunction(is_llvm_target_library)
33 macro(llvm_config executable)
34   explicit_llvm_config(${executable} ${ARGN})
35 endmacro(llvm_config)
38 function(explicit_llvm_config executable)
39   set( link_components ${ARGN} )
41   llvm_map_components_to_libnames(LIBRARIES ${link_components})
42   get_target_property(t ${executable} TYPE)
43   if("x${t}" STREQUAL "xSTATIC_LIBRARY")
44     target_link_libraries(${executable} ${cmake_2_8_12_INTERFACE} ${LIBRARIES})
45   elseif("x${t}" STREQUAL "xSHARED_LIBRARY" OR "x${t}" STREQUAL "xMODULE_LIBRARY")
46     target_link_libraries(${executable} ${cmake_2_8_12_PRIVATE} ${LIBRARIES})
47   else()
48     # Use plain form for legacy user.
49     target_link_libraries(${executable} ${LIBRARIES})
50   endif()
51 endfunction(explicit_llvm_config)
54 # This is Deprecated
55 function(llvm_map_components_to_libraries OUT_VAR)
56   message(AUTHOR_WARNING "Using llvm_map_components_to_libraries() is deprecated. Use llvm_map_components_to_libnames() instead")
57   explicit_map_components_to_libraries(result ${ARGN})
58   set( ${OUT_VAR} ${result} ${sys_result} PARENT_SCOPE )
59 endfunction(llvm_map_components_to_libraries)
61 # This is a variant intended for the final user:
62 # Map LINK_COMPONENTS to actual libnames.
63 function(llvm_map_components_to_libnames out_libs)
64   set( link_components ${ARGN} )
65   if(NOT LLVM_AVAILABLE_LIBS)
66     # Inside LLVM itself available libs are in a global property.
67     get_property(LLVM_AVAILABLE_LIBS GLOBAL PROPERTY LLVM_LIBS)
68   endif()
69   string(TOUPPER "${LLVM_AVAILABLE_LIBS}" capitalized_libs)
71   # Expand some keywords:
72   list(FIND LLVM_TARGETS_TO_BUILD "${LLVM_NATIVE_ARCH}" have_native_backend)
73   list(FIND link_components "engine" engine_required)
74   if( NOT engine_required EQUAL -1 )
75     list(FIND LLVM_TARGETS_WITH_JIT "${LLVM_NATIVE_ARCH}" have_jit)
76     if( NOT have_native_backend EQUAL -1 AND NOT have_jit EQUAL -1 )
77       list(APPEND link_components "jit")
78       list(APPEND link_components "native")
79     else()
80       list(APPEND link_components "interpreter")
81     endif()
82   endif()
83   list(FIND link_components "native" native_required)
84   if( NOT native_required EQUAL -1 )
85     if( NOT have_native_backend EQUAL -1 )
86       list(APPEND link_components ${LLVM_NATIVE_ARCH})
87     endif()
88   endif()
90   # Translate symbolic component names to real libraries:
91   foreach(c ${link_components})
92     # add codegen, asmprinter, asmparser, disassembler
93     list(FIND LLVM_TARGETS_TO_BUILD ${c} idx)
94     if( NOT idx LESS 0 )
95       if( TARGET LLVM${c}CodeGen )
96         list(APPEND expanded_components "LLVM${c}CodeGen")
97       else()
98         if( TARGET LLVM${c} )
99           list(APPEND expanded_components "LLVM${c}")
100         else()
101           message(FATAL_ERROR "Target ${c} is not in the set of libraries.")
102         endif()
103       endif()
104       if( TARGET LLVM${c}AsmPrinter )
105         list(APPEND expanded_components "LLVM${c}AsmPrinter")
106       endif()
107       if( TARGET LLVM${c}AsmParser )
108         list(APPEND expanded_components "LLVM${c}AsmParser")
109       endif()
110       if( TARGET LLVM${c}Desc )
111         list(APPEND expanded_components "LLVM${c}Desc")
112       endif()
113       if( TARGET LLVM${c}Info )
114         list(APPEND expanded_components "LLVM${c}Info")
115       endif()
116       if( TARGET LLVM${c}Disassembler )
117         list(APPEND expanded_components "LLVM${c}Disassembler")
118       endif()
119     elseif( c STREQUAL "native" )
120       # already processed
121     elseif( c STREQUAL "nativecodegen" )
122       list(APPEND expanded_components "LLVM${LLVM_NATIVE_ARCH}CodeGen")
123       if( TARGET LLVM${LLVM_NATIVE_ARCH}Desc )
124         list(APPEND expanded_components "LLVM${LLVM_NATIVE_ARCH}Desc")
125       endif()
126       if( TARGET LLVM${LLVM_NATIVE_ARCH}Info )
127         list(APPEND expanded_components "LLVM${LLVM_NATIVE_ARCH}Info")
128       endif()
129     elseif( c STREQUAL "backend" )
130       # same case as in `native'.
131     elseif( c STREQUAL "engine" )
132       # already processed
133     elseif( c STREQUAL "all" )
134       list(APPEND expanded_components ${LLVM_AVAILABLE_LIBS})
135     else( NOT idx LESS 0 )
136       # Canonize the component name:
137       string(TOUPPER "${c}" capitalized)
138       list(FIND capitalized_libs LLVM${capitalized} lib_idx)
139       if( lib_idx LESS 0 )
140         # The component is unknown. Maybe is an omitted target?
141         is_llvm_target_library(${c} iltl_result)
142         if( NOT iltl_result )
143           message(FATAL_ERROR "Library `${c}' not found in list of llvm libraries.")
144         endif()
145       else( lib_idx LESS 0 )
146         list(GET LLVM_AVAILABLE_LIBS ${lib_idx} canonical_lib)
147         list(APPEND expanded_components ${canonical_lib})
148       endif( lib_idx LESS 0 )
149     endif( NOT idx LESS 0 )
150   endforeach(c)
152   set(${out_libs} ${expanded_components} PARENT_SCOPE)
153 endfunction()
155 # Expand dependencies while topologically sorting the list of libraries:
156 function(llvm_expand_dependencies out_libs)
157   set(expanded_components ${ARGN})
158   list(LENGTH expanded_components lst_size)
159   set(cursor 0)
160   set(processed)
161   while( cursor LESS lst_size )
162     list(GET expanded_components ${cursor} lib)
163     get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${lib})
164     list(APPEND expanded_components ${lib_deps})
165     # Remove duplicates at the front:
166     list(REVERSE expanded_components)
167     list(REMOVE_DUPLICATES expanded_components)
168     list(REVERSE expanded_components)
169     list(APPEND processed ${lib})
170     # Find the maximum index that doesn't have to be re-processed:
171     while(NOT "${expanded_components}" MATCHES "^${processed}.*" )
172       list(REMOVE_AT processed -1)
173     endwhile()
174     list(LENGTH processed cursor)
175     list(LENGTH expanded_components lst_size)
176   endwhile( cursor LESS lst_size )
177   set(${out_libs} ${expanded_components} PARENT_SCOPE)
178 endfunction()
180 function(explicit_map_components_to_libraries out_libs)
181   llvm_map_components_to_libnames(link_libs ${ARGN})
182   llvm_expand_dependencies(expanded_components ${link_libs})
183   # Return just the libraries included in this build:
184   set(result)
185   foreach(c ${expanded_components})
186     if( TARGET ${c} )
187       set(result ${result} ${c})
188     endif()
189   endforeach(c)
190   set(${out_libs} ${result} PARENT_SCOPE)
191 endfunction(explicit_map_components_to_libraries)