include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 //===----------------------------------------------------------------------===//
  77 // Types used by intrinsics.
  78 //===----------------------------------------------------------------------===//
  79
  80 class LLVMType<ValueType vt> {
  81   ValueType VT = vt;
  82 }
  83
  84 class LLVMQualPointerType<LLVMType elty, int addrspace>
  85   : LLVMType<iPTR>{
  86   LLVMType ElTy = elty;
  87   int AddrSpace = addrspace;
  88 }
  89
  90 class LLVMPointerType<LLVMType elty>
  91   : LLVMQualPointerType<elty, 0>;
  92
  93 class LLVMAnyPointerType<LLVMType elty>
  94   : LLVMType<iPTRAny>{
  95   LLVMType ElTy = elty;
  96 }
  97
  98 // Match the type of another intrinsic parameter.  Number is an index into the
  99 // list of overloaded types for the intrinsic, excluding all the fixed types.
 100 // The Number value must refer to a previously listed type.  For example:
 101 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 102 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 103 // refers to the first overloaded type, which is the 2nd argument.
 104 class LLVMMatchType<int num>
 105   : LLVMType<OtherVT>{
 106   int Number = num;
 107 }
 108
 109 // Match the type of another intrinsic parameter that is expected to be based on
 110 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 111 // be twice as wide or half as wide as the other type.  This is only useful when
 112 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 113 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 114 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 115 class LLVMVectorSameWidth<int num, LLVMType elty>
 116   : LLVMMatchType<num> {
 117   ValueType ElTy = elty.VT;
 118 }
 119 class LLVMPointerTo<int num> : LLVMMatchType<num>;
 120
 121 // Match the type of another intrinsic parameter that is expected to be a
 122 // vector type, but change the element count to be half as many
 123 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 124
 125 def llvm_void_ty       : LLVMType<isVoid>;
 126 def llvm_any_ty        : LLVMType<Any>;
 127 def llvm_anyint_ty     : LLVMType<iAny>;
 128 def llvm_anyfloat_ty   : LLVMType<fAny>;
 129 def llvm_anyvector_ty  : LLVMType<vAny>;
 130 def llvm_i1_ty         : LLVMType<i1>;
 131 def llvm_i8_ty         : LLVMType<i8>;
 132 def llvm_i16_ty        : LLVMType<i16>;
 133 def llvm_i32_ty        : LLVMType<i32>;
 134 def llvm_i64_ty        : LLVMType<i64>;
 135 def llvm_half_ty       : LLVMType<f16>;
 136 def llvm_float_ty      : LLVMType<f32>;
 137 def llvm_double_ty     : LLVMType<f64>;
 138 def llvm_f80_ty        : LLVMType<f80>;
 139 def llvm_f128_ty       : LLVMType<f128>;
 140 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 141 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 142 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 143 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 144 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 145 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 146 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 147
 148 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 149 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 150
 151 def llvm_ptri16_ty     : LLVMPointerType<llvm_i16_ty>;            // i16*
 152 def llvm_ptri32_ty     : LLVMPointerType<llvm_i32_ty>;            // i32*
 153 def llvm_ptri64_ty     : LLVMPointerType<llvm_i64_ty>;            // i64*
 154 def llvm_ptrdouble_ty  : LLVMPointerType<llvm_double_ty>;         // double*
 155
 156 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 157 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 158 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 159 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 160 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 161 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 162 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 163 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 164 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 165 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 166 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 167 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 168 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 169
 170 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 171 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 172 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 173 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 174 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 175 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 176
 177 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 178 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 179 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 180 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 181 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 182 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 183 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 184 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 185 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 186 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 187
 188 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 189 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 190 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 191 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 192 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 193 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 194 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 195 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 196 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 197 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 198 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 199 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 200
 201 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 202
 203
 204 //===----------------------------------------------------------------------===//
 205 // Intrinsic Definitions.
 206 //===----------------------------------------------------------------------===//
 207
 208 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 209 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 210 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 211 // example, llvm.bswap.i16 -> int_bswap_i16.
 212 //
 213 //  * RetTypes is a list containing the return types expected for the
 214 //    intrinsic.
 215 //  * ParamTypes is a list containing the parameter types expected for the
 216 //    intrinsic.
 217 //  * Properties can be set to describe the behavior of the intrinsic.
 218 //
 219 class SDPatternOperator;
 220 class Intrinsic<list<LLVMType> ret_types,
 221                 list<LLVMType> param_types = [],
 222                 list<IntrinsicProperty> properties = [],
 223                 string name = ""> : SDPatternOperator {
 224   string LLVMName = name;
 225   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 226   list<LLVMType> RetTypes = ret_types;
 227   list<LLVMType> ParamTypes = param_types;
 228   list<IntrinsicProperty> Properties = properties;
 229
 230   bit isTarget = 0;
 231 }
 232
 233 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 234 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 235 /// support.
 236 class GCCBuiltin<string name> {
 237   string GCCBuiltinName = name;
 238 }
 239
 240 class MSBuiltin<string name> {
 241   string MSBuiltinName = name;
 242 }
 243
 244
 245 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 246 //
 247
 248 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 249 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 250                             "llvm.va_copy">;
 251 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 252
 253 //===------------------- Garbage Collection Intrinsics --------------------===//
 254 //
 255 def int_gcroot  : Intrinsic<[],
 256                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 257 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 258                             [llvm_ptr_ty, llvm_ptrptr_ty],
 259                             [IntrReadArgMem]>;
 260 def int_gcwrite : Intrinsic<[],
 261                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 262                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 263
 264 //===--------------------- Code Generator Intrinsics ----------------------===//
 265 //
 266 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 267 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 268 def int_frameallocate : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 269 def int_framerecover : Intrinsic<[llvm_ptr_ty],
 270                                              [llvm_ptr_ty, llvm_ptr_ty],
 271                                              [IntrNoMem]>;
 272 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 273                                    [IntrNoMem], "llvm.read_register">;
 274 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 275                                    [], "llvm.write_register">;
 276
 277 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 278 // model their dependencies on allocas.
 279 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 280                         GCCBuiltin<"__builtin_stack_save">;
 281 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 282                         GCCBuiltin<"__builtin_stack_restore">;
 283
 284 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 285 // however it does conveniently prevent the prefetch from being reordered
 286 // with respect to nearby accesses to the same memory.
 287 def int_prefetch      : Intrinsic<[],
 288                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 289                                    llvm_i32_ty],
 290                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 291 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 292
 293 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 294
 295 // The assume intrinsic is marked as arbitrarily writing so that proper
 296 // control dependencies will be maintained.
 297 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 298
 299 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 300 // guard to the correct place on the stack frame.
 301 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 302 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 303                                         [IntrReadWriteArgMem]>;
 304
 305 // A counter increment for instrumentation based profiling.
 306 def int_instrprof_increment : Intrinsic<[],
 307                                         [llvm_ptr_ty, llvm_i64_ty,
 308                                          llvm_i32_ty, llvm_i32_ty],
 309                                         []>;
 310
 311 //===------------------- Standard C Library Intrinsics --------------------===//
 312 //
 313
 314 def int_memcpy  : Intrinsic<[],
 315                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 316                               llvm_i32_ty, llvm_i1_ty],
 317                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 318                              ReadOnly<1>]>;
 319 def int_memmove : Intrinsic<[],
 320                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 321                              llvm_i32_ty, llvm_i1_ty],
 322                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 323                              ReadOnly<1>]>;
 324 def int_memset  : Intrinsic<[],
 325                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 326                              llvm_i32_ty, llvm_i1_ty],
 327                             [IntrReadWriteArgMem, NoCapture<0>]>;
 328
 329 let Properties = [IntrNoMem] in {
 330   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 331                            [LLVMMatchType<0>, LLVMMatchType<0>,
 332                             LLVMMatchType<0>]>;
 333   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 334                               [LLVMMatchType<0>, LLVMMatchType<0>,
 335                                LLVMMatchType<0>]>;
 336
 337   // These functions do not read memory, but are sensitive to the
 338   // rounding mode. LLVM purposely does not model changes to the FP
 339   // environment so they can be treated as readnone.
 340   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 341   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 342   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 343   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 344   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 345                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 346   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 347   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 348   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 349   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 350   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 351   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 352   def int_minnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 353   def int_maxnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 354   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 355                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 356   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 357   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 358   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 359   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 360   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 361   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 362 }
 363
 364 // NOTE: these are internal interfaces.
 365 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 366 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 367 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 368 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 369
 370 // Internal interface for object size checking
 371 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 372                                [IntrNoMem]>,
 373                                GCCBuiltin<"__builtin_object_size">;
 374
 375 //===------------------------- Expect Intrinsics --------------------------===//
 376 //
 377 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 378                                               LLVMMatchType<0>], [IntrNoMem]>;
 379
 380 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 381 //
 382
 383 // None of these intrinsics accesses memory at all.
 384 let Properties = [IntrNoMem] in {
 385   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 386   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 387   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 388   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 389 }
 390
 391 //===------------------------ Debugger Intrinsics -------------------------===//
 392 //
 393
 394 // None of these intrinsics accesses memory at all...but that doesn't mean the
 395 // optimizers can change them aggressively.  Special handling needed in a few
 396 // places.
 397 let Properties = [IntrNoMem] in {
 398   def int_dbg_declare      : Intrinsic<[],
 399                                        [llvm_metadata_ty,
 400                                        llvm_metadata_ty,
 401                                        llvm_metadata_ty]>;
 402   def int_dbg_value        : Intrinsic<[],
 403                                        [llvm_metadata_ty, llvm_i64_ty,
 404                                         llvm_metadata_ty,
 405                                         llvm_metadata_ty]>;
 406 }
 407
 408 //===------------------ Exception Handling Intrinsics----------------------===//
 409 //
 410
 411 // The result of eh.typeid.for depends on the enclosing function, but inside a
 412 // given function it is 'const' and may be CSE'd etc.
 413 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 414
 415 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 416 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 417
 418 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 419 // callee-saved registers to be saved and restored (regardless of whether they
 420 // are used) in the calling function. It is used by libgcc_eh.
 421 def int_eh_unwind_init: Intrinsic<[]>,
 422                         GCCBuiltin<"__builtin_unwind_init">;
 423
 424 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 425
 426 let Properties = [IntrNoMem] in {
 427   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 428   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 429 }
 430 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 431 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 432 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 433
 434 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 435 //
 436 def int_var_annotation : Intrinsic<[],
 437                                    [llvm_ptr_ty, llvm_ptr_ty,
 438                                     llvm_ptr_ty, llvm_i32_ty],
 439                                    [], "llvm.var.annotation">;
 440 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 441                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 442                                     llvm_i32_ty],
 443                                    [], "llvm.ptr.annotation">;
 444 def int_annotation : Intrinsic<[llvm_anyint_ty],
 445                                [LLVMMatchType<0>, llvm_ptr_ty,
 446                                 llvm_ptr_ty, llvm_i32_ty],
 447                                [], "llvm.annotation">;
 448
 449 //===------------------------ Trampoline Intrinsics -----------------------===//
 450 //
 451 def int_init_trampoline : Intrinsic<[],
 452                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 453                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 454                                    GCCBuiltin<"__builtin_init_trampoline">;
 455
 456 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 457                                       [IntrReadArgMem]>,
 458                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 459
 460 //===------------------------ Overflow Intrinsics -------------------------===//
 461 //
 462
 463 // Expose the carry flag from add operations on two integrals.
 464 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 465                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 466                                        [IntrNoMem]>;
 467 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 468                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 469                                        [IntrNoMem]>;
 470
 471 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 472                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 473                                        [IntrNoMem]>;
 474 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 475                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 476                                        [IntrNoMem]>;
 477
 478 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 479                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 480                                        [IntrNoMem]>;
 481 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 482                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 483                                        [IntrNoMem]>;
 484
 485 //===------------------------- Memory Use Markers -------------------------===//
 486 //
 487 def int_lifetime_start  : Intrinsic<[],
 488                                     [llvm_i64_ty, llvm_ptr_ty],
 489                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 490 def int_lifetime_end    : Intrinsic<[],
 491                                     [llvm_i64_ty, llvm_ptr_ty],
 492                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 493 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 494                                     [llvm_i64_ty, llvm_ptr_ty],
 495                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 496 def int_invariant_end   : Intrinsic<[],
 497                                     [llvm_descriptor_ty, llvm_i64_ty,
 498                                      llvm_ptr_ty],
 499                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 500
 501 //===------------------------ Stackmap Intrinsics -------------------------===//
 502 //
 503 def int_experimental_stackmap : Intrinsic<[],
 504                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 505                                   [Throws]>;
 506 def int_experimental_patchpoint_void : Intrinsic<[],
 507                                                  [llvm_i64_ty, llvm_i32_ty,
 508                                                   llvm_ptr_ty, llvm_i32_ty,
 509                                                   llvm_vararg_ty],
 510                                                   [Throws]>;
 511 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 512                                                 [llvm_i64_ty, llvm_i32_ty,
 513                                                  llvm_ptr_ty, llvm_i32_ty,
 514                                                  llvm_vararg_ty],
 515                                                  [Throws]>;
 516
 517
 518 //===------------------------ Garbage Collection Intrinsics ---------------===//
 519 // These are documented in docs/Statepoint.rst
 520
 521 def int_experimental_gc_statepoint : Intrinsic<[llvm_i32_ty],
 522                                [llvm_anyptr_ty, llvm_i32_ty,
 523                                 llvm_i32_ty, llvm_vararg_ty]>;
 524
 525 def int_experimental_gc_result   : Intrinsic<[llvm_any_ty], [llvm_i32_ty]>;
 526 def int_experimental_gc_relocate : Intrinsic<[llvm_anyptr_ty],
 527                                 [llvm_i32_ty, llvm_i32_ty, llvm_i32_ty]>;
 528
 529 // Deprecated: will be removed in a couple of weeks
 530 def int_experimental_gc_result_int : Intrinsic<[llvm_anyint_ty], [llvm_i32_ty]>;
 531 def int_experimental_gc_result_float : Intrinsic<[llvm_anyfloat_ty],
 532                                                  [llvm_i32_ty]>;
 533 def int_experimental_gc_result_ptr : Intrinsic<[llvm_anyptr_ty], [llvm_i32_ty]>;
 534
 535 //===-------------------------- Other Intrinsics --------------------------===//
 536 //
 537 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 538                      GCCBuiltin<"__builtin_flt_rounds">;
 539 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 540                GCCBuiltin<"__builtin_trap">;
 541 def int_debugtrap : Intrinsic<[]>,
 542                     GCCBuiltin<"__builtin_debugtrap">;
 543
 544 // NOP: calls/invokes to this intrinsic are removed by codegen
 545 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 546
 547 // Intrisics to support half precision floating point format
 548 let Properties = [IntrNoMem] in {
 549 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 550 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 551 }
 552
 553 // These convert intrinsics are to support various conversions between
 554 // various types with rounding and saturation. NOTE: avoid using these
 555 // intrinsics as they might be removed sometime in the future and
 556 // most targets don't support them.
 557 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 558                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 559 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 560                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 561 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 562                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 563 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 564                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 565 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 566                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 567 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 568                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 569 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 570                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 571 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 572                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 573 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 574                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 575
 576 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 577 // maps to void __clear_cache() on supporting platforms
 578 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 579                                 [], "llvm.clear_cache">;
 580
 581 //===-------------------------- Masked Intrinsics -------------------------===//
 582 //
 583 def int_masked_store : Intrinsic<[], [llvm_anyvector_ty, LLVMPointerTo<0>,
 584                                       llvm_i32_ty,
 585                                       LLVMVectorSameWidth<0, llvm_i1_ty>],
 586                                  [IntrReadWriteArgMem]>;
 587
 588 def int_masked_load  : Intrinsic<[llvm_anyvector_ty],
 589                                  [LLVMPointerTo<0>, llvm_i32_ty,
 590                                   LLVMVectorSameWidth<0, llvm_i1_ty>, LLVMMatchType<0>],
 591                                  [IntrReadArgMem]>;
 592
 593 //===----------------------------------------------------------------------===//
 594 // Target-specific intrinsics
 595 //===----------------------------------------------------------------------===//
 596
 597 include "llvm/IR/IntrinsicsPowerPC.td"
 598 include "llvm/IR/IntrinsicsX86.td"
 599 include "llvm/IR/IntrinsicsARM.td"
 600 include "llvm/IR/IntrinsicsAArch64.td"
 601 include "llvm/IR/IntrinsicsXCore.td"
 602 include "llvm/IR/IntrinsicsHexagon.td"
 603 include "llvm/IR/IntrinsicsNVVM.td"
 604 include "llvm/IR/IntrinsicsMips.td"
 605 include "llvm/IR/IntrinsicsR600.td"
 606 include "llvm/IR/IntrinsicsTI.td"
 607 include "llvm/IR/IntrinsicsC6000.td"
 608 include "llvm/IR/IntrinsicsC7000.td"
 609 include "llvm/IR/IntrinsicsMSP430.td"